menu.qc File Reference

#include "menu.qh"
#include "item.qh"
#include "anim/animhost.qh"
#include "item/dialog.qh"
#include "item/listbox.qh"
#include "item/nexposee.qh"
#include "xonotic/commandbutton.qh"
#include "xonotic/mainwindow.qh"
#include "xonotic/serverlist.qh"
#include "xonotic/slider_resolution.qh"
#include "xonotic/util.qh"
#include <common/items/_mod.qh>
#include <common/weapons/_all.qh>
#include <common/mapinfo.qh>
#include <common/mutators/base.qh>

Include dependency graph for menu.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Enumerations
enum	{   SCALEMODE_CROP, SCALEMODE_LETTERBOX, SCALEMODE_WIDTH, SCALEMODE_HEIGHT,   SCALEMODE_STRETCH }

Functions
void	draw_Picture_Aligned (vector algn, float scalemode, string img, float a)
void	draw_reset_cropped ()
void	draw_reset_full ()
void	drawBackground (string img, float a, string algn, float force1)
string	gettooltip ()
void	m_activate_window (entity wnd)
bool	m_allocatetooltipbox (vector pos)
void	m_display ()
void	m_draw (float width, float height)
entity	m_findtooltipitem (entity root, vector pos)
void	m_focus_item_chain (entity outermost, entity innermost)
void	m_gamestatus ()
void	m_goto (string itemname)
void	m_hide ()
void	m_init ()
void	m_init_delayed ()
void	m_keydown (float key, float ascii)
void	m_keyup (float key, float ascii)
void	m_play_click_sound (string soundfile)
void	m_play_focus_sound ()
void	m_setpointerfocus (entity wnd)
void	m_sync ()
bool	m_testmousetooltipbox (vector pos)
bool	m_testtooltipbox (vector tooltippos)
void	m_toggle (int mode)
void	m_tooltip (vector pos)
void	Shutdown ()
void	UpdateConWidthHeight (float w, float h, float p)

Variables
float	autocvar_menu_force_on_disconnection
float	conheight_s
string	controlledCvar
float	conwidth_s
string	m_goto_buffer
const float	MENU_ASPECT = 1280 / 1024
int	menu_tooltips
int	menu_tooltips_old
float	menuAlpha
bool	menuInitialized
float	menuLogoAlpha
int	menuMouseMode
vector	menuMousePos
bool	menuNotTheFirstFrame
float	menuPrevTime
int	menuShiftState
float	menuTooltipAlpha
vector	menuTooltipAveragedMousePos
entity	menuTooltipItem
vector	menuTooltipOrigin
vector	menuTooltipSize
int	menuTooltipState
string	menuTooltipText
int	mouseButtonsPressed
float	prevMenuAlpha
float	realconheight
float	realconwidth
float	vidheight_s
float	vidpixelheight_s
float	vidwidth_s

Enumeration Type Documentation

anonymous enum

anonymous enum

Enumerator
SCALEMODE_CROP
SCALEMODE_LETTERBOX
SCALEMODE_WIDTH
SCALEMODE_HEIGHT
SCALEMODE_STRETCH

Definition at line 296 of file menu.qc.

     {
    SCALEMODE_CROP,
    SCALEMODE_LETTERBOX,
    SCALEMODE_WIDTH,
    SCALEMODE_HEIGHT,
    SCALEMODE_STRETCH,
};

Function Documentation

draw_Picture_Aligned()

void draw_Picture_Aligned	(	vector	algn,
		float	scalemode,
		string	img,
		float	a
	)

Definition at line 303 of file menu.qc.

References draw_Picture(), draw_PictureSize(), draw_scale, eX, eY, SCALEMODE_CROP, SCALEMODE_HEIGHT, SCALEMODE_LETTERBOX, SCALEMODE_STRETCH, SCALEMODE_WIDTH, and vector().

Referenced by drawBackground().

{
    vector sz = draw_PictureSize(img);
    bool width_is_larger = (sz.x * draw_scale.y >= sz.y * draw_scale.x);
    vector isz_w = '1 0 0' + '0 1 0' * ((sz.y / sz.x) * (draw_scale.x / draw_scale.y));
    vector isz_h = '0 1 0' + '1 0 0' * ((sz.x / sz.y) * (draw_scale.y / draw_scale.x));
    vector isz;
    switch (scalemode)
    {
        default:
        case SCALEMODE_CROP:
            isz = (width_is_larger ? isz_h : isz_w);
            break;
        case SCALEMODE_LETTERBOX:
            isz = (width_is_larger ? isz_w : isz_h);
            break;
        case SCALEMODE_WIDTH:
            isz = isz_w;
            break;
        case SCALEMODE_HEIGHT:
            isz = isz_h;
            break;
        case SCALEMODE_STRETCH:
            isz = '1 1 0';
            break;
    }
    vector org = eX * (algn.x * (1 - isz.x)) + eY * (algn.y * (1 - isz.y));
    draw_Picture(org, img, isz, '1 1 1', a);
}

Here is the call graph for this function:

Here is the caller graph for this function:

draw_reset_cropped()

void draw_reset_cropped

(

)

Definition at line 109 of file menu.qc.

References conheight, conwidth, draw_reset(), realconheight, and realconwidth.

Referenced by m_draw(), m_init_delayed(), m_keydown(), m_keyup(), preMenuInit(), and UpdateConWidthHeight().

{
    draw_reset(conwidth, conheight, 0.5 * (realconwidth - conwidth), 0.5 * (realconheight - conheight));
}

Here is the call graph for this function:

Here is the caller graph for this function:

draw_reset_full()

void draw_reset_full

(

)

Definition at line 113 of file menu.qc.

References draw_reset(), realconheight, and realconwidth.

Referenced by m_draw().

{
    draw_reset(realconwidth, realconheight, 0, 0);
}

Here is the call graph for this function:

Here is the caller graph for this function:

drawBackground()

void drawBackground	(	string	img,
		float	a,
		string	algn,
		float	force1
	)

Definition at line 333 of file menu.qc.

References draw_Picture_Aligned(), ftos(), LABEL, main, random(), SCALEMODE_CROP, SCALEMODE_HEIGHT, SCALEMODE_LETTERBOX, SCALEMODE_STRETCH, SCALEMODE_WIDTH, strcat(), strlen(), substring(), v, and vector().

Referenced by m_draw().

{
    if (main.mainNexposee.ModalController_state == 0) return;
    vector v = '0 0 0';
    int scalemode = SCALEMODE_CROP;
    int len = strlen(algn);
    for (int i = 0, l = 0; i < len; ++i)
    {
        string c = substring(algn, i, 1);
        switch (c)
        {
            case "c":
                scalemode = SCALEMODE_CROP;
                goto nopic;
            case "l":
                scalemode = SCALEMODE_LETTERBOX;
                goto nopic;
            case "h":
                scalemode = SCALEMODE_HEIGHT;
                goto nopic;
            case "w":
                scalemode = SCALEMODE_WIDTH;
                goto nopic;
            case "s":
                scalemode = SCALEMODE_STRETCH;
                goto nopic;
            case "1": case "4": case "7":
                v.x = 0.0;
                break;
            case "2": case "5": case "8":
                v.x = 0.5;
                break;
            case "3": case "6": case "9":
                v.x = 1.0;
                break;
            default:
                v.x = random();
                break;
        }
        switch (c)
        {
            case "7": case "8": case "9":
                v.y = 0.0;
                break;
            case "4": case "5": case "6":
                v.y = 0.5;
                break;
            case "1": case "2": case "3":
                v.y = 1.0;
                break;
            default:
                v.y = random();
                break;
        }
        if (l == 0)
        {
            draw_Picture_Aligned(v, scalemode, img, a);
        }
        else if (force1)
        {
            // force all secondary layers to use alpha 1. Prevents ugly issues
            // with overlap. It's a flag because it cannot be used for the
            // ingame background
            draw_Picture_Aligned(v, scalemode, strcat(img, "_l", ftos(l + 1)), 1);
        }
        else
        {
            draw_Picture_Aligned(v, scalemode, strcat(img, "_l", ftos(l + 1)), a);
        }
        ++l;
LABEL(nopic)
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

gettooltip()

string gettooltip

(

)

Definition at line 503 of file menu.qc.

References cvar_string(), getCvarsMulti(), menu_tooltips, menuTooltipItem, and strcat().

Referenced by m_tooltip().

{
    if (menu_tooltips == 2)
    {
        string s;
        if (menuTooltipItem.controlledCvar)
        {
            string cvar_list = getCvarsMulti(menuTooltipItem);
            if (cvar_list)
                cvar_list = strcat(menuTooltipItem.controlledCvar, " ", cvar_list);
            else
                cvar_list = menuTooltipItem.controlledCvar;
            s = strcat("[", cvar_list, " \"", cvar_string(menuTooltipItem.controlledCvar), "\"]");
        }
        else if (menuTooltipItem.onClickCommand)
        {
            s = strcat("<", menuTooltipItem.onClickCommand, ">");
        }
        else
        {
            return menuTooltipItem.tooltip;
        }
        if (menuTooltipItem.tooltip) return strcat(menuTooltipItem.tooltip, " ", s);
        return s;
    }
    return menuTooltipItem.tooltip;
}

Here is the call graph for this function:

Here is the caller graph for this function:

m_activate_window()

void m_activate_window

(

entity

wnd

)

Definition at line 910 of file menu.qc.

References Container_setFocus(), entity(), NULL, and TabButton_Click().

Referenced by m_goto().

{
    entity par = wnd.parent;
    if (par) m_activate_window(par);

    if (par.instanceOfModalController)
    {
        if (wnd.tabSelectingButton)
            // tabs
            TabButton_Click(wnd.tabSelectingButton, wnd);
        else
            // root
            par.initializeDialog(par, wnd);
    }
    else if (par.instanceOfNexposee)
    {
        // nexposee (sorry for violating abstraction here)
        par.selectedChild = wnd;
        par.animationState = 1;
        Container_setFocus(par, NULL);
    }
    else if (par.instanceOfContainer)
    {
        // other containers
        if (par.focused) par.setFocus(par, wnd);
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

m_allocatetooltipbox()

bool m_allocatetooltipbox

(

vector

pos

)

Definition at line 432 of file menu.qc.

References conheight, conwidth, m_testtooltipbox(), menuTooltipSize, v, and vector().

Referenced by m_tooltip().

{
    vector avoidplus;
    avoidplus.x = (SKINAVOID_TOOLTIP_x + SKINSIZE_CURSOR_x - SKINOFFSET_CURSOR_x * SKINSIZE_CURSOR_x) / conwidth;
    avoidplus.y = (SKINAVOID_TOOLTIP_y + SKINSIZE_CURSOR_y - SKINOFFSET_CURSOR_y * SKINSIZE_CURSOR_y) / conheight;
    avoidplus.z = 0;

    vector avoidminus;
    avoidminus.x = (SKINAVOID_TOOLTIP_x + SKINOFFSET_CURSOR_x * SKINSIZE_CURSOR_x) / conwidth + menuTooltipSize.x;
    avoidminus.y = (SKINAVOID_TOOLTIP_y + SKINOFFSET_CURSOR_y * SKINSIZE_CURSOR_y) / conheight + menuTooltipSize.y;
    avoidminus.z = 0;

    // bottom right
    vector v = pos + avoidplus;
    if (m_testtooltipbox(v)) return true;

    // bottom center
    v.x = pos.x - menuTooltipSize.x * 0.5;
    if (m_testtooltipbox(v)) return true;

    // bottom left
    v.x = pos.x - avoidminus.x;
    if (m_testtooltipbox(v)) return true;

    // top left
    v.y = pos.y - avoidminus.y;
    if (m_testtooltipbox(v)) return true;

    // top center
    v.x = pos.x - menuTooltipSize.x * 0.5;
    if (m_testtooltipbox(v)) return true;

    // top right
    v.x = pos.x + avoidplus.x;
    if (m_testtooltipbox(v)) return true;

    return false;
}

Here is the call graph for this function:

Here is the caller graph for this function:

m_display()

void m_display

(

)

Definition at line 854 of file menu.qc.

References KEY_MENU, main, Menu_Active, menuInitialized, menuMouseMode, menuMousePos, mouseButtonsPressed, MT_CLIENT, MT_MENU, setkeydest(), and setmousetarget().

Referenced by m_goto(), m_init(), m_init_delayed(), and m_toggle().

{
    Menu_Active = true;
    setkeydest(KEY_MENU);
    setmousetarget((menuMouseMode ? MT_CLIENT : MT_MENU));

    if (!menuInitialized) return;

    if (mouseButtonsPressed) main.mouseRelease(main, menuMousePos);
    mouseButtonsPressed = 0;

    main.focusEnter(main);
    main.showNotify(main);
}

Here is the call graph for this function:

Here is the caller graph for this function:

m_draw()

void m_draw	(	float	width,
		float	height
	)

Definition at line 676 of file menu.qc.

References anim, autocvar_menu_force_on_disconnection, bound(), clientstate(), CS_DISCONNECTED, cvar(), cvar_set(), draw_alpha, draw_drawMousePointer(), draw_Fill(), draw_reset_cropped(), draw_reset_full(), draw_scale, draw_shift, drawBackground(), eX, execute_next_frame(), eY, frametime, ftos(), GAME_CONNECTED, GAME_ISSERVER, gamestatus, getkeydest(), getmousepos(), getmousetarget(), gettime(), globalToBox(), globalToBoxSize(), IL_ENDFRAME(), KEY_MENU, KEY_MENU_GRABBED, keyGrabber, localcmd, m_gamestatus(), m_hide(), m_init_delayed(), m_toggle(), m_tooltip(), main, max(), Menu_Active, menuAlpha, menuInitialized, menuLogoAlpha, menuMouseMode, menuMousePos, menuNotTheFirstFrame, menuPrevTime, min(), mouseButtonsPressed, MT_CLIENT, MT_MENU, postMenuDraw(), preMenuDraw(), prevMenuAlpha, realconheight, realconwidth, setkeydest(), time, UpdateConWidthHeight(), and vector().

{
    if (autocvar_menu_force_on_disconnection > 0)
    {
        static float connected_time;
        if (clientstate() == CS_DISCONNECTED)
        {
            if (connected_time && time - connected_time > autocvar_menu_force_on_disconnection)
            {
                m_toggle(true);
                connected_time = 0;
            }
        }
        else
            connected_time = time;
    }

    m_gamestatus();

    execute_next_frame();

    menuMouseMode = cvar("menu_mouse_absolute");

    if (anim) anim.tickAll(anim);

    UpdateConWidthHeight(width, height, cvar("vid_pixelheight"));

    if (!menuInitialized)
    {
        // TODO draw an info image about this situation
        m_init_delayed();
        return;
    }
    if (!menuNotTheFirstFrame)
    {
        menuNotTheFirstFrame = true;
        if (Menu_Active && !cvar("menu_video_played"))
        {
            localcmd("cd loop $menu_cdtrack\n");
            // TODO: use this when we have a welcome sound
            //localcmd("cd loop $menu_cdtrack; play sound/announcer/default/welcome.wav\n");
            menuLogoAlpha = -0.8;  // no idea why, but when I start this at zero, it jumps instead of fading FIXME
        }
        // ALWAYS set this cvar; if we start but menu is not active, this means we want no background music!
        localcmd("set menu_video_played 1\n");
    }

    float t = gettime();
    float realFrametime = frametime = min(0.2, t - menuPrevTime);
    menuPrevTime = t;
    time += frametime;

    t = cvar("menu_slowmo");
    if (t)
    {
        frametime *= t;
        realFrametime *= t;
    }
    else
    {
        t = 1;
    }

    if (Menu_Active)
    {
        if (getmousetarget() == (menuMouseMode ? MT_CLIENT : MT_MENU)
            && (getkeydest() == KEY_MENU || getkeydest() == KEY_MENU_GRABBED))
                setkeydest(keyGrabber ? KEY_MENU_GRABBED : KEY_MENU);
        else m_hide();
    }

    if (cvar("cl_capturevideo")) frametime = t / cvar("cl_capturevideo_fps");  // make capturevideo work smoothly

    prevMenuAlpha = menuAlpha;
    if (Menu_Active)
    {
        if (menuAlpha == 0 && menuLogoAlpha < 2)
        {
            menuLogoAlpha += 2 * frametime;
        }
        else
        {
            menuAlpha = min(1, menuAlpha + 5 * frametime);
            menuLogoAlpha = 2;
        }
    }
    else
    {
        menuAlpha = max(0, menuAlpha - 5 * frametime);
        menuLogoAlpha = 2;
    }

    draw_reset_cropped();

    if (!(gamestatus & (GAME_CONNECTED | GAME_ISSERVER)))
    {
        if (menuLogoAlpha > 0)
        {
            draw_reset_full();
            draw_Fill('0 0 0', '1 1 0', SKINCOLOR_BACKGROUND, 1);
            drawBackground(SKINGFX_BACKGROUND, bound(0, menuLogoAlpha, 1), SKINALIGN_BACKGROUND, true);
            draw_reset_cropped();
            if (menuAlpha <= 0 && SKINALPHA_CURSOR_INTRO > 0)
            {
                draw_alpha = SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1);
                draw_drawMousePointer(menuMousePos);
                draw_alpha = 1;
            }
        }
    }
    else if (SKINALPHA_BACKGROUND_INGAME)
    {
        if (menuAlpha > 0)
        {
            draw_reset_full();
            drawBackground(SKINGFX_BACKGROUND_INGAME, menuAlpha * SKINALPHA_BACKGROUND_INGAME,
                SKINALIGN_BACKGROUND_INGAME, false);
            draw_reset_cropped();
        }
    }

    if (menuAlpha != prevMenuAlpha) cvar_set("_menu_alpha", ftos(menuAlpha));

    draw_reset_cropped();
    preMenuDraw();
    draw_reset_cropped();

    if (menuAlpha <= 0)
    {
        if (prevMenuAlpha > 0) main.initializeDialog(main, main.firstChild);
        draw_reset_cropped();
        postMenuDraw();
        return;
    }

    draw_alpha *= menuAlpha;

    if (menuMouseMode)
    {
        vector rawMousePos = getmousepos();
        vector newMouse = globalToBox(rawMousePos, draw_shift, draw_scale);
        if (rawMousePos != '0 0 0' && newMouse != menuMousePos)
        {
            menuMousePos = newMouse;
            if (mouseButtonsPressed) main.mouseDrag(main, menuMousePos);
            else main.mouseMove(main, menuMousePos);
        }
    }
    else if (frametime > 0)
    {
        vector dMouse = getmousepos() * (frametime / realFrametime);  // for capturevideo
        if (dMouse != '0 0 0')
        {
            vector minpos = globalToBox('0 0 0', draw_shift, draw_scale);
            vector maxpos = globalToBox(eX * (realconwidth - 1) + eY * (realconheight - 1), draw_shift, draw_scale);
            dMouse = globalToBoxSize(dMouse, draw_scale);
            menuMousePos += dMouse * cvar("menu_mouse_speed");
            menuMousePos.x = bound(minpos.x, menuMousePos.x, maxpos.x);
            menuMousePos.y = bound(minpos.y, menuMousePos.y, maxpos.y);
            if (mouseButtonsPressed) main.mouseDrag(main, menuMousePos);
            else main.mouseMove(main, menuMousePos);
        }
    }
    main.draw(main);

    m_tooltip(menuMousePos);

    draw_alpha = max(draw_alpha, SKINALPHA_CURSOR_INTRO * bound(0, menuLogoAlpha, 1));

    draw_drawMousePointer(menuMousePos);

    draw_reset_cropped();
    postMenuDraw();

    frametime = 0;
    IL_ENDFRAME();
}

Here is the call graph for this function:

m_findtooltipitem()

entity m_findtooltipitem	(	entity	root,
		vector	pos
	)

Definition at line 470 of file menu.qc.

References best, entity(), globalToBox(), menu_tooltips, and NULL.

Referenced by m_tooltip().

{
    entity best = NULL;
    for (entity it = root; it.instanceOfContainer; )
    {
        while (it.instanceOfNexposee && it.focusedChild)
        {
            it = it.focusedChild;
            pos = globalToBox(pos, it.Container_origin, it.Container_size);
        }
        if (it.instanceOfNexposee)
        {
            it = it.itemFromPoint(it, pos);
            if (it.tooltip) best = it;
            else if (menu_tooltips == 2 && (it.controlledCvar || it.onClickCommand)) best = it;
            it = NULL;
        }
        else if (it.instanceOfModalController)
        {
            it = it.focusedChild;
        }
        else
        {
            it = it.itemFromPoint(it, pos);
        }
        if (!it) break;
        if (it.tooltip) best = it;
        else if (menu_tooltips == 2 && (it.controlledCvar || it.onClickCommand)) best = it;
        pos = globalToBox(pos, it.Container_origin, it.Container_size);
    }

    return best;
}

Here is the call graph for this function:

Here is the caller graph for this function:

m_focus_item_chain()

void m_focus_item_chain	(	entity	outermost,
		entity	innermost
	)

Definition at line 904 of file menu.qc.

Referenced by m_setpointerfocus().

{
    if (innermost.parent != outermost) m_focus_item_chain(outermost, innermost.parent);
    innermost.parent.setFocus(innermost.parent, innermost);
}

Here is the caller graph for this function:

m_gamestatus()

void m_gamestatus

(

)

Definition at line 48 of file menu.qc.

References clientstate(), CS_CONNECTED, cvar(), GAME_CONNECTED, GAME_DEVELOPER, GAME_ISSERVER, gamestatus, isdemo(), and isserver().

Referenced by m_draw().

{
    gamestatus = 0;
    if (isserver()) gamestatus |= GAME_ISSERVER;
    if (clientstate() == CS_CONNECTED || isdemo()) gamestatus |= GAME_CONNECTED;
    if (cvar("developer") > 0) gamestatus |= GAME_DEVELOPER;
}

Here is the call graph for this function:

Here is the caller graph for this function:

m_goto()

void m_goto

(

string

itemname

)

Definition at line 951 of file menu.qc.

References entity(), find(), GAME_CONNECTED, GAME_ISSERVER, gamestatus, m_activate_window(), m_display(), m_goto_buffer, m_hide(), m_setpointerfocus(), main, Menu_Active, menuInitialized, name, NULL, and strcpy.

Referenced by GameCommand(), m_init_delayed(), XonoticCommandButton_Click(), XonoticNexposee_close(), and XonoticRootDialog_close().

{
    if (!menuInitialized)
    {
        strcpy(m_goto_buffer, itemname);
        return;
    }
    if (itemname == "")  // this can be called by GameCommand
    {
        if (gamestatus & (GAME_ISSERVER | GAME_CONNECTED))
        {
            m_hide();
        }
        else
        {
            m_activate_window(main.mainNexposee);
            m_display();
        }
    }
    else
    {
        entity e;
        for (e = NULL; (e = find(e, name, itemname)); )
            if (e.classname != "vtbl") break;

        if ((e) && (!e.requiresConnection || (gamestatus & (GAME_ISSERVER | GAME_CONNECTED))))
        {
            if(!Menu_Active)
                e.hideMenuOnClose = true;
            m_hide();
            m_activate_window(e);
            m_setpointerfocus(e);
            m_display();
        }
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

m_hide()

void m_hide

(

)

Definition at line 869 of file menu.qc.

References KEY_GAME, main, Menu_Active, menuInitialized, MT_CLIENT, setkeydest(), and setmousetarget().

Referenced by Dialog_close(), m_draw(), m_goto(), m_init(), m_keydown(), m_toggle(), and Shutdown().

{
    Menu_Active = false;
    setkeydest(KEY_GAME);
    setmousetarget(MT_CLIENT);

    if (!menuInitialized) return;

    main.focusLeave(main);
    main.hideNotify(main);
}

Here is the call graph for this function:

Here is the caller graph for this function:

m_init()

void m_init

(

)

Definition at line 56 of file menu.qc.

References cvar(), cvar_set(), cvar_string(), GETGAMEDIRINFO_DESCRIPTION, GETGAMEDIRINFO_NAME, localcmd, LOG_TRACE, LOG_TRACEF, m_display(), m_hide(), prvm_language, RegisterSLCategories(), static_init, static_init_late, static_init_precache, strzone(), and updateCompression().

{
    bool restarting = false;
    cvar_set("_menu_alpha", "0");
    prvm_language = cvar_string("prvm_language");
    if (prvm_language == "")
    {
        prvm_language = "en";
        cvar_set("prvm_language", prvm_language);
        localcmd("\nmenu_restart\n");
        restarting = true;
    }
    prvm_language = strzone(prvm_language);
    cvar_set("_menu_prvm_language", prvm_language);

#ifdef WATERMARK
        LOG_TRACEF("^4MQC Build information: ^1%s", WATERMARK);
#endif

    // list all game dirs (TEST)
    if (cvar("developer") > 0)
    {
        for (int i = 0; ; ++i)
        {
            string s = getgamedirinfo(i, GETGAMEDIRINFO_NAME);
            if (!s) break;
            LOG_TRACE(s, ": ", getgamedirinfo(i, GETGAMEDIRINFO_DESCRIPTION));
        }
    }

    // needs to be done so early because of the constants they create
    static_init();
    static_init_late();
    static_init_precache();

    RegisterSLCategories();

    float ddsload = cvar("r_texture_dds_load");
    float texcomp = cvar("gl_texturecompression");
    updateCompression();
    if (ddsload != cvar("r_texture_dds_load") || texcomp != cvar("gl_texturecompression")) localcmd("\nr_restart\n");

    if (!restarting)
    {
        if (cvar("_menu_initialized"))  // always show menu after menu_restart
            m_display();
        else m_hide();
        cvar_set("_menu_initialized", "1");
    }
}

Here is the call graph for this function:

m_init_delayed()

void m_init_delayed

(

)

Definition at line 158 of file menu.qc.

References anim, argv(), argv_end_index, argv_start_index, conheight, conwidth, cvar_defstring(), cvar_set(), cvar_string(), draw_currentSkin, draw_reset_cropped(), draw_setMousePointer(), error(), eX, eY, fclose(), fgets(), FILE_READ, fopen(), m_display(), m_goto(), m_goto_buffer, m_sync(), main, Menu_Active, menuInitialized, menuMousePos, menuShiftState, NEW, precache_pic(), preMenuInit(), search_begin(), search_end(), search_getfilename(), search_getsize(), strcat(), strfree, strzone(), substring(), and tokenize_console.

Referenced by m_draw().

{
    draw_reset_cropped();

    menuInitialized = false;
    if (!preMenuInit()) return;
    menuInitialized = true;

    int fh = -1;
    if (cvar_string("menu_skin") != "")
    {
        draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
        fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
    }
    if (fh < 0 && cvar_defstring("menu_skin") != "")
    {
        cvar_set("menu_skin", cvar_defstring("menu_skin"));
        draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
        fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
    }
    if (fh < 0)
    {
        draw_currentSkin = "gfx/menu/default";
        fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
    }
    if (fh < 0) error("cannot load any menu skin\n");
    draw_currentSkin = strzone(draw_currentSkin);
    for (string s; (s = fgets(fh)); )
    {
        // these two are handled by skinlist.qc
        if (substring(s, 0, 6) == "title ") continue;
        if (substring(s, 0, 7) == "author ") continue;
        int n = tokenize_console(s);
        if (n < 2) continue;
        Skin_ApplySetting(argv(0), substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
    }
    fclose(fh);

    int glob = search_begin(strcat(draw_currentSkin, "/*.tga"), true, true);
    if (glob >= 0)
    {
        for (int i = 0, n = search_getsize(glob); i < n; ++i)
            precache_pic(search_getfilename(glob, i));
        search_end(glob);
    }

    draw_setMousePointer(SKINGFX_CURSOR, SKINSIZE_CURSOR, SKINOFFSET_CURSOR);

    anim = NEW(AnimHost);
    main = NEW(MainWindow);
    main.configureMainWindow(main);

    main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
    main.focused = true;
    menuShiftState = 0;
    menuMousePos = '0.5 0.5 0';

    m_sync();

    if (m_goto_buffer)
    {
        m_goto(m_goto_buffer);
        strfree(m_goto_buffer);
    }

    if (Menu_Active) m_display();  // delayed menu display
}

Here is the call graph for this function:

Here is the caller graph for this function:

m_keydown()

void m_keydown	(	float	key,
		float	ascii
	)

Definition at line 247 of file menu.qc.

References draw_reset_cropped(), entity(), GAME_CONNECTED, GAME_ISSERVER, gamestatus, getmousepos(), K_ALT, K_CTRL, K_ESCAPE, K_MOUSE1, K_MOUSE3, K_SHIFT, keyGrabber, LOG_TRACE, m_hide(), main, Menu_Active, menuInitialized, menuMouseMode, menuMousePos, menuShiftState, mouseButtonsPressed, NULL, realconheight, realconwidth, S_ALT, S_CTRL, S_SHIFT, and vector().

{
    if (!menuInitialized) return;
    if (!Menu_Active) return;

    if (menuMouseMode && key >= K_MOUSE1 && key <= K_MOUSE3)
    {
        // detect a click outside of the game window
        vector p = getmousepos();
        if (p.x < 0 || p.x > realconwidth || p.y < 0 || p.y > realconheight)
        {
            ++mouseButtonsPressed;
            return;
        }
    }

    if (keyGrabber)
    {
        entity e = keyGrabber;
        keyGrabber = NULL;
        e.keyGrabbed(e, key, ascii);
    }
    else
    {
        draw_reset_cropped();
        if (!mouseButtonsPressed && key >= K_MOUSE1 && key <= K_MOUSE3)
            main.mousePress(main, menuMousePos);
        if (!main.keyDown(main, key, ascii, menuShiftState))
        {
            // disable menu on unhandled ESC
            if (key == K_ESCAPE)
                if (gamestatus & (GAME_ISSERVER | GAME_CONNECTED))  // don't back out to console only
                    m_hide();
        }
    }
    if (key >= K_MOUSE1 && key <= K_MOUSE3)
    {
        ++mouseButtonsPressed;
        if (mouseButtonsPressed > 10)
        {
            mouseButtonsPressed = 10;
            LOG_TRACE("Warning: pressed an already pressed button");
        }
    }
    if (key == K_ALT) menuShiftState |= S_ALT;
    if (key == K_CTRL) menuShiftState |= S_CTRL;
    if (key == K_SHIFT) menuShiftState |= S_SHIFT;
}

Here is the call graph for this function:

m_keyup()

void m_keyup	(	float	key,
		float	ascii
	)

Definition at line 226 of file menu.qc.

References draw_reset_cropped(), K_ALT, K_CTRL, K_MOUSE1, K_MOUSE3, K_SHIFT, LOG_TRACE, main, Menu_Active, menuInitialized, menuMousePos, menuShiftState, mouseButtonsPressed, S_ALT, S_CTRL, and S_SHIFT.

{
    if (!menuInitialized) return;
    if (!Menu_Active) return;
    draw_reset_cropped();
    main.keyUp(main, key, ascii, menuShiftState);
    if (key >= K_MOUSE1 && key <= K_MOUSE3)
    {
        --mouseButtonsPressed;
        if (!mouseButtonsPressed) main.mouseRelease(main, menuMousePos);
        if (mouseButtonsPressed < 0)
        {
            mouseButtonsPressed = 0;
            LOG_TRACE("Warning: released an already released button");
        }
    }
    if (key == K_ALT) menuShiftState &= ~S_ALT;
    if (key == K_CTRL) menuShiftState &= ~S_CTRL;
    if (key == K_SHIFT) menuShiftState &= ~S_SHIFT;
}

Here is the call graph for this function:

m_play_click_sound()

void m_play_click_sound

(

string

soundfile

)

Definition at line 997 of file menu.qc.

References cvar(), and localsound().

Referenced by Button_playClickSound(), CheckBox_playClickSound(), Dialog_keyDown(), GameCommand(), InputBox_keyDown(), InputBox_mouseRelease(), KeyBinder_Bind_Clear(), Nexposee_draw(), Nexposee_keyDown(), ServerList_Favorite_Click(), Slider_keyUp(), Slider_mouseRelease(), XonoticColorpicker_mouseRelease(), XonoticColorpickerString_mouseRelease(), XonoticGametypeList_clickListBoxItem(), XonoticGametypeList_keyDown(), XonoticHUDSkinList_doubleClickListBoxItem(), XonoticKeyBinder_keyGrabbed(), XonoticLanguageList_doubleClickListBoxItem(), XonoticLanguageList_keyDown(), XonoticMapList_clickListBoxItem(), XonoticMapList_doubleClickListBoxItem(), XonoticMapList_keyDown(), XonoticServerList_keyDown(), XonoticSkinList_doubleClickListBoxItem(), XonoticSkinList_keyDown(), and XonoticWinnerDialog_focusEnter().

{
    if (!cvar("menu_sounds")) return;
    localsound(soundfile);
}

Here is the call graph for this function:

Here is the caller graph for this function:

m_play_focus_sound()

void m_play_focus_sound

(

)

Definition at line 988 of file menu.qc.

References cvar(), localsound(), MENU_SOUND_FOCUS, and time.

{
    static float menuLastFocusSoundTime;
    if (cvar("menu_sounds") < 2) return;
    if (time - menuLastFocusSoundTime <= 0.25) return;
    localsound(MENU_SOUND_FOCUS);
    menuLastFocusSoundTime = time;
}

Here is the call graph for this function:

m_setpointerfocus()

void m_setpointerfocus

(

entity

wnd

)

Definition at line 938 of file menu.qc.

References conheight, conwidth, entity(), m_focus_item_chain(), and menuMousePos.

Referenced by m_goto().

{
    if (!wnd.instanceOfContainer) return;
    entity focus = wnd.preferredFocusedGrandChild(wnd);
    if (!focus) return;
    menuMousePos = focus.origin + 0.5 * focus.size;
    menuMousePos.x *= 1 / conwidth;
    menuMousePos.y *= 1 / conheight;
    entity par = wnd.parent;
    if (par.focused) par.setFocus(par, wnd);
    if (wnd.focused) m_focus_item_chain(wnd, focus);
}

Here is the call graph for this function:

Here is the caller graph for this function:

m_sync()

void m_sync

(

)

Definition at line 40 of file menu.qc.

References loadAllCvars(), main, updateCompression(), vidheight_s, vidpixelheight_s, and vidwidth_s.

Referenced by GameCommand(), and m_init_delayed().

{
    updateCompression();
    vidwidth_s = vidheight_s = vidpixelheight_s = 0;  // Force updateConwidths on next draw

    loadAllCvars(main);
}

Here is the call graph for this function:

Here is the caller graph for this function:

m_testmousetooltipbox()

bool m_testmousetooltipbox

(

vector

pos

)

Definition at line 416 of file menu.qc.

References menuTooltipOrigin, and menuTooltipSize.

Referenced by m_tooltip().

{
    return !(
        (pos.x >= menuTooltipOrigin.x && pos.x < menuTooltipOrigin.x + menuTooltipSize.x)
        && (pos.y >= menuTooltipOrigin.y && pos.y < menuTooltipOrigin.y + menuTooltipSize.y)
            );
}

Here is the caller graph for this function:

m_testtooltipbox()

bool m_testtooltipbox

(

vector

tooltippos

)

Definition at line 423 of file menu.qc.

References menuTooltipOrigin, and menuTooltipSize.

Referenced by m_allocatetooltipbox().

{
    if (tooltippos.x < 0) return false;
    if (tooltippos.y < 0) return false;
    if (tooltippos.x + menuTooltipSize.x > 1) return false;
    if (tooltippos.y + menuTooltipSize.y > 1) return false;
    menuTooltipOrigin = tooltippos;
    return true;
}

Here is the caller graph for this function:

m_toggle()

void m_toggle

(

int

mode

)

Definition at line 881 of file menu.qc.

References m_display(), m_hide(), and Menu_Active.

Referenced by m_draw().

{
    if (Menu_Active)
    {
        if (mode == 1) return;
        m_hide();
    }
    else
    {
        if (mode == 0) return;
        m_display();
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

m_tooltip()

void m_tooltip

(

vector

pos

)

Definition at line 530 of file menu.qc.

References bound(), conheight, conwidth, cvar(), draw_BorderPicture(), draw_Text(), draw_TextWidth(), draw_TextWidth_WithoutColors(), entity(), frametime, gettooltip(), getWrappedLine(), getWrappedLine_remaining, m_allocatetooltipbox(), m_findtooltipitem(), m_testmousetooltipbox(), main, menu_tooltips, menu_tooltips_old, menuTooltipAlpha, menuTooltipAveragedMousePos, menuTooltipItem, menuTooltipOrigin, menuTooltipSize, menuTooltipState, menuTooltipText, NULL, strcpy, strfree, vdist, and vector().

Referenced by m_draw().

{
    static string prev_tooltip;
    entity it;
    menu_tooltips = cvar("menu_tooltips");
    if (!menu_tooltips)
    {
        // don't return immediately, fade out the active tooltip first
        if (menuTooltipItem == NULL) return;
        it = NULL;
        menu_tooltips_old = menu_tooltips;
    }
    else
    {
        float f = bound(0, frametime * 2, 1);
        menuTooltipAveragedMousePos = menuTooltipAveragedMousePos * (1 - f) + pos * f;
        if (vdist(pos - menuTooltipAveragedMousePos, <, 0.01))
        {
            it = m_findtooltipitem(main, pos);

            if (it.instanceOfListBox && it.isScrolling(it)) it = NULL;

            if (it && prev_tooltip != it.tooltip)
            {
                // fade out if tooltip of a certain item has changed
                menuTooltipState = 3;
                strcpy(prev_tooltip, it.tooltip);
            }
            else if (menuTooltipItem && !m_testmousetooltipbox(pos))
            {
                menuTooltipState = 3;  // fade out if mouse touches it
            }
        }
        else
        {
            it = NULL;
        }
    }
    vector fontsize = '1 0 0' * (SKINFONTSIZE_TOOLTIP / conwidth) + '0 1 0' * (SKINFONTSIZE_TOOLTIP / conheight);

    // float menuTooltipState; // 0: static, 1: fading in, 2: fading out, 3: forced fading out
    if (it != menuTooltipItem)
    {
        switch (menuTooltipState)
        {
            case 0:
                if (menuTooltipItem)
                {
                    // another item: fade out first
                    menuTooltipState = 2;
                }
                else
                {
                    // new item: fade in
                    menuTooltipState = 1;
                    menuTooltipItem = it;

                    menuTooltipOrigin.x = -1;  // unallocated

                    strcpy(menuTooltipText, gettooltip());

                    int i = 0;
                    float w = 0;
                    for (getWrappedLine_remaining = menuTooltipText; getWrappedLine_remaining && i <= 16; ++i)
                    {
                        string s = getWrappedLine(SKINWIDTH_TOOLTIP, fontsize, draw_TextWidth_WithoutColors);
                        if (i == 16)
                            s = "...";
                        float f = draw_TextWidth(s, false, fontsize);
                        if (f > w) w = f;
                    }
                    menuTooltipSize.x = w + 2 * (SKINMARGIN_TOOLTIP_x / conwidth);
                    menuTooltipSize.y = i * fontsize.y + 2 * (SKINMARGIN_TOOLTIP_y / conheight);
                    menuTooltipSize.z = 0;
                }
                break;
            case 1:
                // changing item while fading in: fade out first
                menuTooltipState = 2;
                break;
            case 2:
                // changing item while fading out: can't
                break;
        }
    }
    else if (menuTooltipState == 2)  // re-fade in?
    {
        menuTooltipState = 1;
    }

    switch (menuTooltipState)
    {
        case 1:  // fade in
            menuTooltipAlpha = bound(0, menuTooltipAlpha + 5 * frametime, 1);
            if (menuTooltipAlpha == 1) menuTooltipState = 0;
            break;
        case 2:  // fade out
        case 3:  // forced fade out
            menuTooltipAlpha = bound(0, menuTooltipAlpha - 2 * frametime, 1);
            if (menuTooltipAlpha == 0)
            {
                menuTooltipState = 0;
                menuTooltipItem = NULL;
            }
            break;
    }

    if (menuTooltipItem == NULL)
    {
        strfree(menuTooltipText);
        return;
    }
    else
    {
        if (menu_tooltips != menu_tooltips_old)
        {
            if (menu_tooltips != 0 && menu_tooltips_old != 0) menuTooltipItem = NULL; // reload tooltip next frame
            menu_tooltips_old = menu_tooltips;
        }
        else if (menuTooltipOrigin.x < 0)                                             // unallocated?
        {
            m_allocatetooltipbox(pos);
        }
        if (menuTooltipOrigin.x >= 0)
        {
            // draw the tooltip!
            vector p = SKINBORDER_TOOLTIP;
            p.x *= 1 / conwidth;
            p.y *= 1 / conheight;
            draw_BorderPicture(menuTooltipOrigin, SKINGFX_TOOLTIP, menuTooltipSize, '1 1 1', menuTooltipAlpha, p);
            p = menuTooltipOrigin;
            p.x += SKINMARGIN_TOOLTIP_x / conwidth;
            p.y += SKINMARGIN_TOOLTIP_y / conheight;
            int i = 0;
            for (getWrappedLine_remaining = menuTooltipText; getWrappedLine_remaining && i <= 16; ++i, p.y += fontsize.y)
            {
                string s = getWrappedLine(SKINWIDTH_TOOLTIP, fontsize, draw_TextWidth_WithoutColors);
                if (i == 16)
                    s = "...";
                draw_Text(p, s, fontsize, SKINCOLOR_TOOLTIP, SKINALPHA_TOOLTIP * menuTooltipAlpha, false);
            }
        }
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

Shutdown()

void Shutdown

(

)

Definition at line 895 of file menu.qc.

References FOREACH_ENTITY_ORDERED, and m_hide().

{
    m_hide();
    FOREACH_ENTITY_ORDERED(it.destroy, {
        if (it.classname == "vtbl") continue;
        it.destroy(it);
    });
}

Here is the call graph for this function:

UpdateConWidthHeight()

void UpdateConWidthHeight	(	float	w,
		float	h,
		float	p
	)

Definition at line 118 of file menu.qc.

References conheight, conheight_s, conwidth, conwidth_s, cvar(), cvar_string(), draw_reset_cropped(), eX, eY, localcmd, main, MENU_ASPECT, realconheight, realconwidth, updateConwidths(), vidheight_s, vidpixelheight_s, and vidwidth_s.

Referenced by m_draw().

{
    if (w != vidwidth_s || h != vidheight_s || p != vidpixelheight_s)
    {
        if (updateConwidths(w, h, p)) localcmd(sprintf("\nexec %s\n", cvar_string("menu_font_cfg")));
        vidwidth_s = w;
        vidheight_s = h;
        vidpixelheight_s = p;
    }
    conwidth_s = conwidth;
    conheight_s = conheight;
    realconwidth = cvar("vid_conwidth");
    realconheight = cvar("vid_conheight");
    if (realconwidth / realconheight > MENU_ASPECT)
    {
        // widescreen
        conwidth = realconheight * MENU_ASPECT;
        conheight = realconheight;
    }
    else
    {
        // squarescreen
        conwidth = realconwidth;
        conheight = realconwidth / MENU_ASPECT;
    }
    if (main)
    {
        if (conwidth_s != conwidth || conheight_s != conheight)
        {
            draw_reset_cropped();
            main.resizeNotify(main, '0 0 0', eX * conwidth + eY * conheight, '0 0 0', eX * conwidth + eY * conheight);
        }
    }
    else
    {
        vidwidth_s = vidheight_s = vidpixelheight_s = 0;  // retry next frame
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

Variable Documentation

autocvar_menu_force_on_disconnection

float autocvar_menu_force_on_disconnection

Definition at line 675 of file menu.qc.

Referenced by m_draw().

conheight_s

float conheight_s

Definition at line 36 of file menu.qc.

Referenced by UpdateConWidthHeight().

controlledCvar

string controlledCvar

Definition at line 16 of file menu.qc.

conwidth_s

float conwidth_s

Definition at line 36 of file menu.qc.

Referenced by UpdateConWidthHeight().

m_goto_buffer

string m_goto_buffer

Definition at line 157 of file menu.qc.

Referenced by m_goto(), and m_init_delayed().

MENU_ASPECT

const float MENU_ASPECT = 1280 / 1024

Definition at line 107 of file menu.qc.

Referenced by UpdateConWidthHeight().

menu_tooltips

int menu_tooltips

Definition at line 407 of file menu.qc.

Referenced by gettooltip(), m_findtooltipitem(), and m_tooltip().

menu_tooltips_old

int menu_tooltips_old

Definition at line 408 of file menu.qc.

Referenced by m_tooltip().

menuAlpha

float menuAlpha

Definition at line 29 of file menu.qc.

Referenced by m_draw().

menuInitialized

bool menuInitialized

Definition at line 32 of file menu.qc.

Referenced by m_display(), m_draw(), m_goto(), m_hide(), m_init_delayed(), m_keydown(), and m_keyup().

menuLogoAlpha

float menuLogoAlpha

Definition at line 30 of file menu.qc.

Referenced by m_draw().

menuMouseMode

int menuMouseMode

Definition at line 34 of file menu.qc.

Referenced by m_display(), m_draw(), and m_keydown().

menuMousePos

vector menuMousePos

Definition at line 26 of file menu.qc.

Referenced by m_display(), m_draw(), m_init_delayed(), m_keydown(), m_keyup(), and m_setpointerfocus().

menuNotTheFirstFrame

bool menuNotTheFirstFrame

Definition at line 33 of file menu.qc.

Referenced by m_draw().

menuPrevTime

float menuPrevTime

Definition at line 28 of file menu.qc.

Referenced by m_draw().

menuShiftState

int menuShiftState

Definition at line 27 of file menu.qc.

Referenced by m_init_delayed(), m_keydown(), and m_keyup().

menuTooltipAlpha

float menuTooltipAlpha

Definition at line 413 of file menu.qc.

Referenced by m_tooltip().

menuTooltipAveragedMousePos

vector menuTooltipAveragedMousePos

Definition at line 409 of file menu.qc.

Referenced by m_tooltip().

menuTooltipItem

entity menuTooltipItem

Definition at line 410 of file menu.qc.

Referenced by gettooltip(), and m_tooltip().

menuTooltipOrigin

vector menuTooltipOrigin

Definition at line 411 of file menu.qc.

Referenced by m_testmousetooltipbox(), m_testtooltipbox(), and m_tooltip().

menuTooltipSize

vector menuTooltipSize

Definition at line 412 of file menu.qc.

Referenced by m_allocatetooltipbox(), m_testmousetooltipbox(), m_testtooltipbox(), and m_tooltip().

menuTooltipState

int menuTooltipState

Definition at line 415 of file menu.qc.

Referenced by m_tooltip().

menuTooltipText

string menuTooltipText

Definition at line 414 of file menu.qc.

Referenced by m_tooltip().

mouseButtonsPressed

int mouseButtonsPressed

Definition at line 25 of file menu.qc.

Referenced by m_display(), m_draw(), m_keydown(), and m_keyup().

prevMenuAlpha

float prevMenuAlpha

Definition at line 31 of file menu.qc.

Referenced by m_draw().

realconheight

float realconheight

Definition at line 38 of file menu.qc.

Referenced by draw_reset_cropped(), draw_reset_full(), m_draw(), m_keydown(), and UpdateConWidthHeight().

realconwidth

float realconwidth

Definition at line 38 of file menu.qc.

Referenced by draw_reset_cropped(), draw_reset_full(), m_draw(), m_keydown(), and UpdateConWidthHeight().

vidheight_s

float vidheight_s

Definition at line 37 of file menu.qc.

Referenced by m_sync(), and UpdateConWidthHeight().

vidpixelheight_s

float vidpixelheight_s

Definition at line 37 of file menu.qc.

Referenced by m_sync(), and UpdateConWidthHeight().

vidwidth_s

float vidwidth_s

Definition at line 37 of file menu.qc.

Referenced by m_sync(), and UpdateConWidthHeight().