scores.qh File Reference

#include <common/scores.qh>

Include dependency graph for scores.qh:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Macros
#define	PlayerScore_Get(player, scorefield)   PlayerScore_Add(player, scorefield, 0)
	Returns the player's score. More...
#define	WINNINGCONDITIONHELPER_LOWERISBETTER_WORST   999999999

Functions
string	GetPlayerScoreString (entity pl, float shortString)
	Returns score strings for eventlog etc. More...
string	GetTeamScoreString (float tm, float shortString)
float	PlayerScore_Add (entity player, PlayerScoreField scorefield, float score)
	Adds a score to the player's scores. More...
void	PlayerScore_Attach (entity player)
	Attaches a PlayerScore entity to a player. More...
float	PlayerScore_Clear (entity player)
	Initialize the score of this player if needed. More...
void	PlayerScore_Detach (entity player)
	Detaches a PlayerScore entity from the player. More...
float	PlayerScore_Set (entity player, PlayerScoreField scorefield, float score)
	Sets the player's score to the score parameter. More...
entity	PlayerScore_Sort (.float field, int teams, bool strict, bool nospectators)
	Sorts the players and stores their place in the given field, starting with. More...
float	PlayerTeamScore_Add (entity player, PlayerScoreField pscorefield, float tscorefield, float score)
	Adds a score to both the player and the team. More...
void	Score_ClearAll ()
	Clear ALL scores (for ready-restart). More...
void	Score_NicePrint (entity to)
	Prints the scores to the console of a player. More...
void	ScoreInfo_Init (float teams)
	Initialize the scores info for the given number of teams. More...
void	ScoreInfo_SetLabel_PlayerScore (PlayerScoreField i, string label, float scoreflags)
	Set the label of a player score item, as well as the scoring flags. More...
void	ScoreInfo_SetLabel_TeamScore (float i, string label, float scoreflags)
	Set the label of a team score item, as well as the scoring flags. More...
float	TeamScore_Add (entity player, float scorefield, float score)
	Adds a score to the player's team's scores. More...
float	TeamScore_AddToTeam (int t, float scorefield, float score)
	Adds a score to the given team. More...
float	TeamScore_GetCompareValue (float t)
	Returns a value indicating the team score (and higher is better). More...
void	WinningConditionHelper (entity this)
	Sets the following results for the current scores entities. More...

Variables
bool	autocvar_g_full_getstatus_responses
float	scoreboard_pos
entity	scores_initialized
float	WinningConditionHelper_equality
	we have no winner More...
float	WinningConditionHelper_lowerisbetter
	lower is better, duh More...
entity	WinningConditionHelper_second
	the second player, or NULL if none More...
float	WinningConditionHelper_secondscore
	second highest score More...
float	WinningConditionHelper_secondteam
	the color of the second team, or -1 if none More...
float	WinningConditionHelper_topscore
	highest score More...
entity	WinningConditionHelper_winner
	the winning player, or NULL if none More...
float	WinningConditionHelper_winnerteam
	the color of the winning team, or -1 if none More...
float	WinningConditionHelper_zeroisworst
	zero is worst, duh More...

Macro Definition Documentation

PlayerScore_Get

#define PlayerScore_Get	(		player,
			scorefield
	)		PlayerScore_Add(player, scorefield, 0)

Returns the player's score.

Parameters

[in]	player	Player to inspect.
[in]	scorefield	Field of the score.

Returns

Player's score.

Definition at line 43 of file scores.qh.

Referenced by DynamicHandicap_UpdateHandicap(), MUTATOR_HOOKFUNCTION(), and TeamBalance_GetPlayerForTeamSwitch().

WINNINGCONDITIONHELPER_LOWERISBETTER_WORST

#define WINNINGCONDITIONHELPER_LOWERISBETTER_WORST   999999999

Definition at line 117 of file scores.qh.

Function Documentation

GetPlayerScoreString()

string GetPlayerScoreString	(	entity	pl,
		float	shortString
	)

Returns score strings for eventlog etc.

When called with NULL, or 0, as argument, they return the labels in the same order. The strings are comma separated; labels that end with !! designate primary, labels that end with ! designate high priority. Labels get an appended < if the scores are better if smaller (e.g. deaths). High priorities always come first. Example label string: score!!,kills,deaths<,suicides< If shortString is set, only the sort keys are returned.

Definition at line 586 of file scores.qc.

References CS(), entity(), FOREACH, ftos(), GetScoreLogLabel(), scorekeeper, scores_flags, scores_label, SFL_SORT_PRIO_MASK, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_SECONDARY, strcat(), strlen(), and substring().

Referenced by DumpStats(), and WinningConditionHelper().

{
    string out;
    entity sk;
    float f;
    string l;

    out = "";
    if(!pl)
    {
        // label
        FOREACH(Scores, true, {
            if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
            {
                f = scores_flags(it);
                l = scores_label(it);
                out = strcat(out, GetScoreLogLabel(l, f), ",");
            }
        });
        if(shortString < 2)
        FOREACH(Scores, true, {
            if((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
            {
                f = scores_flags(it);
                l = scores_label(it);
                out = strcat(out, GetScoreLogLabel(l, f), ",");
            }
        });
        if(shortString < 1)
        FOREACH(Scores, true, {
            if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
            if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
            {
                f = scores_flags(it);
                l = scores_label(it);
                out = strcat(out, GetScoreLogLabel(l, f), ",");
            }
        });
        out = substring(out, 0, strlen(out) - 1);
    }
    else if((sk = CS(pl).scorekeeper))
    {
        FOREACH(Scores, true, {
            if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
                out = strcat(out, ftos(sk.(scores(it))), ",");
        });
        if(shortString < 2)
        FOREACH(Scores, true, {
            if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
                out = strcat(out, ftos(sk.(scores(it))), ",");
        });
        if(shortString < 1)
        FOREACH(Scores, true, {
            if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
            if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
                out = strcat(out, ftos(sk.(scores(it))), ",");
        });
        out = substring(out, 0, strlen(out) - 1);
    }
    return out;
}

Here is the call graph for this function:

Here is the caller graph for this function:

GetTeamScoreString()

string GetTeamScoreString	(	float	tm,
		float	shortString
	)

Definition at line 648 of file scores.qc.

References entity(), ftos(), GetScoreLogLabel(), MAX_TEAMSCORE, SFL_SORT_PRIO_MASK, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_SECONDARY, strcat(), strlen(), substring(), teamscorekeepers, teamscores_flags, and teamscores_label.

Referenced by DumpStats(), and WinningConditionHelper().

{
    string out;
    entity sk;
    float i, f;
    string l;

    out = "";
    if(tm == 0)
    {
        // label
        for(i = 0; i < MAX_TEAMSCORE; ++i)
            if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
            {
                f = teamscores_flags(i);
                l = teamscores_label(i);
                out = strcat(out, GetScoreLogLabel(l, f), ",");
            }
        if(shortString < 2)
        for(i = 0; i < MAX_TEAMSCORE; ++i)
            if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
            {
                f = teamscores_flags(i);
                l = teamscores_label(i);
                out = strcat(out, GetScoreLogLabel(l, f), ",");
            }
        if(shortString < 1)
        for(i = 0; i < MAX_TEAMSCORE; ++i)
            if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
            if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
            {
                f = teamscores_flags(i);
                l = teamscores_label(i);
                out = strcat(out, GetScoreLogLabel(l, f), ",");
            }
        out = substring(out, 0, strlen(out) - 1);
    }
    else if((sk = teamscorekeepers[tm - 1]))
    {
        for(i = 0; i < MAX_TEAMSCORE; ++i)
            if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
                out = strcat(out, ftos(sk.(teamscores(i))), ",");
        if(shortString < 2)
        for(i = 0; i < MAX_TEAMSCORE; ++i)
            if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
                out = strcat(out, ftos(sk.(teamscores(i))), ",");
        if(shortString < 1)
        for(i = 0; i < MAX_TEAMSCORE; ++i)
            if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
            if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
                out = strcat(out, ftos(sk.(teamscores(i))), ",");
        out = substring(out, 0, strlen(out) - 1);
    }
    return out;
}

Here is the call graph for this function:

Here is the caller graph for this function:

PlayerScore_Add()

float PlayerScore_Add	(	entity	player,
		PlayerScoreField	scorefield,
		float	score
	)

Adds a score to the player's scores.

NEVER call this if PlayerScore_Attach has not been called yet! Means: FIXME make players unable to join the game when not called ClientConnect yet. Returns the new score.

Definition at line 336 of file scores.qc.

References BIT, CS(), entity(), LOG_WARN, M_ARGV, MUTATOR_CALLHOOK, scores_initialized, scores_label, strcat(), and warmup_stage.

Referenced by _GameRules_scoring_add(), _GameRules_scoring_add_float2int(), and PlayerTeamScore_Add().

{
    bool mutator_returnvalue = MUTATOR_CALLHOOK(AddPlayerScore, scorefield, score, player);
    score = M_ARGV(1, float);

    if(!mutator_returnvalue && game_stopped)
    {
        score = 0;
    }

    if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
    entity s = CS(player).scorekeeper;
    if(!s)
    {
        if(game_stopped)
            return 0;
        LOG_WARN("Adding score to unknown player!");
        return 0;
    }
    if(!score)
    {
        return s.(scores(scorefield));
    }
    if(scores_label(scorefield) != "")
        s.SendFlags |= BIT(scorefield.m_id % 16);
    if(!warmup_stage)
        PlayerStats_GameReport_Event_Player(s.owner, strcat(PLAYERSTATS_TOTAL, scores_label(scorefield)), score);
    s.(scores(scorefield)) += score;
    MUTATOR_CALLHOOK(AddedPlayerScore, scorefield, score, player);
    return s.(scores(scorefield));
}

Here is the call graph for this function:

Here is the caller graph for this function:

PlayerScore_Attach()

void PlayerScore_Attach

(

entity

player

)

Attaches a PlayerScore entity to a player.

Use that in ClientConnect. Remember to detach it in ClientDisconnect!

Definition at line 318 of file scores.qc.

References CS(), entity(), error(), new_pure, PlayerScore_SendEntity(), and scorekeeper.

{
    if(CS(player).scorekeeper)
        error("player already has a scorekeeper");
    entity sk = new_pure(scorekeeper);
    sk.owner = player;
    Net_LinkEntity(sk, false, 0, PlayerScore_SendEntity);
    CS(player).scorekeeper = sk;
}

Here is the call graph for this function:

PlayerScore_Clear()

float PlayerScore_Clear

(

entity

player

)

Initialize the score of this player if needed.

Does nothing in teamplay. Use that when a spectator becomes a player. Returns whether clearing has been performed

Definition at line 267 of file scores.qc.

References BIT, CS(), entity(), FOREACH, MUTATOR_CALLHOOK, scores_label, and teamscores_entities_count.

Referenced by PutPlayerInServer(), and SetPlayerTeam().

{
    entity sk;

    if(teamscores_entities_count)
        return 0;

    if(MUTATOR_CALLHOOK(ForbidPlayerScore_Clear)) return 0;

    sk = CS(player).scorekeeper;
    FOREACH(Scores, true, {
        if(sk.(scores(it)) != 0)
            if(scores_label(it) != "")
                sk.SendFlags |= BIT(i % 16);
        if(i != SP_ELO.m_id)
            sk.(scores(it)) = 0;
    });

    return 1;
}

Here is the call graph for this function:

Here is the caller graph for this function:

PlayerScore_Detach()

void PlayerScore_Detach

(

entity

player

)

Detaches a PlayerScore entity from the player.

Use that in ClientDisconnect.

Definition at line 328 of file scores.qc.

References CS(), error(), NULL, and scorekeeper.

{
    if(!CS(player).scorekeeper)
        error("player has no scorekeeper");
    delete(CS(player).scorekeeper);
    CS(player).scorekeeper = NULL;
}

Here is the call graph for this function:

PlayerScore_Set()

float PlayerScore_Set	(	entity	player,
		PlayerScoreField	scorefield,
		float	score
	)

Sets the player's score to the score parameter.

NEVER call this if PlayerScore_Attach has not been called yet! Means: FIXME make players unable to join the game when not called ClientConnect yet. Returns the new (or old if unchanged) score.

Definition at line 368 of file scores.qc.

References BIT, CS(), entity(), LOG_WARN, scores_initialized, and scores_label.

Referenced by NET_HANDLE().

{
    if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
    entity s = CS(player).scorekeeper;
    if(!s)
    {
        if(game_stopped)
            return 0;
        LOG_WARN("Setting score of unknown player!");
        return 0;
    }

    float oldscore = s.(scores(scorefield));
    if(oldscore == score)
        return oldscore;

    if(scores_label(scorefield) != "")
        s.SendFlags |= BIT(scorefield.m_id % 16);
    s.(scores(scorefield)) = score;
    return s.(scores(scorefield));
}

Here is the call graph for this function:

Here is the caller graph for this function:

PlayerScore_Sort()

entity PlayerScore_Sort	(	.float	field,
		int	teams,
		bool	strict,
		bool	nospectators
	)

Sorts the players and stores their place in the given field, starting with.

1. Non-players get 0 written into that field. Returns the beginning of a sorted chain of the non-spectators. teams: >0: sort by teams first (always strict ordering); <0: sort by teams only (respects strict flag) strict: return a strict ordering nospectators: exclude spectators

Definition at line 724 of file scores.qc.

References CS(), entity(), FOREACH_CLIENT, FRAGS_SPECTATOR, NULL, PlayerTeamScore_Compare(), and scorekeeper.

Referenced by MUTATOR_HOOKFUNCTION(), and Score_NicePrint().

{
    entity p, plist, pprev, pbest, pbestprev, pfirst, plast;
    float i, j;

    plist = NULL;

    FOREACH_CLIENT(true, { it.(field) = 0; });

    FOREACH_CLIENT(CS(it).scorekeeper,
    {
        if(nospectators)
            if(it.frags == FRAGS_SPECTATOR)
                continue;

        it.chain = plist;
        plist = it;
    });
    // Now plist points to the whole list.

    pfirst = plast = NULL;

    i = j = 0;
    while(plist)
    {
        pprev = pbestprev = NULL;
        pbest = plist;
        for(p = plist; (pprev = p), (p = p.chain); )
        {
            if(PlayerTeamScore_Compare(p, pbest, teams, strict) > 0)
            {
                pbest = p;
                pbestprev = pprev;
            }
        }

        // remove pbest out of the chain
        if(pbestprev == NULL)
            plist = pbest.chain;
        else
            pbestprev.chain = pbest.chain;
        pbest.chain = NULL;

        ++i;
        if(!plast || PlayerTeamScore_Compare(plast, pbest, teams, strict))
            j = i;

        pbest.(field) = j;

        if (!pfirst)
            pfirst = pbest;
        if(plast)
            plast.chain = pbest;
        plast = pbest;
    }

    return pfirst;
}

Here is the call graph for this function:

Here is the caller graph for this function:

PlayerTeamScore_Add()

float PlayerTeamScore_Add	(	entity	player,
		PlayerScoreField	pscorefield,
		float	tscorefield,
		float	score
	)

Adds a score to both the player and the team.

Returns the team score if possible, otherwise the player score.

Definition at line 390 of file scores.qc.

References PlayerScore_Add(), TeamScore_Add(), and teamscores_entities_count.

Referenced by _GameRules_scoring_add_team().

{
    float r;
    r = PlayerScore_Add(player, pscorefield, score);
    if(teamscores_entities_count) // only for teamplay
        r = TeamScore_Add(player, tscorefield, score);
    return r;
}

Here is the call graph for this function:

Here is the caller graph for this function:

Score_ClearAll()

void Score_ClearAll

(

)

Clear ALL scores (for ready-restart).

Definition at line 288 of file scores.qc.

References BIT, CS(), entity(), FOREACH, FOREACH_CLIENTSLOT, MAX_TEAMSCORE, scores_label, teamscorekeepers, and teamscores_label.

Referenced by reset_map().

{
    entity sk;
    float t;
    FOREACH_CLIENTSLOT(true, {
        sk = CS(it).scorekeeper;
        if (!sk) continue;
        FOREACH(Scores, true, {
            if(sk.(scores(it)) != 0)
                if(scores_label(it) != "")
                    sk.SendFlags |= BIT(i % 16);
            if(i != SP_ELO.m_id)
                sk.(scores(it)) = 0;
        });
    });
    for(t = 0; t < 16; ++t)
    {
        sk = teamscorekeepers[t];
        if(!sk)
            continue;
        for(int j = 0; j < MAX_TEAMSCORE; ++j)
        {
            if(sk.(teamscores(j)) != 0)
                if(teamscores_label(j) != "")
                    sk.SendFlags |= BIT(j);
            sk.(teamscores(j)) = 0;
        }
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

Score_NicePrint()

void Score_NicePrint

(

entity

to

)

Prints the scores to the console of a player.

Definition at line 903 of file scores.qc.

References bound(), entity(), floor(), FOREACH, FOREACH_CLIENT, IS_PLAYER, PlayerScore_Sort(), score_dummyfield, Score_NicePrint_Player(), Score_NicePrint_Spectator(), Score_NicePrint_Spectators(), Score_NicePrint_Team(), scores_label, SCORESWIDTH, and teamscores_entities_count.

Referenced by CommonCommand_teamstatus(), and MUTATOR_HOOKFUNCTION().

{
    entity p;
    float w;

    int t = 0;
    FOREACH(Scores, true, {
        if(scores_label(it) != "")
            ++t;
    });
    w = bound(6, floor(SCORESWIDTH / t - 1), 9);

    p = PlayerScore_Sort(score_dummyfield, 1, true, false);
    t = -1;

    if(!teamscores_entities_count)
        Score_NicePrint_Team(to, t, w);
    while(p)
    {
        if(teamscores_entities_count)
            if(t != p.team)
                Score_NicePrint_Team(to, p.team, w);
        Score_NicePrint_Player(to, p, w);
        t = p.team;
        p = p.chain;
    }

    t = 0;
    FOREACH_CLIENT(!IS_PLAYER(it), {
        if (!t)
            Score_NicePrint_Spectators(to);
        Score_NicePrint_Spectator(to, it);
        t = 1;
    });
}

Here is the call graph for this function:

Here is the caller graph for this function:

ScoreInfo_Init()

void ScoreInfo_Init

(

float

teams

)

Initialize the scores info for the given number of teams.

Set all labels right before this call.

ScoreInfo_SetLabel_PlayerScore()

void ScoreInfo_SetLabel_PlayerScore	(	PlayerScoreField	i,
		string	label,
		float	scoreflags
	)

Set the label of a player score item, as well as the scoring flags.

Definition at line 165 of file scores.qc.

References scores, scores_flags, scores_flags_primary, scores_label, scores_primary, SFL_SORT_PRIO_MASK, SFL_SORT_PRIO_PRIMARY, and strcat().

Referenced by _GameRules_scoring_field(), and ScoreRules_basics().

{
    scores_label(i) = label;
    scores_flags(i) = scoreflags;
    if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
    {
        scores_primary = scores(i);
        scores_flags_primary = scoreflags;
    }
    if(label != "")
    {
        PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
        PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

ScoreInfo_SetLabel_TeamScore()

void ScoreInfo_SetLabel_TeamScore	(	float	i,
		string	label,
		float	scoreflags
	)

Set the label of a team score item, as well as the scoring flags.

Definition at line 181 of file scores.qc.

References SFL_SORT_PRIO_MASK, SFL_SORT_PRIO_PRIMARY, strcat(), teamscores, teamscores_flags, teamscores_flags_primary, teamscores_label, and teamscores_primary.

Referenced by _GameRules_scoring_field_team(), and ScoreRules_basics().

{
    teamscores_label(i) = label;
    teamscores_flags(i) = scoreflags;
    if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
    {
        teamscores_primary = teamscores(i);
        teamscores_flags_primary = scoreflags;
    }
    if(label != "")
    {
        PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
        PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

TeamScore_Add()

float TeamScore_Add	(	entity	player,
		float	scorefield,
		float	score
	)

Adds a score to the player's team's scores.

NEVER call this if team has not been set yet! Returns the new score.

Definition at line 137 of file scores.qc.

References TeamScore_AddToTeam().

Referenced by PlayerTeamScore_Add().

{
    return TeamScore_AddToTeam(player.team, scorefield, score);
}

Here is the call graph for this function:

Here is the caller graph for this function:

TeamScore_AddToTeam()

float TeamScore_AddToTeam	(	int	t,
		float	scorefield,
		float	score
	)

Adds a score to the given team.

NEVER call this if team has not been set yet! Returns the new score.

Definition at line 108 of file scores.qc.

References BIT, entity(), error(), scores_initialized, teamscorekeepers, and teamscores_label.

Referenced by CA_CheckWinner(), ctf_Handle_Return(), Domination_CheckWinner(), dompointthink(), freezetag_CheckWinner(), GoalTouch(), MUTATOR_HOOKFUNCTION(), Onslaught_CheckWinner(), TeamScore_Add(), WinningCondition_Assault(), and WinningCondition_RanOutOfSpawns().

{
    entity s;

    if(game_stopped)
    {
        score = 0;
    }

    if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
    if(t <= 0 || t >= 16)
    {
        if(game_stopped)
            return 0;
        error("Adding score to invalid team!");
    }
    s = teamscorekeepers[t - 1];
    if(!s)
    {
        if(game_stopped)
            return 0;
        error("Adding score to unknown team!");
    }
    if(score)
        if(teamscores_label(scorefield) != "")
            s.SendFlags |= BIT(scorefield);
    return (s.(teamscores(scorefield)) += score);
}

Here is the call graph for this function:

Here is the caller graph for this function:

TeamScore_GetCompareValue()

float TeamScore_GetCompareValue

(

float

t

)

Returns a value indicating the team score (and higher is better).

Definition at line 783 of file scores.qc.

References entity(), error(), SFL_LOWER_IS_BETTER, SFL_ZERO_IS_WORST, teamscorekeepers, and teamscores_flags_primary.

Referenced by WinningCondition_Scores().

{
    float s;
    entity sk;

    if(t <= 0 || t >= 16)
    {
        if(game_stopped)
            return 0;
        error("Reading score of invalid team!");
    }

    sk = teamscorekeepers[t - 1];
    if (!sk)
        return -999999999;
    s = sk.teamscores_primary;
    if(teamscores_flags_primary & SFL_ZERO_IS_WORST)
        if(!s)
            return -999999999;
    if(teamscores_flags_primary & SFL_LOWER_IS_BETTER)
        s = -s;
    return s;
}

Here is the call graph for this function:

Here is the caller graph for this function:

WinningConditionHelper()

void WinningConditionHelper

(

entity

this

)

Sets the following results for the current scores entities.

Definition at line 415 of file scores.qc.

References autocvar_g_full_getstatus_responses, autocvar_g_xonoticversion, CS(), cvar_purechanges_count, entity(), FOREACH_CLIENT, ftos(), GetGametype(), GetPlayerScoreString(), GetTeamScoreString(), INGAME_JOINED, IS_PLAYER, IS_REAL_CLIENT, modname, nJoinAllowed(), NULL, player_count, PlayerScore_Compare(), scores_flags_primary, serverflags, SFL_LOWER_IS_BETTER, SFL_ZERO_IS_WORST, strcat(), strcpy, sv_termsofservice_url_escaped, TeamScore_Compare(), teamscorekeepers, teamscores_entities_count, teamscores_flags_primary, WinningConditionHelper_equality, WinningConditionHelper_lowerisbetter, WinningConditionHelper_second, WinningConditionHelper_secondscore, WinningConditionHelper_secondteam, WinningConditionHelper_topscore, WinningConditionHelper_winner, WinningConditionHelper_winnerteam, WinningConditionHelper_zeroisworst, and worldstatus.

Referenced by spawnfunc(), WinningCondition_Assault(), WinningCondition_Invasion(), WinningCondition_LMS(), and WinningCondition_Scores().

{
    float c;
    string s;
    float fullstatus;
    entity winnerscorekeeper;
    entity secondscorekeeper;
    entity sk;

    // format:
    // gametype:P<pure>:S<slots>::plabel,plabel:tlabel,tlabel:teamid:tscore,tscore:teamid:tscore,tscore
    // score labels always start with a symbol or with lower case
    // so to match pure, match for :P0:
    // to match full, match for :S0:

    fullstatus = autocvar_g_full_getstatus_responses;

    s = GetGametype();
    s = strcat(s, ":", autocvar_g_xonoticversion);
    s = strcat(s, ":P", ftos(cvar_purechanges_count));
    s = strcat(s, ":S", ftos(nJoinAllowed(this, NULL)));
    s = strcat(s, ":F", ftos(serverflags));
    s = strcat(s, ":T", sv_termsofservice_url_escaped);
    s = strcat(s, ":M", modname);
    s = strcat(s, "::", GetPlayerScoreString(NULL, (fullstatus ? 1 : 2)));

    if(teamscores_entities_count)
    {
        float t;

        s = strcat(s, ":", GetTeamScoreString(0, 1));
        for(t = 0; t < 16; ++t)
            if(teamscorekeepers[t])
                s = strcat(s, ":", ftos(t+1), ":", GetTeamScoreString(t+1, 1));

        WinningConditionHelper_winnerteam = -1;
        WinningConditionHelper_secondteam = -1;
        winnerscorekeeper = NULL;
        secondscorekeeper = NULL;
        for(t = 0; t < 16; ++t)
        {
            sk = teamscorekeepers[t];
            c = TeamScore_Compare(winnerscorekeeper, sk, 1);
            if(c < 0)
            {
                WinningConditionHelper_secondteam = WinningConditionHelper_winnerteam;
                WinningConditionHelper_winnerteam = t + 1;
                secondscorekeeper = winnerscorekeeper;
                winnerscorekeeper = sk;
            }
            else
            {
                c = TeamScore_Compare(secondscorekeeper, sk, 1);
                if(c < 0)
                {
                    WinningConditionHelper_secondteam = t + 1;
                    secondscorekeeper = sk;
                }
            }
        }

        WinningConditionHelper_equality = (TeamScore_Compare(winnerscorekeeper, secondscorekeeper, 0) == 0);
        if(WinningConditionHelper_equality)
            WinningConditionHelper_winnerteam = WinningConditionHelper_secondteam = -1;

        WinningConditionHelper_topscore = winnerscorekeeper.teamscores_primary;
        WinningConditionHelper_secondscore = secondscorekeeper.teamscores_primary;
        WinningConditionHelper_lowerisbetter = (teamscores_flags_primary & SFL_LOWER_IS_BETTER);
        WinningConditionHelper_zeroisworst = (teamscores_flags_primary & SFL_ZERO_IS_WORST);

        WinningConditionHelper_winner = NULL; // not supported in teamplay
        WinningConditionHelper_second = NULL; // not supported in teamplay
    }
    else
    {
        WinningConditionHelper_winner = NULL;
        WinningConditionHelper_second = NULL;
        winnerscorekeeper = NULL;
        secondscorekeeper = NULL;
        FOREACH_CLIENT(IS_PLAYER(it), {
            sk = CS(it).scorekeeper;
            c = PlayerScore_Compare(winnerscorekeeper, sk, true);
            if(c < 0)
            {
                WinningConditionHelper_second = WinningConditionHelper_winner;
                WinningConditionHelper_winner = it;
                secondscorekeeper = winnerscorekeeper;
                winnerscorekeeper = sk;
            }
            else
            {
                c = PlayerScore_Compare(secondscorekeeper, sk, true);
                if(c < 0)
                {
                    WinningConditionHelper_second = it;
                    secondscorekeeper = sk;
                }
            }
        });

        WinningConditionHelper_equality = (PlayerScore_Compare(winnerscorekeeper, secondscorekeeper, false) == 0);
        if(WinningConditionHelper_equality)
            WinningConditionHelper_winner = WinningConditionHelper_second = NULL;

        WinningConditionHelper_topscore = winnerscorekeeper.scores_primary;
        WinningConditionHelper_secondscore = secondscorekeeper.scores_primary;
        WinningConditionHelper_lowerisbetter = (scores_flags_primary & SFL_LOWER_IS_BETTER);
        WinningConditionHelper_zeroisworst = (scores_flags_primary & SFL_ZERO_IS_WORST);

        WinningConditionHelper_winnerteam = -1; // no teamplay
        WinningConditionHelper_secondteam = -1; // no teamplay
    }

    if(WinningConditionHelper_topscore == 0)
    {
        if(scores_flags_primary & SFL_ZERO_IS_WORST)
        {
            if(WinningConditionHelper_lowerisbetter)
                WinningConditionHelper_topscore = 999999999;
            else
                WinningConditionHelper_topscore = -999999999;
        }
        if(player_count == 0) // special case: empty servers DO end the match at a 0:0 tie
            WinningConditionHelper_equality = 0;
    }

    if(WinningConditionHelper_secondscore == 0)
    {
        if(scores_flags_primary & SFL_ZERO_IS_WORST)
        {
            if(WinningConditionHelper_lowerisbetter)
                WinningConditionHelper_secondscore = 999999999;
            else
                WinningConditionHelper_secondscore = -999999999;
        }
    }

    strcpy(worldstatus, s);

    FOREACH_CLIENT(true, {
        string s = "";
        if(fullstatus)
        {
            s = GetPlayerScoreString(it, 1);
            s = strcat(s, IS_REAL_CLIENT(it) ? ":human" : ":bot");
            if(!(IS_PLAYER(it) || INGAME_JOINED(it)))
                s = strcat(s, ":spectator");
        }
        else
        {
            if (IS_PLAYER(it) || INGAME_JOINED(it))
                s = GetPlayerScoreString(it, 2);
            else
                s = "-666";
        }

        strcpy(it.clientstatus, s);
    });
}

Here is the call graph for this function:

Here is the caller graph for this function:

Variable Documentation

autocvar_g_full_getstatus_responses

bool autocvar_g_full_getstatus_responses

Definition at line 5 of file scores.qh.

Referenced by WinningConditionHelper().

scoreboard_pos

float scoreboard_pos

Definition at line 8 of file scores.qh.

scores_initialized

entity scores_initialized

Definition at line 7 of file scores.qh.

Referenced by GameplayMode_DelayedInit(), PlayerScore_Add(), PlayerScore_Set(), ScoreInfo_Init(), and TeamScore_AddToTeam().

WinningConditionHelper_equality

float WinningConditionHelper_equality

we have no winner

Definition at line 112 of file scores.qh.

Referenced by WinningCondition_Scores(), and WinningConditionHelper().

WinningConditionHelper_lowerisbetter

float WinningConditionHelper_lowerisbetter

lower is better, duh

Definition at line 115 of file scores.qh.

Referenced by WinningCondition_Scores(), and WinningConditionHelper().

WinningConditionHelper_second

entity WinningConditionHelper_second

the second player, or NULL if none

Definition at line 114 of file scores.qh.

Referenced by WinningConditionHelper().

WinningConditionHelper_secondscore

float WinningConditionHelper_secondscore

second highest score

Definition at line 109 of file scores.qh.

Referenced by WinningCondition_LMS(), WinningCondition_Scores(), and WinningConditionHelper().

WinningConditionHelper_secondteam

float WinningConditionHelper_secondteam

the color of the second team, or -1 if none

Definition at line 111 of file scores.qh.

Referenced by WinningConditionHelper().

WinningConditionHelper_topscore

float WinningConditionHelper_topscore

highest score

Definition at line 108 of file scores.qh.

Referenced by WinningCondition_LMS(), WinningCondition_Scores(), and WinningConditionHelper().

WinningConditionHelper_winner

entity WinningConditionHelper_winner

the winning player, or NULL if none

Definition at line 113 of file scores.qh.

Referenced by WinningCondition_LMS(), WinningCondition_Scores(), and WinningConditionHelper().

WinningConditionHelper_winnerteam

float WinningConditionHelper_winnerteam

the color of the winning team, or -1 if none

Definition at line 110 of file scores.qh.

Referenced by WinningCondition_Scores(), and WinningConditionHelper().

WinningConditionHelper_zeroisworst

float WinningConditionHelper_zeroisworst

zero is worst, duh

Definition at line 116 of file scores.qh.

Referenced by WinningCondition_Scores(), and WinningConditionHelper().