sv_random_items.qc File Reference

Source file that contains implementation of the random items mutator. More...

#include "sv_random_items.qh"

Include dependency graph for sv_random_items.qc:

Go to the source code of this file.

Functions
	MUTATOR_HOOKFUNCTION (random_items, BuildMutatorsString)
	MUTATOR_HOOKFUNCTION (random_items, BuildMutatorsPrettyString)
	MUTATOR_HOOKFUNCTION (random_items, FilterItem, CBC_ORDER_LAST)
	Hook that is called when an item is about to spawn. More...
	MUTATOR_HOOKFUNCTION (random_items, ItemTouched, CBC_ORDER_LAST)
	Hook that is called after the player has touched an item. More...
	MUTATOR_HOOKFUNCTION (random_items, PlayerDies)
	Hook which is called when the player dies. More...
string	RandomItems_GetItemReplacementClassNames (entity item)
	Returns list of classnames to replace a map item with. More...
string	RandomItems_GetRandomItemClassName (string prefix)
	Returns a random classname of the item. More...
string	RandomItems_GetRandomItemClassNameWithProperty (string prefix,.bool item_property)
	Returns a random classname of the item with specific property. More...
string	RandomItems_GetRandomVanillaItemClassName (string prefix, int types)
	Returns a random classname of the vanilla item. More...
entity	RandomItems_ReplaceMapItem (entity item)
	Replaces a map item. More...
void	RandomItems_SpawnLootItem (vector position)
	Spawns a random loot item. More...

Variables
float	autocvar_g_random_loot_max
	Maximum amount of loot items. More...
float	autocvar_g_random_loot_min
	Classnames to replace s with. More...
float	autocvar_g_random_loot_spread
	How far can loot be thrown. More...
float	autocvar_g_random_loot_time
	Amount of time the loot will stay. More...
bool	random_items_is_spawning = false
	Probability of random s spawning as loot. More...

Detailed Description

Source file that contains implementation of the random items mutator.

Author

Lyberta

Copyright

GNU GPLv2 or any later version.

Definition in file sv_random_items.qc.

Function Documentation

MUTATOR_HOOKFUNCTION() [1/5]

MUTATOR_HOOKFUNCTION	(	random_items	,
		BuildMutatorsString
	)

Definition at line 334 of file sv_random_items.qc.

References M_ARGV, and strcat().

{
    M_ARGV(0, string) = strcat(M_ARGV(0, string), ":random_items");
}

Here is the call graph for this function:

MUTATOR_HOOKFUNCTION() [2/5]

MUTATOR_HOOKFUNCTION	(	random_items	,
		BuildMutatorsPrettyString
	)

Definition at line 339 of file sv_random_items.qc.

References M_ARGV, and strcat().

{
    M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Random items");
}

Here is the call graph for this function:

MUTATOR_HOOKFUNCTION() [3/5]

MUTATOR_HOOKFUNCTION	(	random_items	,
		FilterItem	,
		CBC_ORDER_LAST
	)

Hook that is called when an item is about to spawn.

Definition at line 345 of file sv_random_items.qc.

References autocvar_g_random_items, entity(), Item_IsLoot(), M_ARGV, NULL, random_items_is_spawning, and RandomItems_ReplaceMapItem().

{
    //PrintToChatAll("FilterItem");
    if (!autocvar_g_random_items)
    {
        return false;
    }
    if (random_items_is_spawning == true)
    {
        return false;
    }
    entity item = M_ARGV(0, entity);
    if (Item_IsLoot(item))
    {
        return false;
    }
    if (RandomItems_ReplaceMapItem(item) == NULL)
    {
        return false;
    }
    return true;
}

Here is the call graph for this function:

MUTATOR_HOOKFUNCTION() [4/5]

MUTATOR_HOOKFUNCTION	(	random_items	,
		ItemTouched	,
		CBC_ORDER_LAST
	)

Hook that is called after the player has touched an item.

Definition at line 369 of file sv_random_items.qc.

References autocvar_g_random_items, entity(), Item_IsLoot(), Item_ScheduleRespawn(), M_ARGV, NULL, and RandomItems_ReplaceMapItem().

{
    //PrintToChatAll("ItemTouched");
    if (!autocvar_g_random_items)
    {
        return;
    }
    entity item = M_ARGV(0, entity);
    if (Item_IsLoot(item))
    {
        return;
    }
    entity new_item = RandomItems_ReplaceMapItem(item);
    if (new_item == NULL)
    {
        return;
    }
    Item_ScheduleRespawn(new_item);
    delete(item);
}

Here is the call graph for this function:

MUTATOR_HOOKFUNCTION() [5/5]

MUTATOR_HOOKFUNCTION	(	random_items	,
		PlayerDies
	)

Hook which is called when the player dies.

Definition at line 391 of file sv_random_items.qc.

References autocvar_g_random_loot, autocvar_g_random_loot_max, autocvar_g_random_loot_min, entity(), floor(), M_ARGV, random(), RandomItems_SpawnLootItem(), and vector().

{
    //PrintToChatAll("PlayerDies");
    if (!autocvar_g_random_loot)
    {
        return;
    }
    entity victim = M_ARGV(2, entity);
    vector loot_position = victim.origin + '0 0 32';
    int num_loot_items = floor(autocvar_g_random_loot_min + random() *
        autocvar_g_random_loot_max);
    for (int item_index = 0; item_index < num_loot_items; ++item_index)
    {
        RandomItems_SpawnLootItem(loot_position);
    }
}

Here is the call graph for this function:

RandomItems_GetItemReplacementClassNames()

string RandomItems_GetItemReplacementClassNames

(

entity

item

)

Returns list of classnames to replace a map item with.

Parameters

[in]

item

Item to inspect.

Returns

List of classnames to replace a map item with.

Definition at line 200 of file sv_random_items.qc.

References cvar_string(), CVAR_TYPEFLAG_EXISTS, and LOG_WARNF.

Referenced by RandomItems_ReplaceMapItem().

{
    string cvar_name = sprintf("g_random_items_replace_%s", item.classname);
    if (!(cvar_type(cvar_name) & CVAR_TYPEFLAG_EXISTS))
    {
        LOG_WARNF("Random items: cvar %s doesn't exist.", cvar_name);
        return "";
    }
    return cvar_string(cvar_name);
}

Here is the call graph for this function:

Here is the caller graph for this function:

RandomItems_GetRandomItemClassName()

string RandomItems_GetRandomItemClassName

(

string

prefix

)

Returns a random classname of the item.

Parameters

[in]

prefix

Prefix of the cvars that hold probabilities.

Returns

Random classname of the item.

Note

This function will automatically detect gamemode and use cvars from that gamemode.

Definition at line 54 of file sv_random_items.qc.

References M_ARGV, MUTATOR_CALLHOOK, RANDOM_ITEM_TYPE_ALL, RandomItems_GetRandomItemClassName(), and RandomItems_GetRandomVanillaItemClassName().

Referenced by RandomItems_GetRandomItemClassName(), RandomItems_ReplaceMapItem(), and RandomItems_SpawnLootItem().

{
    if (MUTATOR_CALLHOOK(RandomItems_GetRandomItemClassName, prefix))
    {
        return M_ARGV(1, string);
    }
    return RandomItems_GetRandomVanillaItemClassName(prefix,
        RANDOM_ITEM_TYPE_ALL);
}

Here is the call graph for this function:

Here is the caller graph for this function:

RandomItems_GetRandomItemClassNameWithProperty()

string RandomItems_GetRandomItemClassNameWithProperty	(	string	prefix,
		.bool	item_property
	)

Returns a random classname of the item with specific property.

Parameters

[in]

prefix

Prefix of the cvars that hold probabilities.

Returns

Random classname of the item.

Definition at line 211 of file sv_random_items.qc.

References cvar(), CVAR_TYPEFLAG_EXISTS, FOREACH, ITEM_FLAG_NORMAL, Item_IsDefinitionAllowed(), LOG_WARNF, RandomSelection_AddString, RandomSelection_chosen_string, and RandomSelection_Init().

Referenced by RandomItems_GetRandomVanillaItemClassName().

{
    RandomSelection_Init();
    FOREACH(Items, it.item_property && (it.spawnflags & ITEM_FLAG_NORMAL) &&
        Item_IsDefinitionAllowed(it),
    {
        string cvar_name = sprintf("g_%s_%s_probability", prefix,
            it.m_canonical_spawnfunc);
        if (!(cvar_type(cvar_name) & CVAR_TYPEFLAG_EXISTS))
        {
            LOG_WARNF("Random items: cvar %s doesn't exist.", cvar_name);
            continue;
        }
        RandomSelection_AddString(it.m_canonical_spawnfunc, cvar(cvar_name), 1);
    });
    return RandomSelection_chosen_string;
}

Here is the call graph for this function:

Here is the caller graph for this function:

RandomItems_GetRandomVanillaItemClassName()

string RandomItems_GetRandomVanillaItemClassName	(	string	prefix,
		int	types
	)

Returns a random classname of the vanilla item.

Parameters

[in]	prefix	Prefix of the cvars that hold probabilities.
[in]	types	Bitmask of the types. See RANDOM_ITEM_TYPE constants.

Returns

Random classname of the vanilla item.

Note

This includes mutator items that don't change gameplay a lot such as jetpack and new toys.

Definition at line 64 of file sv_random_items.qc.

References cvar(), CVAR_TYPEFLAG_EXISTS, FOREACH, LOG_WARNF, RANDOM_ITEM_TYPE_ARMOR, RANDOM_ITEM_TYPE_HEALTH, RANDOM_ITEM_TYPE_POWERUP, RANDOM_ITEM_TYPE_RESOURCE, RANDOM_ITEM_TYPE_WEAPON, RandomItems_GetRandomItemClassNameWithProperty(), RandomSelection_AddFloat, RandomSelection_AddString, RandomSelection_chosen_float, RandomSelection_chosen_string, RandomSelection_Init(), and WEP_FLAG_MUTATORBLOCKED.

Referenced by RandomItems_GetRandomItemClassName().

{
    if (types == 0)
    {
        return "";
    }
    while (types != 0)
    {
        string cvar_name;
        RandomSelection_Init();
        if (types & RANDOM_ITEM_TYPE_HEALTH)
        {
            cvar_name = sprintf("g_%s_health_probability", prefix);
            if (!(cvar_type(cvar_name) & CVAR_TYPEFLAG_EXISTS))
            {
                LOG_WARNF("Random items: cvar %s doesn't exist.", cvar_name);
            }
            else
            {
                RandomSelection_AddFloat(RANDOM_ITEM_TYPE_HEALTH,
                    cvar(cvar_name), 1);
            }
        }
        if (types & RANDOM_ITEM_TYPE_ARMOR)
        {
            cvar_name = sprintf("g_%s_armor_probability", prefix);
            if (!(cvar_type(cvar_name) & CVAR_TYPEFLAG_EXISTS))
            {
                LOG_WARNF("Random items: cvar %s doesn't exist.", cvar_name);
            }
            else
            {
                RandomSelection_AddFloat(RANDOM_ITEM_TYPE_ARMOR,
                    cvar(cvar_name), 1);
            }
        }
        if (types & RANDOM_ITEM_TYPE_RESOURCE)
        {
            cvar_name = sprintf("g_%s_resource_probability", prefix);
            if (!(cvar_type(cvar_name) & CVAR_TYPEFLAG_EXISTS))
            {
                LOG_WARNF("Random items: cvar %s doesn't exist.", cvar_name);
            }
            else
            {
                RandomSelection_AddFloat(RANDOM_ITEM_TYPE_RESOURCE,
                    cvar(cvar_name), 1);
            }
        }
        if (types & RANDOM_ITEM_TYPE_WEAPON)
        {
            cvar_name = sprintf("g_%s_weapon_probability", prefix);
            if (!(cvar_type(cvar_name) & CVAR_TYPEFLAG_EXISTS))
            {
                LOG_WARNF("Random items: cvar %s doesn't exist.", cvar_name);
            }
            else
            {
                RandomSelection_AddFloat(RANDOM_ITEM_TYPE_WEAPON, cvar(cvar_name), 1);
            }
        }
        if (types & RANDOM_ITEM_TYPE_POWERUP)
        {
            cvar_name = sprintf("g_%s_powerup_probability", prefix);
            if (!(cvar_type(cvar_name) & CVAR_TYPEFLAG_EXISTS))
            {
                LOG_WARNF("Random items: cvar %s doesn't exist.", cvar_name);
            }
            else
            {
                RandomSelection_AddFloat(RANDOM_ITEM_TYPE_POWERUP, cvar(cvar_name), 1);
            }
        }
        int item_type = RandomSelection_chosen_float;
        string class_name = "";
        switch (item_type)
        {
            case RANDOM_ITEM_TYPE_HEALTH:
            {
                class_name = RandomItems_GetRandomItemClassNameWithProperty(
                    prefix, instanceOfHealth);
                break;
            }
            case RANDOM_ITEM_TYPE_ARMOR:
            {
                class_name = RandomItems_GetRandomItemClassNameWithProperty(
                    prefix, instanceOfArmor);
                break;
            }
            case RANDOM_ITEM_TYPE_RESOURCE:
            {
                class_name = RandomItems_GetRandomItemClassNameWithProperty(
                    prefix, instanceOfAmmo);
                break;
            }
            case RANDOM_ITEM_TYPE_WEAPON:
            {
                RandomSelection_Init();
                FOREACH(Weapons, it != WEP_Null &&
                    !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED),
                {
                    cvar_name = sprintf("g_%s_%s_probability", prefix,
                        it.m_canonical_spawnfunc);
                    if (!(cvar_type(cvar_name) & CVAR_TYPEFLAG_EXISTS))
                    {
                        LOG_WARNF("Random items: cvar %s doesn't exist.",
                            cvar_name);
                        continue;
                    }
                    RandomSelection_AddString(it.m_canonical_spawnfunc,
                        cvar(cvar_name), 1);
                });
                class_name = RandomSelection_chosen_string;
                break;
            }
            case RANDOM_ITEM_TYPE_POWERUP:
            {
                class_name = RandomItems_GetRandomItemClassNameWithProperty(
                    prefix, instanceOfPowerup);
                break;
            }
        }
        if (class_name != "")
        {
            return class_name;
        }
        types &= ~item_type;
    }
    return "";
}

Here is the call graph for this function:

Here is the caller graph for this function:

RandomItems_ReplaceMapItem()

entity RandomItems_ReplaceMapItem

(

entity

item

)

Replaces a map item.

Parameters

[in]

item

Item to replace.

Returns

Spawned item on success, NULL otherwise.

Definition at line 233 of file sv_random_items.qc.

References argv(), entity(), floor(), Item_Create(), Item_Initialize(), Item_ShouldKeepPosition(), MUTATOR_IS_ENABLED, NULL, random(), random_items_is_spawning, RandomItems_GetItemReplacementClassNames(), RandomItems_GetRandomItemClassName(), setorigin(), spawn(), strzone(), and tokenize_console.

Referenced by MUTATOR_HOOKFUNCTION().

{
    //PrintToChatAll(strcat("Replacing ", item.classname));
    string new_classnames = RandomItems_GetItemReplacementClassNames(item);
    if (new_classnames == "")
    {
        return NULL;
    }
    string new_classname;
    if (new_classnames == "random")
    {
        new_classname = RandomItems_GetRandomItemClassName("random_items");
        if (new_classname == "")
        {
            return NULL;
        }
    }
    else
    {
        int num_new_classnames = tokenize_console(new_classnames);
        if (num_new_classnames == 1)
        {
            new_classname = new_classnames;
        }
        else
        {
            int classname_index = floor(random() * num_new_classnames);
            new_classname = argv(classname_index);
        }
    }
    //PrintToChatAll(strcat("Replacing with ", new_classname));
    if (new_classname == item.classname)
    {
        return NULL;
    }
    random_items_is_spawning = true;
    entity new_item;
    if (!MUTATOR_IS_ENABLED(ok))
    {
        new_item = Item_Create(strzone(new_classname), item.origin,
            Item_ShouldKeepPosition(item));
        random_items_is_spawning = false;
        if (new_item == NULL)
        {
            return NULL;
        }
    }
    else
    {
        new_item = spawn();
        new_item.classname = strzone(new_classname);
        new_item.spawnfunc_checked = true;
        new_item.noalign = Item_ShouldKeepPosition(item);
        new_item.ok_item = true;
        Item_Initialize(new_item, new_classname);
        random_items_is_spawning = false;
        if (wasfreed(new_item))
        {
            return NULL;
        }
        setorigin(new_item, item.origin);
    }
    if (item.team)
    {
        new_item.team = item.team;
    }
    return new_item;
}

Here is the call graph for this function:

Here is the caller graph for this function:

RandomItems_SpawnLootItem()

void RandomItems_SpawnLootItem

(

vector

position

)

Spawns a random loot item.

Parameters

[in]

position

Position of the item.

Returns

No return.

Definition at line 305 of file sv_random_items.qc.

References autocvar_g_random_loot_spread, autocvar_g_random_loot_time, entity(), Item_CreateLoot(), Item_InitializeLoot(), MUTATOR_IS_ENABLED, random_items_is_spawning, RandomItems_GetRandomItemClassName(), randomvec(), spawn(), and vector().

Referenced by MUTATOR_HOOKFUNCTION().

{
    string class_name = RandomItems_GetRandomItemClassName("random_loot");
    if (class_name == "")
    {
        return;
    }
    vector spread = '0 0 0';
    spread.z = autocvar_g_random_loot_spread / 2;
    spread += randomvec() * autocvar_g_random_loot_spread;
    random_items_is_spawning = true;
    if (!MUTATOR_IS_ENABLED(ok))
    {
        Item_CreateLoot(class_name, position, spread,
            autocvar_g_random_loot_time);
    }
    else
    {
        entity item = spawn();
        item.ok_item = true;
        item.classname = class_name;
        Item_InitializeLoot(item, class_name, position, spread,
            autocvar_g_random_loot_time);
    }
    random_items_is_spawning = false;
}

Here is the call graph for this function:

Here is the caller graph for this function:

Variable Documentation

autocvar_g_random_loot_max

float autocvar_g_random_loot_max

Maximum amount of loot items.

Definition at line 28 of file sv_random_items.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_random_loot_min

float autocvar_g_random_loot_min

Classnames to replace s with.

string autocvar_g_random_items_replace_s; Probability of random s spawning in the map. float autocvar_g_random_items_s_probability; Probability of random s spawning in the map during overkill. float autocvar_g_random_items_overkill_s_probability; Minimum amount of loot items.

Definition at line 27 of file sv_random_items.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_random_loot_spread

float autocvar_g_random_loot_spread

How far can loot be thrown.

Definition at line 30 of file sv_random_items.qc.

Referenced by RandomItems_SpawnLootItem().

autocvar_g_random_loot_time

float autocvar_g_random_loot_time

Amount of time the loot will stay.

Definition at line 29 of file sv_random_items.qc.

Referenced by RandomItems_SpawnLootItem().

random_items_is_spawning

bool random_items_is_spawning = false

Probability of random s spawning as loot.

float autocvar_g_random_loot_s_probability; Probability of random s spawning as loot during overkill. float autocvar_g_random_loot_overkill_s_probability; Holds whether random item is spawning. Used to prevent infinite recursion.

Definition at line 42 of file sv_random_items.qc.

Referenced by MUTATOR_HOOKFUNCTION(), RandomItems_ReplaceMapItem(), and RandomItems_SpawnLootItem().