sv_resources.qc File Reference

Source file that contains implementation of the resource system. More...

#include "sv_resources.qh"
#include <common/resources/resources.qh>
#include <server/mutators/_mod.qh>
#include <server/world.qh>

Include dependency graph for sv_resources.qc:

Go to the source code of this file.

Functions
float	GetResource (entity e, Resource res_type)
	Returns the current amount of resource the given entity has. More...
float	GetResourceLimit (entity e, Resource res_type)
	Returns the maximum amount of the given resource. More...
void	GiveResource (entity receiver, Resource res_type, float amount)
	Gives an entity some resource. More...
void	GiveResourceWithLimit (entity receiver, Resource res_type, float amount, float limit)
	Gives an entity some resource but not more than a limit. More...
void	SetResource (entity e, Resource res_type, float amount)
	Sets the current amount of resource the given entity will have. More...
bool	SetResourceExplicit (entity e, Resource res_type, float amount)
	Sets the resource amount of an entity without calling any hooks. More...
void	TakeResource (entity receiver, Resource res_type, float amount)
	Takes an entity some resource. More...
void	TakeResourceWithLimit (entity receiver, Resource res_type, float amount, float limit)
	Takes an entity some resource but not less than a limit. More...

Detailed Description

Source file that contains implementation of the resource system.

Author

Lyberta

Copyright

GNU GPLv2 or any later version.

Definition in file sv_resources.qc.

Function Documentation

GetResource()

float GetResource	(	entity	e,
		Resource	res_type
	)

Returns the current amount of resource the given entity has.

Parameters

[in]	e	Entity to check.
[in]	res_type	Type of the resource (a RES_* constant).

Returns

Current amount of resource the given entity has.

Definition at line 76 of file sv_resources.qc.

Referenced by GiveResource(), GiveResourceWithLimit(), TakeResource(), and TakeResourceWithLimit().

{
    return e.(GetResourceField(res_type));
}

Here is the caller graph for this function:

GetResourceLimit()

float GetResourceLimit	(	entity	e,
		Resource	res_type
	)

Returns the maximum amount of the given resource.

Parameters

[in]	e	Entity to check.
[in]	res_type	Type of the resource (a RES_* constant).

Returns

Maximum amount of the given resource.

Definition at line 12 of file sv_resources.qc.

References autocvar_g_balance_armor_limit, autocvar_g_balance_fuel_limit, autocvar_g_balance_health_limit, error(), g_pickup_cells_max, g_pickup_nails_max, g_pickup_plasma_max, g_pickup_rockets_max, g_pickup_shells_max, GetResourceLimit(), IS_PLAYER, M_ARGV, MUTATOR_CALLHOOK, RES_AMOUNT_HARD_LIMIT, RES_HEALTH, and RES_LIMIT_NONE.

Referenced by GetResourceLimit(), RotRegen(), and SetResource().

{
    if(!IS_PLAYER(e))
        return RES_LIMIT_NONE; // no limits on non-players

    float limit;
    // TODO: registry handles
    switch (res_type)
    {
        case RES_HEALTH:
        {
            limit = autocvar_g_balance_health_limit;
            break;
        }
        case RES_ARMOR:
        {
            limit = autocvar_g_balance_armor_limit;
            break;
        }
        case RES_SHELLS:
        {
            limit = g_pickup_shells_max;
            break;
        }
        case RES_BULLETS:
        {
            limit = g_pickup_nails_max;
            break;
        }
        case RES_ROCKETS:
        {
            limit = g_pickup_rockets_max;
            break;
        }
        case RES_CELLS:
        {
            limit = g_pickup_cells_max;
            break;
        }
        case RES_PLASMA:
        {
            limit = g_pickup_plasma_max;
            break;
        }
        case RES_FUEL:
        {
            limit = autocvar_g_balance_fuel_limit;
            break;
        }
        default:
        {
            error("GetResourceLimit: Invalid resource type.");
            return 0;
        }
    }
    MUTATOR_CALLHOOK(GetResourceLimit, e, res_type, limit);
    limit = M_ARGV(2, float);
    if (limit > RES_AMOUNT_HARD_LIMIT)
    {
        limit = RES_AMOUNT_HARD_LIMIT;
    }
    return limit;
}

Here is the call graph for this function:

Here is the caller graph for this function:

GiveResource()

void GiveResource	(	entity	receiver,
		Resource	res_type,
		float	amount
	)

Gives an entity some resource.

Parameters

[in,out]	receiver	Entity to give resource to.
[in]	res_type	Type of the resource (a RES_* constant).
[in]	amount	Amount of resource to give.

Returns

No return.

Definition at line 120 of file sv_resources.qc.

References autocvar_g_balance_pause_armor_rot, autocvar_g_balance_pause_fuel_rot, autocvar_g_balance_pause_health_rot, entity(), GetResource(), GiveResource(), M_ARGV, max(), MUTATOR_CALLHOOK, RES_HEALTH, SetResource(), and time.

Referenced by GiveRandomWeapons(), GiveResource(), GiveResourceWithLimit(), Monster_Miniboss_Check(), MUTATOR_HOOKFUNCTION(), NIX_GiveCurrentWeapon(), ons_ControlPoint_Icon_BuildThink(), and W_ThrowNewWeapon().

{
    if (amount <= 0)
    {
        return;
    }
    bool forbid = MUTATOR_CALLHOOK(GiveResource, receiver, res_type, amount);
    if (forbid)
    {
        return;
    }
    res_type = M_ARGV(1, entity);
    amount = M_ARGV(2, float);
    if (amount <= 0)
    {
        return;
    }
    SetResource(receiver, res_type, GetResource(receiver, res_type) + amount);
    // TODO: registry handles
    switch (res_type)
    {
        case RES_HEALTH:
        {
            receiver.pauserothealth_finished =
                max(receiver.pauserothealth_finished, time +
                autocvar_g_balance_pause_health_rot);
            return;
        }
        case RES_ARMOR:
        {
            receiver.pauserotarmor_finished =
                max(receiver.pauserotarmor_finished, time +
                autocvar_g_balance_pause_armor_rot);
            return;
        }
        case RES_FUEL:
        {
            receiver.pauserotfuel_finished = max(receiver.pauserotfuel_finished,
                time + autocvar_g_balance_pause_fuel_rot);
            return;
        }
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

GiveResourceWithLimit()

void GiveResourceWithLimit	(	entity	receiver,
		Resource	res_type,
		float	amount,
		float	limit
	)

Gives an entity some resource but not more than a limit.

Parameters

[in,out]	receiver	Entity to give resource to.
[in]	res_type	Type of the resource (a RES_* constant).
[in]	amount	Amount of resource to give.
[in]	limit	Limit of resources to give.

Returns

No return.

Definition at line 164 of file sv_resources.qc.

References entity(), GetResource(), GiveResource(), GiveResourceWithLimit(), M_ARGV, MUTATOR_CALLHOOK, and RES_LIMIT_NONE.

Referenced by destructible_heal(), GiveResourceWithLimit(), Item_GiveAmmoTo(), Monster_Heal(), ons_ControlPoint_Icon_Heal(), ons_ControlPoint_Icon_Think(), ons_GeneratorHeal(), PlayerHeal(), and vehicles_heal().

{
    if (amount <= 0)
    {
        return;
    }
    bool forbid = MUTATOR_CALLHOOK(GiveResourceWithLimit, receiver, res_type, amount, limit);
    if (forbid)
    {
        return;
    }
    res_type = M_ARGV(1, entity);
    amount = M_ARGV(2, float);
    limit = M_ARGV(3, float);
    if (amount <= 0)
    {
        return;
    }
    float current_amount = GetResource(receiver, res_type);
    if (current_amount + amount > limit && limit != RES_LIMIT_NONE)
    {
        amount = limit - current_amount;
    }
    GiveResource(receiver, res_type, amount);
}

Here is the call graph for this function:

Here is the caller graph for this function:

SetResource()

void SetResource	(	entity	e,
		Resource	res_type,
		float	amount
	)

Sets the current amount of resource the given entity will have.

Sets the current amount of resource the given entity will have but limited to the max amount allowed for the resource type.

Parameters

[in,out]	e	Entity to adjust.
[in]	res_type	Type of the resource (a RES_* constant).
[in]	amount	Amount of resource to set.

Returns

No return.

Definition at line 92 of file sv_resources.qc.

References entity(), GetResourceLimit(), M_ARGV, MUTATOR_CALLHOOK, RES_LIMIT_NONE, and SetResourceExplicit().

Referenced by GiveResource(), and TakeResource().

{
    bool forbid = MUTATOR_CALLHOOK(SetResource, e, res_type, amount);
    if (forbid)
    {
        return;
    }
    res_type = M_ARGV(1, entity);
    amount = M_ARGV(2, float);
    float max_amount = GetResourceLimit(e, res_type); // TODO: should allow overriding these limits if cheats are enabled!
    float amount_wasted = 0;
    if (amount > max_amount && max_amount != RES_LIMIT_NONE)
    {
        amount_wasted = amount - max_amount;
        amount = max_amount;
    }
    bool changed = SetResourceExplicit(e, res_type, amount);
    if (changed)
    {
        MUTATOR_CALLHOOK(ResourceAmountChanged, e, res_type, amount);
    }
    if (amount_wasted == 0)
    {
        return;
    }
    MUTATOR_CALLHOOK(ResourceWasted, e, res_type, amount_wasted);
}

Here is the call graph for this function:

Here is the caller graph for this function:

SetResourceExplicit()

bool SetResourceExplicit	(	entity	e,
		Resource	res_type,
		float	amount
	)

Sets the resource amount of an entity without calling any hooks.

Parameters

[in,out]	e	Entity to adjust.
[in]	res_type	Type of the resource (a RES_* constant).
[in]	amount	Amount of resource to set.

Returns

Boolean for whether the ammo amount was changed

Definition at line 81 of file sv_resources.qc.

Referenced by SetResource().

{
    .float res_field = GetResourceField(res_type);
    if (e.(res_field) != amount)
    {
        e.(res_field) = amount;
        return true;
    }
    return false;
}

Here is the caller graph for this function:

TakeResource()

void TakeResource	(	entity	receiver,
		Resource	res_type,
		float	amount
	)

Takes an entity some resource.

Parameters

[in,out]	receiver	Entity to take resource from.
[in]	res_type	Type of the resource (a RES_* constant).
[in]	amount	Amount of resource to take.

Returns

No return.

Definition at line 190 of file sv_resources.qc.

References entity(), GetResource(), M_ARGV, MUTATOR_CALLHOOK, and SetResource().

Referenced by TakeResourceWithLimit().

{
    if (amount <= 0)
    {
        return;
    }
    bool forbid = MUTATOR_CALLHOOK(TakeResource, receiver, res_type, amount);
    if (forbid)
    {
        return;
    }
    res_type = M_ARGV(1, entity);
    amount = M_ARGV(2, float);
    if (amount <= 0)
    {
        return;
    }
    SetResource(receiver, res_type, GetResource(receiver, res_type) - amount);
}

Here is the call graph for this function:

Here is the caller graph for this function:

TakeResourceWithLimit()

void TakeResourceWithLimit	(	entity	receiver,
		Resource	res_type,
		float	amount,
		float	limit
	)

Takes an entity some resource but not less than a limit.

Parameters

[in,out]	receiver	Entity to take resource from.
[in]	res_type	Type of the resource (a RES_* constant).
[in]	amount	Amount of resource to take.
[in]	limit	Limit of resources to take.

Returns

No return.

Definition at line 210 of file sv_resources.qc.

References entity(), GetResource(), M_ARGV, MUTATOR_CALLHOOK, and TakeResource().

{
    if (amount <= 0)
    {
        return;
    }
    bool forbid = MUTATOR_CALLHOOK(TakeResourceWithLimit, receiver, res_type, amount, limit);
    if (forbid)
    {
        return;
    }
    res_type = M_ARGV(1, entity);
    amount = M_ARGV(2, float);
    limit = M_ARGV(3, float);
    if (amount <= 0)
    {
        return;
    }
    float current_amount = GetResource(receiver, res_type);
    if (current_amount - amount < -limit)
    {
        amount = -limit + current_amount;
    }
    TakeResource(receiver, res_type, amount);
}

Here is the call graph for this function: