menu_cmd.qc File Reference

#include "menu_cmd.qh"
#include "../menu.qh"
#include "../item.qh"
#include <menu/mutators/_mod.qh>
#include <common/command/_mod.qh>

Include dependency graph for menu_cmd.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
void	_dumptree_close (entity pass, entity me)
void	_dumptree_open (entity pass, entity me)
void	GameCommand (string theCommand)
float	updateConwidths (float width, float height, float pixelheight)

Variables
string	_dumptree_space
entity	firstChild
entity	nextSibling

Function Documentation

_dumptree_close()

void _dumptree_close	(	entity	pass,
		entity	me
	)

Definition at line 30 of file menu_cmd.qc.

References _dumptree_space, height, print(), strlen(), substring(), and updateConwidths().

Referenced by GameCommand().

{
    if (me.firstChild)
    {
        _dumptree_space = substring(_dumptree_space, 0, strlen(_dumptree_space) - 2);
        print(_dumptree_space, "}\n");
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

_dumptree_open()

void _dumptree_open	(	entity	pass,
		entity	me
	)

Definition at line 13 of file menu_cmd.qc.

References _dumptree_space, etos(), print(), and strcat().

Referenced by GameCommand().

{
    string s;
    s = me.toString(me);
    if (s == "") s = me.classname;
    else s = strcat(me.classname, ": ", s);
    print(_dumptree_space, etos(me), " (", s, ")");
    if (me.firstChild)
    {
        print(" {\n");
        _dumptree_space = strcat(_dumptree_space, "  ");
    }
    else
    {
        print("\n");
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

GameCommand()

void GameCommand

(

string

theCommand

)

Definition at line 41 of file menu_cmd.qc.

References _dumptree_close(), _dumptree_open(), _dumptree_space, argv(), cvar(), depthfirst(), firstChild, FOREACH_ENTITY_ORDERED, GenericCommand(), GenericCommand_macro_help(), isdemo(), LOG_HELP, LOG_INFO, m_goto(), m_play_click_sound(), m_sync(), main, MENU_SOUND_OPEN, MUTATOR_CALLHOOK, nextSibling, NULL, parent, strcat(), string_null, tokenize_console, and updateConwidths().

{
    int argc = tokenize_console(theCommand);
    string ss = strtolower(argv(0));

    // TODO port these commands to the command system
    if (argv(0) == "help" || argc == 0)
    {
        LOG_HELP("Usage:^3 menu_cmd <command> [<item>], where possible commands are:");
        LOG_HELP("  'sync' reloads all cvars on the current menu page");
        LOG_HELP("  'directmenu' shows the menu window named <item> (or the menu window containing an item named <item>)");
        LOG_HELP("   if <item> is not specified it shows the list of available items in the console");
        LOG_HELP("  'dumptree' dumps the state of the menu as a tree to the console");

        LOG_HELP("\nGeneric commands shared by all programs:");
        GenericCommand_macro_help();

        return;
    }

    if (GenericCommand(theCommand)) return;

    if (argv(0) == "sync")
    {
        m_sync();
        return;
    }

    if (argv(0) == "update_conwidths_before_vid_restart")
    {
        updateConwidths(cvar("vid_width"), cvar("vid_height"), cvar("vid_pixelheight"));
        return;
    }

    if (argv(0) == "directmenu" || argv(0) == "directpanelhudmenu")
    {
        string filter = string_null;
        if (argv(0) == "directpanelhudmenu") filter = "HUD";

        if (argc == 1)
        {
            LOG_HELP("Available items:");

            FOREACH_ENTITY_ORDERED(it.name != "", {
                if (it.classname == "vtbl") continue;
                string s = it.name;
                if (filter)
                {
                    if (!startsWith(s, filter)) continue;
                    s = substring(s, strlen(filter), strlen(s) - strlen(filter));
                }
                LOG_HELP(" ", s);
            });
        }
        else if (argc == 2 && !isdemo())     // don't allow this command in demos
        {
            m_play_click_sound(MENU_SOUND_OPEN);
            m_goto(strcat(filter, argv(1))); // switch to a menu item
        }
        return;
    }

    if (argv(0) == "skinselect")
    {
        m_goto("skinselector");
        return;
    }

    if (argv(0) == "languageselect")
    {
        m_goto("languageselector");
        return;
    }

    if (argv(0) == "videosettings")
    {
        m_goto("videosettings");
        return;
    }

    if (argv(0) == "dumptree")
    {
        _dumptree_space = "";
        depthfirst(main, parent, firstChild, nextSibling, _dumptree_open, _dumptree_close, NULL);
        return;
    }

    if(MUTATOR_CALLHOOK(Menu_ConsoleCommand, ss, argc, theCommand)) // handled by a mutator
        return;

    LOG_INFO("Invalid command. For a list of supported commands, try menu_cmd help.");
}

Here is the call graph for this function:

updateConwidths()

float updateConwidths	(	float	width,
		float	height,
		float	pixelheight
	)

Definition at line 8 of file slider_resolution.qc.

Referenced by _dumptree_close(), GameCommand(), and UpdateConWidthHeight().

{
    vector r, c;
    float minfactor, maxfactor;
    float sz, f;

    sz = cvar("menu_vid_scale");
    if (sz < -1)
        return 0;  // No recalculation.

    // Save off current settings.
    cvar_set("_menu_vid_width", ftos(width));
    cvar_set("_menu_vid_height", ftos(height));
    cvar_set("_menu_vid_pixelheight", ftos(pixelheight));
    cvar_set("_menu_vid_desktopfullscreen", cvar_string("vid_desktopfullscreen"));

    // engine is handling conwidth calculations!
    if((cvar_type("vid_conwidthauto") & CVAR_TYPEFLAG_ENGINE) && cvar("vid_conwidthauto"))
    {
        if(vid_conwidth != cvar("vid_conwidth") || vid_conheight != cvar("vid_conheight"))
        {
            // Please reload resolutions list and such stuff.
            XonoticResolutionSlider_DataHasChanged = true;
            vid_conwidth = cvar("vid_conwidth");
            vid_conheight = cvar("vid_conheight");
            return 1;
        }
        return 0; // No recalculation
    }

    r_x = width;
    r_y = height;
    r_z = pixelheight;

    // calculate the base resolution
    c_z = 0;
    c_x = 800;
    c_y = c.x * r.y * r.z / r.x;
    if(c.y < 600)
    {
        c_y = 600;
        c_x = c.y * r.x / (r.y * r.z);
    }

    f = min(r.x / c.x, r.y / c.y);
    if(f < 1)
        c = c * f; // ensures that c_x <= r_x and c_y <= r_y

    minfactor = min(1, 640 / c.x);            // can be > 1 only if c_x is <640
    maxfactor = max(1, r.x / c.x, r.y / c.y); // can be < 1 only if r_x < c_x and r_y < c_y
    LOG_TRACE("min factor: ", ftos(minfactor));
    LOG_TRACE("max factor: ", ftos(maxfactor));

    if(sz < 0)
        f = 1 - (maxfactor - 1) * sz;
    else if(sz > 0)
        f = 1 + (minfactor - 1) * sz;
    else
        f = 1;
    c = c * f; // fteqcc fail

    c_x = rint(c.x);
    c_y = rint(c.y);

    // Please reload resolutions list and such stuff.
    XonoticResolutionSlider_DataHasChanged = true;

    if (c.x != cvar("vid_conwidth") || c.y != cvar("vid_conheight"))
    {
        cvar_set("vid_conwidth", ftos(c.x));
        cvar_set("vid_conheight", ftos(c.y));
        return 1;
    }
    return 0;
}

Here is the caller graph for this function:

Variable Documentation

_dumptree_space

string _dumptree_space

Definition at line 12 of file menu_cmd.qc.

Referenced by _dumptree_close(), _dumptree_open(), and GameCommand().

firstChild

entity firstChild

Definition at line 10 of file menu_cmd.qc.

Referenced by GameCommand(), and getNewChildValue().

nextSibling

entity nextSibling

Definition at line 10 of file menu_cmd.qc.

Referenced by GameCommand().