impulse.qc File Reference

#include "impulse.qh"

Include dependency graph for impulse.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
void	trigger_impulse_touch_accel (entity this, entity toucher)
void	trigger_impulse_touch_directional (entity this, entity toucher)
void	trigger_impulse_touch_radial (entity this, entity toucher)

Function Documentation

trigger_impulse_touch_accel()

void trigger_impulse_touch_accel	(	entity	this,
		entity	toucher
	)

Definition at line 59 of file impulse.qc.

References active, ACTIVE_ACTIVE, EXACTTRIGGER_TOUCH, IMPULSE_MAX_PUSHDELTATIME, isPushable(), strength, time, and UpdateCSQCProjectile().

Referenced by trigger_impulse_touch_radial().

{
    float pushdeltatime;

    if (this.active != ACTIVE_ACTIVE)
        return;

    if (!isPushable(toucher))
        return;

    EXACTTRIGGER_TOUCH(this, toucher);

    pushdeltatime = time - toucher.lastpushtime;
    if (pushdeltatime > IMPULSE_MAX_PUSHDELTATIME)
    {
        pushdeltatime = 0;
    }
    toucher.lastpushtime = time;
    if(!pushdeltatime)
    {
        return;
    }

    // div0: ticrate independent, 1 = identity (not 20)
    toucher.velocity = toucher.velocity * (this.strength ** pushdeltatime);

#ifdef SVQC
    UpdateCSQCProjectile(toucher);
#endif
}

Here is the call graph for this function:

Here is the caller graph for this function:

trigger_impulse_touch_directional()

void trigger_impulse_touch_directional	(	entity	this,
		entity	toucher
	)

Definition at line 3 of file impulse.qc.

References active, ACTIVE_ACTIVE, entity(), EXACTTRIGGER_TOUCH, find(), IMPULSE_DIRECTIONAL_MAX_ACCEL_FACTOR, IMPULSE_DIRECTIONAL_SPEEDTARGET, IMPULSE_MAX_PUSHDELTATIME, isPushable(), min(), normalize(), NULL, objerror(), spawnflags, strength, target, targetname, time, UNSET_ONGROUND, and UpdateCSQCProjectile().

Referenced by trigger_impulse_touch_radial().

{
    entity targ;
    float pushdeltatime;
    float str;

    if (this.active != ACTIVE_ACTIVE)
        return;

    if (!isPushable(toucher))
        return;

    EXACTTRIGGER_TOUCH(this, toucher);

    targ = find(NULL, targetname, this.target);
    if(!targ)
    {
        objerror(this, "trigger_force without a (valid) .target!\n");
        delete(this);
        return;
    }

    // falloff is not supported because radius is always 0 in directional mode
    str = this.strength;

    pushdeltatime = time - toucher.lastpushtime;
    if (pushdeltatime > IMPULSE_MAX_PUSHDELTATIME)
    {
        pushdeltatime = 0;
    }
    toucher.lastpushtime = time;
    if(!pushdeltatime)
    {
        return;
    }

    if(this.spawnflags & IMPULSE_DIRECTIONAL_SPEEDTARGET)
    {
        float addspeed = str - toucher.velocity * normalize(targ.origin - this.origin);
        if (addspeed > 0)
        {
            float accelspeed = min(IMPULSE_DIRECTIONAL_MAX_ACCEL_FACTOR * pushdeltatime * str, addspeed);
            toucher.velocity += accelspeed * normalize(targ.origin - this.origin);
        }
    }
    else
        toucher.velocity = toucher.velocity + normalize(targ.origin - this.origin) * str * pushdeltatime;

    UNSET_ONGROUND(toucher);

#ifdef SVQC
    UpdateCSQCProjectile(toucher);
#endif
}

Here is the call graph for this function:

Here is the caller graph for this function:

trigger_impulse_touch_radial()

void trigger_impulse_touch_radial	(	entity	this,
		entity	toucher
	)

Definition at line 91 of file impulse.qc.

References active, ACTIVE_ACTIVE, entity(), EXACTTRIGGER_TOUCH, falloff, FALLOFF_LINEAR, FALLOFF_LINEAR_INV, IMPULSE_DEFAULT_ACCEL_STRENGTH, IMPULSE_DEFAULT_DIRECTIONAL_STRENGTH, IMPULSE_DEFAULT_RADIAL_STRENGTH, IMPULSE_MAX_PUSHDELTATIME, isPushable(), min(), move_time, NET_HANDLE, normalize(), origin, radius, REGISTER_NET_LINKED, setorigin(), solid, SOLID_TRIGGER, spawnflags, spawnfunc(), strength, target, time, to, trigger_impulse_touch_accel(), trigger_impulse_touch_directional(), UpdateCSQCProjectile(), vlen(), WriteByte(), and WriteCoord().

{
    float pushdeltatime;
    float str;

    if (this.active != ACTIVE_ACTIVE)
        return;

    if (!isPushable(toucher))
        return;

    EXACTTRIGGER_TOUCH(this, toucher);

    pushdeltatime = time - toucher.lastpushtime;
    if (pushdeltatime > IMPULSE_MAX_PUSHDELTATIME)
    {
        pushdeltatime = 0;
    }
    toucher.lastpushtime = time;
    if(!pushdeltatime)
    {
        return;
    }

    setsize(this, '-1 -1 -1' * this.radius,'1 1 1' * this.radius);

    str = min(this.radius, vlen(this.origin - toucher.origin));

    if(this.falloff == FALLOFF_LINEAR)
        str = (1 - str / this.radius) * this.strength; // 1 in the inside
    else if(this.falloff == FALLOFF_LINEAR_INV)
        str = (str / this.radius) * this.strength; // 0 in the inside
    else
        str = this.strength;

    toucher.velocity = toucher.velocity + normalize(toucher.origin - this.origin) * str * pushdeltatime;

#ifdef SVQC
    UpdateCSQCProjectile(toucher);
#endif
}

Here is the call graph for this function: