inputcontainer.qc File Reference

#include "inputcontainer.qh"

Include dependency graph for inputcontainer.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
bool	InputContainer__changeFocusXY (entity this, vector pos)
void	InputContainer_focusLeave (entity me)
float	InputContainer_keyDown (entity me, float scan, float ascii, float shift)
float	InputContainer_mouseDrag (entity me, vector pos)
float	InputContainer_mouseMove (entity me, vector pos)
float	InputContainer_mouseRelease (entity me, vector pos)
void	InputContainer_resizeNotify (entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)

Function Documentation

InputContainer__changeFocusXY()

bool InputContainer__changeFocusXY	(	entity	this,
		vector	pos
	)

Definition at line 86 of file inputcontainer.qc.

References entity(), globalToBox(), NULL, and prev.

    {
        entity e = this.itemFromPoint(this, pos);
        if (e && !e.focusable) e = NULL;
        entity prev = this.mouseFocusedChild;
        this.mouseFocusedChild = e;
        if (e != prev)
        {
            this.setFocus(this, e);
            if (e && e.instanceOfInputContainer)
            {
                e.focusedChild = NULL;
                e._changeFocusXY(e, globalToBox(pos, e.Container_origin, e.Container_size));
            }
        }
        return true;  // have focus
    }

Here is the call graph for this function:

InputContainer_focusLeave()

void InputContainer_focusLeave

(

entity

me

)

Definition at line 14 of file inputcontainer.qc.

References NULL, and SUPER.

    {
        SUPER(InputContainer).focusLeave(me);
        me.mouseFocusedChild = NULL;
    }

InputContainer_keyDown()

float InputContainer_keyDown	(	entity	me,
		float	scan,
		float	ascii,
		float	shift
	)

Definition at line 20 of file inputcontainer.qc.

References entity(), K_ESCAPE, K_TAB, NULL, S_SHIFT, and SUPER.

    {
        entity f, ff;
        if (SUPER(InputContainer).keyDown(me, scan, ascii, shift))
            return 1;
        if (scan == K_ESCAPE)
        {
            f = me.focusedChild;
            if (f)
            {
                me.setFocus(me, NULL);
                return 1;
            }
            return 0;
        }
        if (scan == K_TAB)
        {
            f = me.focusedChild;
            if (shift & S_SHIFT)
            {
                if (f)
                {
                    for (ff = f.prevSibling; ff; ff = ff.prevSibling)
                    {
                        if (!ff.focusable) continue;
                        me.setFocus(me, ff);
                        return 1;
                    }
                }
                if (!f || me.isTabRoot)
                {
                    for (ff = me.lastChild; ff; ff = ff.prevSibling)
                    {
                        if (!ff.focusable) continue;
                        me.setFocus(me, ff);
                        return 1;
                    }
                    return 0;  // AIIIIEEEEE!
                }
            }
            else
            {
                if (f)
                {
                    for (ff = f.nextSibling; ff; ff = ff.nextSibling)
                    {
                        if (!ff.focusable) continue;
                        me.setFocus(me, ff);
                        return 1;
                    }
                }
                if (!f || me.isTabRoot)
                {
                    for (ff = me.firstChild; ff; ff = ff.nextSibling)
                    {
                        if (!ff.focusable) continue;
                        me.setFocus(me, ff);
                        return 1;
                    }
                    return 0;  // AIIIIEEEEE!
                }
            }
        }
        return 0;
    }

Here is the call graph for this function:

InputContainer_mouseDrag()

float InputContainer_mouseDrag	(	entity	me,
		vector	pos
	)

Definition at line 104 of file inputcontainer.qc.

References SUPER.

    {
        if (SUPER(InputContainer).mouseDrag(me, pos)) return 1;
        if (pos.x >= 0 && pos.y >= 0 && pos.x < 1 && pos.y < 1) return 1;
        return 0;
    }

InputContainer_mouseMove()

float InputContainer_mouseMove	(	entity	me,
		vector	pos
	)

Definition at line 110 of file inputcontainer.qc.

References METHOD, NULL, SUPER, and vector().

    {
        if (me.mouseFocusedChild != me.focusedChild) // if the keyboard moved the focus away
            me.mouseFocusedChild = NULL;             // force focusing
        if (me._changeFocusXY(me, pos))
            if (SUPER(InputContainer).mouseMove(me, pos)) return 1;
        if (pos.x >= 0 && pos.y >= 0 && pos.x < 1 && pos.y < 1) return 1;
        return 0;
    }

Here is the call graph for this function:

InputContainer_mouseRelease()

float InputContainer_mouseRelease	(	entity	me,
		vector	pos
	)

Definition at line 127 of file inputcontainer.qc.

References SUPER.

    {
        SUPER(InputContainer).mouseRelease(me, pos); // return value?
        if (me.focused)                              // am I still eligible for this? (UGLY HACK, but a mouse event could have changed focus away)
            if (me._changeFocusXY(me, pos)) return 1;
        if (pos.x >= 0 && pos.y >= 0 && pos.x < 1 && pos.y < 1) return 1;
        return 0;
    }

InputContainer_resizeNotify()

void InputContainer_resizeNotify	(	entity	me,
		vector	relOrigin,
		vector	relSize,
		vector	absOrigin,
		vector	absSize
	)

Definition at line 3 of file inputcontainer.qc.

References SUPER.

    {
        SUPER(InputContainer).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
        /*
        if(me.parent.instanceOfInputContainer)
            me.isTabRoot = 0;
        else
            me.isTabRoot = 1;
        */
    }