borderimage.qc File Reference

#include "borderimage.qh"
#include "nexposee.qh"
#include "dialog.qh"

Include dependency graph for borderimage.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
void	BorderImage_configureBorderImage (entity me, string theTitle, float sz, vector theColor, string path, float theBorderHeight)
void	BorderImage_draw (entity me)
void	BorderImage_recalcPositionWithText (entity me, string t)
void	BorderImage_resizeNotify (entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)

Function Documentation

BorderImage_configureBorderImage()

void BorderImage_configureBorderImage	(	entity	me,
		string	theTitle,
		float	sz,
		vector	theColor,
		string	path,
		float	theBorderHeight
	)

Definition at line 43 of file borderimage.qc.

    {
        me.configureLabel(me, theTitle, sz, 0.5);
        me.src = path;
        me.color = theColor;
        me.borderHeight = theBorderHeight;
    }

BorderImage_draw()

void BorderImage_draw

(

entity

me

)

Definition at line 50 of file borderimage.qc.

References boxToGlobalSize(), draw_BorderPicture(), draw_fontscale, globalToBoxSize(), SUPER, and vector().

    {
        if (me.src) draw_BorderPicture('0 0 0', me.src, '1 1 0', me.color, 1, me.borderVec);

        if (me.fontSize > 0)
        {
            if (me.recalcPos) me.recalcPositionWithText(me, me.text);

            if (me.isNexposeeTitleBar)
            {
                vector ro, rf, df;

                // me.parent.Nexposee_animationFactor 0 (small) or 1 (full)
                // default values are for 1
                ro = me.realOrigin;
                rf = me.realFontSize;
                df = draw_fontscale;
                me.realOrigin = ro * me.parent.Nexposee_animationFactor + me.realOrigin_Nexposeed * (1 - me.parent.Nexposee_animationFactor);
                me.realFontSize = rf * me.parent.Nexposee_animationFactor + me.realFontSize_Nexposeed * (1 - me.parent.Nexposee_animationFactor);
                draw_fontscale = globalToBoxSize(boxToGlobalSize(df, me.realFontSize), rf);

                SUPER(BorderImage).draw(me);

                // me.Nexposee_animationState 0 (small) or 1 (full)
                // default values are for 1
                me.realOrigin = ro;
                me.realFontSize = rf;
                draw_fontscale = df;
            }
            else
            {
                SUPER(BorderImage).draw(me);
            }
        }
        else
        {
            SUPER(BorderImage).draw(me);
        }
    }

Here is the call graph for this function:

BorderImage_recalcPositionWithText()

void BorderImage_recalcPositionWithText	(	entity	me,
		string	t
	)

Definition at line 5 of file borderimage.qc.

References boxToGlobal(), boxToGlobalSize(), conheight, conwidth, eX, eY, SUPER, and vector().

    {
        if (me.isNexposeeTitleBar)
        {
            vector scrs;
            scrs = eX * conwidth + eY * conheight;
            me.resizeNotify(me, me.saveRelOrigin, me.saveRelSize, boxToGlobal(me.parent.Nexposee_smallOrigin, '0 0 0', scrs), boxToGlobalSize(me.parent.Nexposee_smallSize, scrs));
            SUPER(BorderImage).recalcPositionWithText(me, t);
            me.realOrigin_y = me.realFontSize.y * me.zoomedOutTitleBarPosition;
            me.realOrigin_Nexposeed = me.realOrigin;
            me.realFontSize_Nexposeed = me.realFontSize;
            me.resizeNotify(me, me.saveRelOrigin, me.saveRelSize, boxToGlobal(me.parent.Nexposee_initialOrigin, '0 0 0', scrs), boxToGlobalSize(me.parent.Nexposee_initialSize, scrs));
        }
        SUPER(BorderImage).recalcPositionWithText(me, t);
    }

Here is the call graph for this function:

BorderImage_resizeNotify()

void BorderImage_resizeNotify	(	entity	me,
		vector	relOrigin,
		vector	relSize,
		vector	absOrigin,
		vector	absSize
	)

Definition at line 20 of file borderimage.qc.

References SUPER.

    {
        me.isNexposeeTitleBar = 0;
        if (me.zoomedOutTitleBar)
            if (me.parent.parent.instanceOfNexposee)
                if (me.parent.instanceOfDialog)
                    if (me == me.parent.frame) me.isNexposeeTitleBar = 1;
        me.saveRelOrigin = relOrigin;
        me.saveRelSize = relSize;
        SUPER(BorderImage).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
        me.borderVec_x = me.borderHeight / absSize.x;
        me.borderVec_y = me.borderHeight / absSize.y;
        me.realOrigin_y = 0.5 * (me.borderVec.y - me.realFontSize.y);
        if (me.closeButton)
        {
            // move the close button to the right place
            me.closeButton.Container_origin = '1 0 0' * (1 - me.borderVec.x);
            me.closeButton.Container_size = me.borderVec;
            me.closeButton.color = me.color;
            me.closeButton.colorC = me.color;
            me.closeButton.colorF = me.color;
        }
    }