#include "container.qh"

Include dependency graph for container.qc:

This graph shows which files directly or indirectly include this file:

Functions
void	Container_addItem (entity me, entity other, vector theOrigin, vector theSize, float theAlpha)

void	Container_addItemCentered (entity me, entity other, vector theSize, float theAlpha)

void	Container_addItemRightCentered (entity me, entity other, vector theSize, float theAlpha)

void	Container_draw (entity me)

void	Container_enterLieSubitem (entity me, vector o, vector s, vector f, float a)

void	Container_enterSubitem (entity me, entity sub)

void	Container_focusLeave (entity me)

void	Container_hideNotify (entity me)

entity	Container_itemFromPoint (entity me, vector pos)

float	Container_keyDown (entity me, float scan, float ascii, float shift)

float	Container_keyUp (entity me, float scan, float ascii, float shift)

void	Container_leaveSubitem (entity me)

float	Container_mouseDrag (entity me, vector pos)

float	Container_mouseMove (entity me, vector pos)

float	Container_mouseRelease (entity me, vector pos)

void	Container_moveItemAfter (entity me, entity other, entity dest)

entity	Container_preferredFocusedGrandChild (entity me)

void	Container_removeItem (entity me, entity other)

void	Container_resizeNotify (entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)

void	Container_resizeNotifyLie (entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize,.vector originField,.vector sizeField,.vector fontScaleField)

void	Container_saveFocus (entity me)

void	Container_setAlphaOf (entity me, entity other, float theAlpha)

void	Container_setFocus (entity me, entity other)

void	Container_showNotify (entity me)

Function Documentation

◆ Container_addItem()

void Container_addItem	(	entity	me,
		entity	other,
		vector	theOrigin,
		vector	theSize,
		float	theAlpha
	)

Definition at line 232 of file container.qc.

References bound(), entity(), error(), NULL, and other.

     {
         if (other.parent) error("Can't add already added item!");
 
         if (other.focusable) me.focusable += 1;
 
         if (theSize.x > 1)
         {
             theOrigin.x -= 0.5 * (theSize.x - 1);
             theSize.x = 1;
         }
         if (theSize.y > 1)
         {
             theOrigin.y -= 0.5 * (theSize.y - 1);
             theSize.y = 1;
         }
         theOrigin.x = bound(0, theOrigin.x, 1 - theSize.x);
         theOrigin.y = bound(0, theOrigin.y, 1 - theSize.y);
 
         other.parent = me;
         other.Container_origin = theOrigin;
         other.Container_size = theSize;
 
         // don't call setAlphaOf, it would uneccessarily trigger showNotify
         //me.setAlphaOf(me, other, theAlpha);
         other.Container_alpha = theAlpha;
 
         entity l;
         l = me.lastChild;
 
         if (l) l.nextSibling = other;
         else me.firstChild = other;
 
         other.prevSibling = l;
         other.nextSibling = NULL;
         me.lastChild = other;
     }

Here is the call graph for this function:

◆ Container_addItemCentered()

void Container_addItemCentered	(	entity	me,
		entity	other,
		vector	theSize,
		float	theAlpha
	)

Definition at line 222 of file container.qc.

     {
         me.addItem(me, other, '0.5 0.5 0' - 0.5 * theSize, theSize, theAlpha);
     }

◆ Container_addItemRightCentered()

void Container_addItemRightCentered	(	entity	me,
		entity	other,
		vector	theSize,
		float	theAlpha
	)

Definition at line 227 of file container.qc.

     {
         me.addItem(me, other, '1 0.5 0' - 0.5 * theSize, theSize, theAlpha);
     }

◆ Container_draw()

void Container_draw ( entity me )

Definition at line 114 of file container.qc.

References entity(), and SUPER.

     {
         entity e;
 
         me.focusable = 0;
         for (e = me.firstChild; e; e = e.nextSibling)
         {
             if (e.focusable) me.focusable += 1;
             if (e.Container_alpha < 0.003)  // can't change color values anyway
                 continue;
             me.enterSubitem(me, e);
             e.draw(e);
             me.leaveSubitem(me);
         }
 
         SUPER(Container).draw(me);
     }

Here is the call graph for this function:

◆ Container_enterLieSubitem()

void Container_enterLieSubitem	(	entity	me,
		vector	o,
		vector	s,
		vector	f,
		float	a
	)

Definition at line 8 of file container.qc.

References boxToGlobal(), boxToGlobalSize(), draw_alpha, draw_fontscale, draw_scale, and draw_shift.

     {
         me.Container_save_shift = draw_shift;
         me.Container_save_scale = draw_scale;
         me.Container_save_alpha = draw_alpha;
         me.Container_save_fontscale = draw_fontscale;
 
         draw_shift = boxToGlobal(o, draw_shift, draw_scale);
         draw_scale = boxToGlobalSize(s, draw_scale);
         if (f != '0 0 0') draw_fontscale = boxToGlobalSize(f, draw_fontscale);
         draw_alpha *= a;
     }

Here is the call graph for this function:

◆ Container_enterSubitem()

void Container_enterSubitem	(	entity	me,
		entity	sub
	)

Definition at line 3 of file container.qc.

     {
         me.enterLieSubitem(me, sub.Container_origin, sub.Container_size, sub.Container_fontscale, sub.Container_alpha);
     }

◆ Container_focusLeave()

void Container_focusLeave ( entity me )

Definition at line 132 of file container.qc.

References NULL.

     {
         me.setFocus(me, NULL);
     }

◆ Container_hideNotify()

void Container_hideNotify ( entity me )

Definition at line 38 of file container.qc.

References entity().

     {
         entity e;
         if (!me.shown) return;
         me.shown = 0;
         for (e = me.firstChild; e; e = e.nextSibling)
             if (e.Container_alpha > 0) e.hideNotify(e);
     }

Here is the call graph for this function:

◆ Container_itemFromPoint()

entity Container_itemFromPoint	(	entity	me,
		vector	pos
	)

Definition at line 97 of file container.qc.

References entity(), NULL, and vector().

     {
         entity e;
         vector o, s;
         for (e = me.lastChild; e; e = e.prevSibling)
         {
             o = e.Container_origin;
             s = e.Container_size;
             if (pos.x < o.x) continue;
             if (pos.y < o.y) continue;
             if (pos.x >= o.x + s.x) continue;
             if (pos.y >= o.y + s.y) continue;
             return e;
         }
         return NULL;
     }

Here is the call graph for this function:

◆ Container_keyDown()

float Container_keyDown	(	entity	me,
		float	scan,
		float	ascii,
		float	shift
	)

Definition at line 152 of file container.qc.

References entity().

     {
         entity f;
         float r;
         f = me.focusedChild;
         if (f)
         {
             me.enterSubitem(me, f);
             r = f.keyDown(f, scan, ascii, shift);
             me.leaveSubitem(me);
             return r;
         }
         return 0;
     }

Here is the call graph for this function:

◆ Container_keyUp()

float Container_keyUp	(	entity	me,
		float	scan,
		float	ascii,
		float	shift
	)

Definition at line 137 of file container.qc.

References entity().

     {
         entity f;
         float r;
         f = me.focusedChild;
         if (f)
         {
             me.enterSubitem(me, f);
             r = f.keyUp(f, scan, ascii, shift);
             me.leaveSubitem(me);
             return r;
         }
         return 0;
     }

Here is the call graph for this function:

◆ Container_leaveSubitem()

void Container_leaveSubitem ( entity me )

Definition at line 21 of file container.qc.

References draw_alpha, draw_fontscale, draw_scale, and draw_shift.

     {
         draw_shift = me.Container_save_shift;
         draw_scale = me.Container_save_scale;
         draw_alpha = me.Container_save_alpha;
         draw_fontscale = me.Container_save_fontscale;
     }

◆ Container_mouseDrag()

float Container_mouseDrag	(	entity	me,
		vector	pos
	)

Definition at line 193 of file container.qc.

References entity(), and globalToBox().

     {
         entity f;
         float r;
         f = me.focusedChild;
         if (f)
         {
             me.enterSubitem(me, f);
             r = f.mouseDrag(f, globalToBox(pos, f.Container_origin, f.Container_size));
             me.leaveSubitem(me);
             return r;
         }
         return 0;
     }

Here is the call graph for this function:

◆ Container_mouseMove()

float Container_mouseMove	(	entity	me,
		vector	pos
	)

Definition at line 167 of file container.qc.

References entity(), globalToBox(), METHOD, and vector().

     {
         entity f;
         float r;
         f = me.focusedChild;
         if (f)
         {
             me.enterSubitem(me, f);
             r = f.mouseMove(f, globalToBox(pos, f.Container_origin, f.Container_size));
             me.leaveSubitem(me);
             return r;
         }
         return 0;
     }

Here is the call graph for this function:

◆ Container_mouseRelease()

float Container_mouseRelease	(	entity	me,
		vector	pos
	)

Definition at line 207 of file container.qc.

References entity(), and globalToBox().

     {
         entity f;
         float r;
         f = me.focusedChild;
         if (f)
         {
             me.enterSubitem(me, f);
             r = f.mouseRelease(f, globalToBox(pos, f.Container_origin, f.Container_size));
             me.leaveSubitem(me);
             return r;
         }
         return 0;
     }

Here is the call graph for this function:

◆ Container_moveItemAfter()

void Container_moveItemAfter	(	entity	me,
		entity	other,
		entity	dest
	)

Definition at line 330 of file container.qc.

References dest, entity(), error(), and other.

     {
         // first: remove other from the chain
         entity n, p;
 
         if (other.parent != me) error("Can't move in wrong container!");
 
         n = other.nextSibling;
         p = other.prevSibling;
 
         if (p) p.nextSibling = n;
         else me.firstChild = n;
 
         if (n) n.prevSibling = p;
         else me.lastChild = p;
 
         // now other got removed. Insert it behind dest now.
         other.prevSibling = dest;
         if (dest) other.nextSibling = dest.nextSibling;
         else other.nextSibling = me.firstChild;
 
         if (dest) dest.nextSibling = other;
         else me.firstChild = other;
 
         if (other.nextSibling) other.nextSibling.prevSibling = other;
         else me.lastChild = other;
     }

Here is the call graph for this function:

◆ Container_preferredFocusedGrandChild()

entity Container_preferredFocusedGrandChild ( entity me )

Definition at line 358 of file container.qc.

References best, entity(), and NULL.

     {
         entity e, e2;
         entity best;
 
         best = NULL;
 
         for (e = me.firstChild; e; e = e.nextSibling)
         {
             if (e.instanceOfContainer)
             {
                 e2 = e.preferredFocusedGrandChild(e);
                 if (e2)
                     if (!best || best.preferredFocusPriority < e2.preferredFocusPriority) best = e2;
             }
             if (e)
                 if (!best || best.preferredFocusPriority < e.preferredFocusPriority) best = e;
         }
 
         return best;
     }

Here is the call graph for this function:

◆ Container_removeItem()

void Container_removeItem	(	entity	me,
		entity	other
	)

Definition at line 270 of file container.qc.

References entity(), error(), and NULL.

     {
         if (other.parent != me) error("Can't remove from wrong container!");
 
         if (other.focusable) me.focusable -= 1;
 
         other.parent = NULL;
 
         entity n, p;
         n = other.nextSibling;
         p = other.prevSibling;
 
         if (p) p.nextSibling = n;
         else me.firstChild = n;
 
         if (n) n.prevSibling = p;
         else me.lastChild = p;
     }

Here is the call graph for this function:

◆ Container_resizeNotify()

void Container_resizeNotify	(	entity	me,
		vector	relOrigin,
		vector	relSize,
		vector	absOrigin,
		vector	absSize
	)

Definition at line 92 of file container.qc.

References Container_fontscale, Container_origin, and Container_size.

     {
         me.resizeNotifyLie(me, relOrigin, relSize, absOrigin, absSize, Container_origin, Container_size, Container_fontscale);
     }

◆ Container_resizeNotifyLie()

void Container_resizeNotifyLie	(	entity	me,
		vector	relOrigin,
		vector	relSize,
		vector	absOrigin,
		vector	absSize,
		.vector	originField,
		.vector	sizeField,
		.vector	fontScaleField
	)

Definition at line 60 of file container.qc.

References boxToGlobal(), boxToGlobalSize(), entity(), SUPER, and vector().

     {
         entity e;
         vector o, s;
         float d;
         for (e = me.firstChild; e; e = e.nextSibling)
         {
             o = e.(originField);
             s = e.(sizeField);
             me.enterLieSubitem(me, o, s, e.(fontScaleField), e.Container_alpha);
             e.resizeNotify(e, o, s, boxToGlobal(o, absOrigin, absSize), boxToGlobalSize(s, absSize));
             me.leaveSubitem(me);
         }
         do
         {
             d = 0;
             for (e = me.firstChild; e; e = e.nextSibling)
                 if (e.resized)
                 {
                     e.resized = 0;
                     d = 1;
                     o = e.(originField);
                     s = e.(sizeField);
                     me.enterLieSubitem(me, o, s, e.(fontScaleField), e.Container_alpha);
                     e.resizeNotify(e, o, s, boxToGlobal(o, absOrigin, absSize), boxToGlobalSize(s, absSize));
                     me.leaveSubitem(me);
                 }
         }
         while (d);
         SUPER(Container).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
     }

Here is the call graph for this function:

◆ Container_saveFocus()

void Container_saveFocus ( entity me )

Definition at line 323 of file container.qc.

     {
         me.savedFocus = me.focusedChild;
 
         if (me.focusedChild.instanceOfContainer) me.focusedChild.saveFocus(me.focusedChild);
     }

◆ Container_setAlphaOf()

void Container_setAlphaOf	(	entity	me,
		entity	other,
		float	theAlpha
	)

Definition at line 47 of file container.qc.

     {
         if (theAlpha <= 0)
         {
             if (other.Container_alpha > 0) other.hideNotify(other);
         }
         else  // value > 0
         {
             if (other.Container_alpha <= 0) other.showNotify(other);
         }
         other.Container_alpha = theAlpha;
     }

◆ Container_setFocus()

void Container_setFocus	(	entity	me,
		entity	other
	)

Definition at line 289 of file container.qc.

References error(), NULL, and other.

Referenced by m_activate_window(), and XonoticScrollPanel::XonoticScrollPanel ::setFocus().

     {
         if (me.focusedChild == other) return;
 
         if (me.focusedChild)
         {
             me.focusedChild.focused = 0;
             me.focusedChild.focusLeave(me.focusedChild);
             me.focusedChild = NULL;
         }
 
         if (other)
         {
             if (!me.focused) error("Trying to set focus in a non-focused control!");
 
             if (me.savedFocus)
             {
                 me.focusedChild = me.savedFocus;
                 me.savedFocus = NULL;
                 me.focusedChild.focused = 1;
                 me.focusedChild.focusEnter(me.focusedChild);
 
                 if (me.focusedChild.instanceOfContainer)
                     me.focusedChild.setFocus(me.focusedChild, me.focusedChild.savedFocus);
             }
             else
             {
                 me.focusedChild = other;
                 me.focusedChild.focused = 1;
                 me.focusedChild.focusEnter(me.focusedChild);
             }
         }
     }

Here is the call graph for this function:

Here is the caller graph for this function:

◆ Container_showNotify()

void Container_showNotify ( entity me )

Definition at line 29 of file container.qc.

References entity().

     {
         entity e;
         if (me.shown) return;
         me.shown = 1;
         for (e = me.firstChild; e; e = e.nextSibling)
             if (e.Container_alpha > 0) e.showNotify(e);
     }

Here is the call graph for this function:

Functions

Function Documentation

◆ Container_addItem()

◆ Container_addItemCentered()

◆ Container_addItemRightCentered()

◆ Container_draw()

◆ Container_enterLieSubitem()

◆ Container_enterSubitem()

◆ Container_focusLeave()

◆ Container_hideNotify()

◆ Container_itemFromPoint()

◆ Container_keyDown()

◆ Container_keyUp()

◆ Container_leaveSubitem()

◆ Container_mouseDrag()

◆ Container_mouseMove()

◆ Container_mouseRelease()

◆ Container_moveItemAfter()

◆ Container_preferredFocusedGrandChild()

◆ Container_removeItem()

◆ Container_resizeNotify()

◆ Container_resizeNotifyLie()

◆ Container_saveFocus()

◆ Container_setAlphaOf()

◆ Container_setFocus()

◆ Container_showNotify()