This graph shows which files directly or indirectly include this file:

Functions
void	InterpolateOrigin_Do (entity this)
	set origin based on iorigin1 (old pos), iorigin2 (desired pos), and time More...

void	InterpolateOrigin_Note (entity this)

void	InterpolateOrigin_Reset (entity this)

void	InterpolateOrigin_Undo (entity this)
	snap origin to iorigin2 (actual origin) More...

Variables
float	autocvar_cl_lerpexcess

const int	IFLAG_ANGLES = BIT(1)

const int	IFLAG_AUTOANGLES = BIT(2)

const int	IFLAG_AUTOVELOCITY = BIT(6)

const int	IFLAG_INTERNALMASK = IFLAG_VALID \| IFLAG_PREVALID

const int	IFLAG_ORIGIN = BIT(9)

const int	IFLAG_PREVALID = BIT(4)

const int	IFLAG_TELEPORTED = BIT(5)

const int	IFLAG_V_ANGLE = BIT(7)

const int	IFLAG_V_ANGLE_X = BIT(8)

const int	IFLAG_VALID = BIT(3)

const int	IFLAG_VELOCITY = BIT(0)

int	iflags

Function Documentation

◆ InterpolateOrigin_Do()

void InterpolateOrigin_Do ( entity this )

set origin based on iorigin1 (old pos), iorigin2 (desired pos), and time

Definition at line 129 of file interpolate.qc.

References angles, autocvar_cl_lerpexcess, bound(), fixedvectoangles2, IFLAG_ANGLES, IFLAG_ORIGIN, IFLAG_V_ANGLE, IFLAG_V_ANGLE_X, IFLAG_VELOCITY, iflags, iforward1, iforward2, iorigin1, iorigin2, itime1, itime2, iup1, iup2, ivelocity1, ivelocity2, ivforward1, ivforward2, ivup1, ivup2, setorigin(), time, v_angle, vector(), and velocity.

Referenced by CSQCModel_Draw(), CSQCPlayer_SetCamera(), NET_HANDLE(), and Projectile_Draw().

 {
     if (this.itime1 && this.itime2 && this.itime1 != this.itime2)
     {
         float f = bound(0, (time - this.itime1) / (this.itime2 - this.itime1), 1 + autocvar_cl_lerpexcess);
         float f_1 = 1 - f;
         if (this.iflags & IFLAG_ORIGIN)
             setorigin(this, f_1 * this.iorigin1 + f * this.iorigin2);
         if (this.iflags & IFLAG_ANGLES)
         {
             vector forward = f_1 * this.iforward1 + f * this.iforward2;
             vector up = f_1 * this.iup1 + f * this.iup2;
             this.angles = fixedvectoangles2(forward, up);
         }
         if (this.iflags & IFLAG_V_ANGLE)
         {
             vector forward = f_1 * this.ivforward1 + f * this.ivforward2;
             vector up = f_1 * this.ivup1 + f * this.ivup2;
             this.v_angle = fixedvectoangles2(forward, up);
         }
         else if (this.iflags & IFLAG_V_ANGLE_X)
         {
             this.v_angle_x = f_1 * this.ivforward1.x + f * this.ivforward2.x;
         }
         if (this.iflags & IFLAG_VELOCITY)
             this.velocity = f_1 * this.ivelocity1 + f * this.ivelocity2;
     }
 }

Here is the call graph for this function:

Here is the caller graph for this function:

◆ InterpolateOrigin_Note()

void InterpolateOrigin_Note ( entity this )

Definition at line 37 of file interpolate.qc.

References angles, FIXED_MAKE_VECTORS, IFLAG_ANGLES, IFLAG_AUTOANGLES, IFLAG_AUTOVELOCITY, IFLAG_ORIGIN, IFLAG_PREVALID, IFLAG_TELEPORTED, IFLAG_V_ANGLE, IFLAG_V_ANGLE_X, IFLAG_VALID, IFLAG_VELOCITY, iflags, iforward1, iforward2, iorigin1, iorigin2, itime1, itime2, iup1, iup2, ivelocity1, ivelocity2, ivforward1, ivforward2, ivup1, ivup2, origin, serverprevtime, time, v_angle, vdist, vectoangles(), vector(), and velocity.

Referenced by NET_HANDLE().

 {
     float dt = time - this.itime2;
 
     int f0 = this.iflags;
     if (this.iflags & IFLAG_PREVALID) this.iflags |= IFLAG_VALID;
     else this.iflags |= IFLAG_PREVALID;
 
     if (this.iflags & IFLAG_ORIGIN)
     {
         this.iorigin1 = this.iorigin2;
         this.iorigin2 = this.origin;
     }
 
     if ((this.iflags & IFLAG_AUTOANGLES) && this.iorigin2 != this.iorigin1)
         this.angles = vectoangles(this.iorigin2 - this.iorigin1);
 
     if ((this.iflags & IFLAG_AUTOVELOCITY) && this.itime2 != this.itime1)
         this.velocity = (this.iorigin2 - this.iorigin1) * (1.0 / (this.itime2 - this.itime1));
 
     if (this.iflags & IFLAG_ANGLES)
     {
         vector forward, right, up;
         FIXED_MAKE_VECTORS(this.angles, forward, right, up);
         if (f0 & IFLAG_VALID)
         {
             this.iforward1 = this.iforward2;
             this.iup1 = this.iup2;
         }
         else
         {
             this.iforward1 = forward;
             this.iup1 = up;
         }
         this.iforward2 = forward;
         this.iup2 = up;
     }
 
     if (this.iflags & IFLAG_V_ANGLE)
     {
         vector forward, right, up;
         FIXED_MAKE_VECTORS(this.v_angle, forward, right, up);
         if (f0 & IFLAG_VALID)
         {
             this.ivforward1 = this.ivforward2;
             this.ivup1 = this.ivup2;
         }
         else
         {
             this.ivforward1 = forward;
             this.ivup1 = up;
         }
         this.ivforward2 = forward;
         this.ivup2 = up;
     }
     else if (this.iflags & IFLAG_V_ANGLE_X)
     {
         this.ivforward1_x = this.ivforward2_x;
         this.ivforward2_x = this.v_angle.x;
     }
 
     if (this.iflags & IFLAG_VELOCITY)
     {
         this.ivelocity1 = this.ivelocity2;
         this.ivelocity2 = this.velocity;
     }
 
     if (this.iflags & IFLAG_TELEPORTED)
     {
         this.iflags &= ~IFLAG_TELEPORTED;
         this.itime1 = this.itime2 = time;  // don't lerp
     }
     else if (vdist(this.iorigin2 - this.iorigin1, >, 1000))
     {
         this.itime1 = this.itime2 = time;  // don't lerp
     }
     else if ((this.iflags & IFLAG_VELOCITY) && vdist(this.ivelocity2 - this.ivelocity1, >, 1000))
     {
         this.itime1 = this.itime2 = time;  // don't lerp
     }
     else if (dt >= 0.2)
     {
         this.itime1 = this.itime2 = time;
     }
     else
     {
         this.itime1 = serverprevtime;
         this.itime2 = time;
     }
 }

Here is the call graph for this function:

Here is the caller graph for this function:

◆ InterpolateOrigin_Reset()

void InterpolateOrigin_Reset ( entity this )

Definition at line 32 of file interpolate.qc.

References IFLAG_INTERNALMASK, iflags, itime1, and itime2.

Referenced by NET_HANDLE().

 {
     this.iflags &= ~IFLAG_INTERNALMASK;
     this.itime1 = this.itime2 = 0;
 }

Here is the caller graph for this function:

◆ InterpolateOrigin_Undo()

void InterpolateOrigin_Undo ( entity this )

snap origin to iorigin2 (actual origin)

Definition at line 159 of file interpolate.qc.

References angles, fixedvectoangles2, IFLAG_ANGLES, IFLAG_ORIGIN, IFLAG_V_ANGLE, IFLAG_V_ANGLE_X, IFLAG_VELOCITY, iflags, iforward2, iorigin2, iup2, ivelocity2, ivforward2, ivup2, setorigin(), v_angle, and velocity.

Referenced by NET_HANDLE().

 {
     if (this.iflags & IFLAG_ORIGIN) setorigin(this, this.iorigin2);
     if (this.iflags & IFLAG_ANGLES) this.angles = fixedvectoangles2(this.iforward2, this.iup2);
     if (this.iflags & IFLAG_V_ANGLE) this.v_angle = fixedvectoangles2(this.ivforward2, this.ivup2);
     else if (this.iflags & IFLAG_V_ANGLE_X) this.v_angle_x = this.ivforward2_x;
     if (this.iflags & IFLAG_VELOCITY) this.velocity = this.ivelocity2;
 }