player.qc File Reference

#include "player.qh"
#include <common/mapobjects/_mod.qh>
#include <common/viewloc.qh>

Include dependency graph for player.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Functions
float	AdjustAirAccelQW (float accelqw, float factor)
void	CheckPlayerJump (entity this)
void	CheckWaterJump (entity this)
void	CPM_PM_Aircontrol (entity this, float dt, vector wishdir, float wishspeed)
float	GeomLerp (float a, float _lerp, float b)
bool	IsFlying (entity this)
float	IsMoveInDirection (vector mv, float ang)
bool	PlayerJump (entity this)
void	PM_Accelerate (entity this, float dt, vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float stretchfactor, float sidefric, float speedlimit)
void	PM_AirAccelerate (entity this, float dt, vector wishdir, float wishspeed)
void	PM_check_blocked (entity this)
void	PM_check_frozen (entity this)
void	PM_check_hitground (entity this)
void	PM_check_nickspam (entity this)
void	PM_check_punch (entity this, float dt)
void	PM_check_slick (entity this)
bool	PM_check_specialcommand (entity this, int buttons)
void	PM_ClientMovement_UpdateStatus (entity this)
void	PM_Footsteps (entity this)
void	PM_jetpack (entity this, float maxspd_mod, float dt)
void	sys_phys_update (entity this, float dt)

Variables
float	jetpack_stopped

Function Documentation

AdjustAirAccelQW()

float AdjustAirAccelQW	(	float	accelqw,
		float	factor
	)

Definition at line 213 of file player.qc.

References bound(), copysign(), and fabs().

Referenced by PM_Accelerate().

{
    return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
}

Here is the call graph for this function:

Here is the caller graph for this function:

CheckPlayerJump()

void CheckPlayerJump

(

entity

this

)

Definition at line 473 of file player.qc.

References autocvar_sv_cheats, boolean, CheatImpulse(), CheckWaterJump(), entity(), ITEMS_STAT, jetpack_stopped, LOG_INFO, M_ARGV, maycheat, PHYS_AMMO_FUEL, PHYS_FROZEN, PHYS_INPUT_BUTTON_JETPACK, PHYS_INPUT_BUTTON_JUMP, PHYS_JETPACK_FUEL, PlayerJump(), UNSET_JUMP_HELD, waterlevel, and WATERLEVEL_SWIMMING.

Referenced by sys_phys_update().

{
#ifdef SVQC
    bool was_flying = boolean(ITEMS_STAT(this) & IT_USING_JETPACK);
#endif
    if (JETPACK_JUMP(this) < 2)
        ITEMS_STAT(this) &= ~IT_USING_JETPACK;

    if(PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_JETPACK(this))
    {
        bool playerjump = PlayerJump(this); // required

        bool air_jump = !playerjump || M_ARGV(2, bool);
        bool activate = (JETPACK_JUMP(this) && air_jump && PHYS_INPUT_BUTTON_JUMP(this)) || PHYS_INPUT_BUTTON_JETPACK(this);
        bool has_fuel = !PHYS_JETPACK_FUEL(this) || PHYS_AMMO_FUEL(this) || (ITEMS_STAT(this) & IT_UNLIMITED_AMMO);

        if (!(ITEMS_STAT(this) & ITEM_Jetpack.m_itemid)) { }
        else if (this.jetpack_stopped) { }
        else if (!has_fuel)
        {
#ifdef SVQC
            if (was_flying) // TODO: ran out of fuel message
                Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_JETPACK_NOFUEL);
            else if (activate)
                Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_JETPACK_NOFUEL);
#endif
            this.jetpack_stopped = true;
            ITEMS_STAT(this) &= ~IT_USING_JETPACK;
        }
        else if (activate && !PHYS_FROZEN(this))
            ITEMS_STAT(this) |= IT_USING_JETPACK;
    }
    else
    {
        this.jetpack_stopped = false;
        ITEMS_STAT(this) &= ~IT_USING_JETPACK;
    }
    if (!PHYS_INPUT_BUTTON_JUMP(this))
        UNSET_JUMP_HELD(this);

    if (this.waterlevel == WATERLEVEL_SWIMMING)
        CheckWaterJump(this);
}

Here is the call graph for this function:

Here is the caller graph for this function:

CheckWaterJump()

void CheckWaterJump

(

entity

this

)

Definition at line 439 of file player.qc.

References FL_WATERJUMP, flags, makevectors, movedir, normalize(), origin, SET_JUMP_HELD, teleport_time, time, trace_fraction, trace_plane_normal, v_angle, v_forward, and vector().

Referenced by CheckPlayerJump().

{
// check for a jump-out-of-water
    makevectors(this.v_angle);
    vector start = this.origin;
    start_z += 8;
    v_forward_z = 0;
    normalize(v_forward);
    vector end = start + v_forward*24;
    traceline (start, end, true, this);
    if (trace_fraction < 1)
    {   // solid at waist
        start_z = start_z + this.maxs_z - 8;
        end = start + v_forward*24;
        this.movedir = trace_plane_normal * -50;
        traceline(start, end, true, this);
        if (trace_fraction == 1)
        {   // open at eye level
            this.velocity_z = 225;
            this.flags |= FL_WATERJUMP;
            this.teleport_time = time + 2; // safety net
            SET_JUMP_HELD(this);
        }
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

CPM_PM_Aircontrol()

void CPM_PM_Aircontrol	(	entity	this,
		float	dt,
		vector	wishdir,
		float	wishspeed
	)

Definition at line 177 of file player.qc.

References bound(), IsMoveInDirection(), max(), movement, normalize(), PHYS_AIRCONTROL, PHYS_AIRCONTROL_BACKWARDS, PHYS_AIRCONTROL_PENALTY, PHYS_AIRCONTROL_POWER, PHYS_AIRCONTROL_SIDEWARDS, PHYS_MAXAIRSPEED, sqrt(), velocity, and vlen().

Referenced by sys_phys_simulate().

{
    float movity = IsMoveInDirection(PHYS_CS(this).movement, 0);
    if(PHYS_AIRCONTROL_BACKWARDS(this))
        movity += IsMoveInDirection(PHYS_CS(this).movement, 180);
    if(PHYS_AIRCONTROL_SIDEWARDS(this))
    {
        movity += IsMoveInDirection(PHYS_CS(this).movement, 90);
        movity += IsMoveInDirection(PHYS_CS(this).movement, -90);
    }

    float k = 32 * (2 * movity - 1);
    if (k <= 0)
        return;

    k *= bound(0, wishspeed / PHYS_MAXAIRSPEED(this), 1);

    float zspeed = this.velocity_z;
    this.velocity_z = 0;
    float xyspeed = vlen(this.velocity);
    this.velocity = normalize(this.velocity);

    float dot = this.velocity * wishdir;

    if (dot > 0) // we can't change direction while slowing down
    {
        k *= (dot ** PHYS_AIRCONTROL_POWER(this)) * dt;
        xyspeed = max(0, xyspeed - PHYS_AIRCONTROL_PENALTY(this) * sqrt(max(0, 1 - dot*dot)) * k/32);
        k *= PHYS_AIRCONTROL(this);
        this.velocity = normalize(this.velocity * xyspeed + wishdir * k);
    }

    this.velocity = this.velocity * xyspeed;
    this.velocity_z = zspeed;
}

Here is the call graph for this function:

Here is the caller graph for this function:

GeomLerp()

float GeomLerp	(	float	a,
		float	_lerp,
		float	b
	)

Definition at line 115 of file player.qc.

References fabs().

Referenced by sys_phys_simulate().

{
    return a == 0 ? (_lerp < 1 ? 0 : b)
        : b == 0 ? (_lerp > 0 ? 0 : a)
        : a * (fabs(b / a) ** _lerp);
}

Here is the call graph for this function:

Here is the caller graph for this function:

IsFlying()

bool IsFlying

(

entity

this

)

Definition at line 804 of file player.qc.

References CS(), CSQC_ClientMovement_PlayerMove_Frame(), csqcmodel_modelflags, entity(), frametime, intermission, IS_DEAD, IS_ONGROUND, IS_REAL_CLIENT, ITEMS_STAT, maxs, MF_ROCKET, mins, MOVE_NORMAL, origin, PM_UpdateButtons(), sys_phys_update(), trace_fraction, waterlevel, and WATERLEVEL_SWIMMING.

Referenced by Damage(), and sys_phys_update().

{
    if(IS_ONGROUND(this))
        return false;
    if(this.waterlevel >= WATERLEVEL_SWIMMING)
        return false;
    tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 24', MOVE_NORMAL, this);
    //traceline(this.origin, this.origin - '0 0 48', MOVE_NORMAL, this);
    if(trace_fraction < 1)
        return false;
    return true;
}

Here is the call graph for this function:

Here is the caller graph for this function:

IsMoveInDirection()

float IsMoveInDirection	(	vector	mv,
		float	ang
	)

Definition at line 106 of file player.qc.

References fabs(), RAD2DEG, and remainder().

Referenced by CPM_PM_Aircontrol(), and sys_phys_simulate().

{
    if (mv_x == 0 && mv_y == 0)
        return 0; // avoid division by zero
    ang -= RAD2DEG * atan2(mv_y, mv_x);
    ang = remainder(ang, 360) / 45;
    return ang > 1 ? 0 : ang < -1 ? 0 : 1 - fabs(ang);
}

Here is the call graph for this function:

Here is the caller graph for this function:

PlayerJump()

bool PlayerJump

(

entity

this

)

Definition at line 330 of file player.qc.

References ANIMACTION_JUMP, animdecide_setaction(), CH_PLAYER, ftos(), IS_DUCKED, IS_JUMP_HELD, IS_ONGROUND, jumppadcount, lastground, LOG_TRACE, M_ARGV, maxs, mins, MOVE_NORMAL, MUTATOR_CALLHOOK, origin, PHYS_FRICTION_ONLAND, PHYS_FROZEN, PHYS_INPUT_BUTTON_CHAT, PHYS_INPUT_BUTTON_MINIGAME, PHYS_JUMPSPEEDCAP_DISABLE_ONRAMPS, PHYS_JUMPVELOCITY, PHYS_JUMPVELOCITY_CROUCH, PHYS_MAXSPEED, PHYS_TRACK_CANJUMP, player_blocked, SET_JUMP_HELD, stof(), time, trace_fraction, UNSET_ONGROUND, UNSET_ONSLICK, velocity, viewloc, vlen(), VOICETYPE_PLAYERSOUND, VOL_BASE, vtos(), WAS_ONGROUND, WAS_ONSLICK, waterlevel, and WATERLEVEL_SWIMMING.

Referenced by CheckPlayerJump().

{
    if (PHYS_FROZEN(this))
        return true; // no jumping in freezetag when frozen

    if(PHYS_INPUT_BUTTON_CHAT(this) || PHYS_INPUT_BUTTON_MINIGAME(this))
        return true; // no jumping while typing

#ifdef SVQC
    if (this.player_blocked)
        return true; // no jumping while blocked
#endif

    bool doublejump = false;
    float mjumpheight = ((PHYS_JUMPVELOCITY_CROUCH(this) && IS_DUCKED(this)) ? PHYS_JUMPVELOCITY_CROUCH(this) : PHYS_JUMPVELOCITY(this));
    bool track_jump = PHYS_CL_TRACK_CANJUMP(this);

    if (MUTATOR_CALLHOOK(PlayerJump, this, mjumpheight, doublejump))
        return true;

    mjumpheight = M_ARGV(1, float);
    doublejump = M_ARGV(2, bool);

    if (this.waterlevel >= WATERLEVEL_SWIMMING)
    {
        if(this.viewloc)
        {
            doublejump = true;
            mjumpheight *= 0.7;
            track_jump = true;
        }
        else
        {
            this.velocity_z = PHYS_MAXSPEED(this) * 0.7;
            return true;
        }
    }

    if (!doublejump)
        if (!IS_ONGROUND(this))
            return IS_JUMP_HELD(this);

    if(PHYS_TRACK_CANJUMP(this))
        track_jump = true;

    if (track_jump)
        if (IS_JUMP_HELD(this))
            return true;

    // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
    // velocity bounds.  Final velocity is bound between (jumpheight *
    // min + jumpheight) and (jumpheight * max + jumpheight);

    if(PHYS_JUMPSPEEDCAP_MIN != "")
    {
        float minjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MIN);

        if (this.velocity_z < minjumpspeed)
            mjumpheight += minjumpspeed - this.velocity_z;
    }

    if(PHYS_JUMPSPEEDCAP_MAX != "")
    {
        // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
        tracebox(this.origin + '0 0 0.01', this.mins, this.maxs, this.origin - '0 0 0.01', MOVE_NORMAL, this);

        if (!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && PHYS_JUMPSPEEDCAP_DISABLE_ONRAMPS(this)))
        {
            float maxjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MAX);

            if (this.velocity_z > maxjumpspeed)
                mjumpheight -= this.velocity_z - maxjumpspeed;
        }
    }

    if (!WAS_ONGROUND(this) && !WAS_ONSLICK(this))
    {
#ifdef SVQC
        if(autocvar_speedmeter)
            LOG_TRACE("landing velocity: ", vtos(this.velocity), " (abs: ", ftos(vlen(this.velocity)), ")");
#endif
        if(this.lastground < time - 0.3)
        {
            float f = (1 - PHYS_FRICTION_ONLAND(this));
            this.velocity_x *= f;
            this.velocity_y *= f;
        }
#ifdef SVQC
        if(this.jumppadcount > 1)
            LOG_TRACE(ftos(this.jumppadcount), "x jumppad combo");
        this.jumppadcount = 0;
#endif
    }

    this.velocity_z += mjumpheight;

    UNSET_ONGROUND(this);
    UNSET_ONSLICK(this);
    SET_JUMP_HELD(this);

#ifdef SVQC
    animdecide_setaction(this, ANIMACTION_JUMP, true);

    if (autocvar_g_jump_grunt)
        PlayerSound(this, playersound_jump, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
#endif
    return true;
}

Here is the call graph for this function:

Here is the caller graph for this function:

PM_Accelerate()

void PM_Accelerate	(	entity	this,
		float	dt,
		vector	wishdir,
		float	wishspeed,
		float	wishspeed0,
		float	accel,
		float	accelqw,
		float	stretchfactor,
		float	sidefric,
		float	speedlimit
	)

Definition at line 223 of file player.qc.

References AdjustAirAccelQW(), bound(), fabs(), max(), sqrt(), vec2, vector(), velocity, and vlen().

Referenced by sys_phys_simulate().

{
    float speedclamp = stretchfactor > 0 ? stretchfactor
    : accelqw < 0 ? 1 // full clamping, no stretch
    : -1; // no clamping

    accelqw = fabs(accelqw);

    if (GAMEPLAYFIX_Q2AIRACCELERATE)
        wishspeed0 = wishspeed; // don't need to emulate this Q1 bug

    float vel_straight = this.velocity * wishdir;
    float vel_z = this.velocity_z;
    vector vel_xy = vec2(this.velocity);
    vector vel_perpend = vel_xy - vel_straight * wishdir;

    float step = accel * dt * wishspeed0;

    float vel_xy_current  = vlen(vel_xy);
    if (speedlimit)
        accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
    float vel_xy_forward =  vel_xy_current  + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
    float vel_xy_backward = vel_xy_current  - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
    vel_xy_backward = max(0, vel_xy_backward); // not that it REALLY occurs that this would cause wrong behaviour afterwards
    vel_straight =          vel_straight    + bound(0, wishspeed - vel_straight,   step) * accelqw + step * (1 - accelqw);

    if (sidefric < 0 && (vel_perpend*vel_perpend))
        // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
    {
        float f = max(0, 1 + dt * wishspeed * sidefric);
        float themin = (vel_xy_backward * vel_xy_backward - vel_straight * vel_straight) / (vel_perpend * vel_perpend);
        // assume: themin > 1
        // vel_xy_backward*vel_xy_backward - vel_straight*vel_straight > vel_perpend*vel_perpend
        // vel_xy_backward*vel_xy_backward > vel_straight*vel_straight + vel_perpend*vel_perpend
        // vel_xy_backward*vel_xy_backward > vel_xy * vel_xy
        // obviously, this cannot be
        if (themin <= 0)
            vel_perpend *= f;
        else
        {
            themin = sqrt(themin);
            vel_perpend *= max(themin, f);
        }
    }
    else
        vel_perpend *= max(0, 1 - dt * wishspeed * sidefric);

    vel_xy = vel_straight * wishdir + vel_perpend;

    if (speedclamp >= 0)
    {
        float vel_xy_preclamp;
        vel_xy_preclamp = vlen(vel_xy);
        if (vel_xy_preclamp > 0) // prevent division by zero
        {
            vel_xy_current += (vel_xy_forward - vel_xy_current) * speedclamp;
            if (vel_xy_current < vel_xy_preclamp)
                vel_xy *= (vel_xy_current / vel_xy_preclamp);
        }
    }

    this.velocity = vel_xy + vel_z * '0 0 1';
}

Here is the call graph for this function:

Here is the caller graph for this function:

PM_AirAccelerate()

void PM_AirAccelerate	(	entity	this,
		float	dt,
		vector	wishdir,
		float	wishspeed
	)

Definition at line 287 of file player.qc.

References max(), min(), normalize(), PHYS_MAXSPEED, PHYS_WARSOWBUNNY_ACCEL, PHYS_WARSOWBUNNY_AIRFORWARDACCEL, PHYS_WARSOWBUNNY_BACKTOSIDERATIO, PHYS_WARSOWBUNNY_TOPSPEED, PHYS_WARSOWBUNNY_TURNACCEL, vector(), velocity, and vlen().

Referenced by sys_phys_simulate().

{
    if (wishspeed == 0)
        return;

    vector curvel = this.velocity;
    curvel_z = 0;
    float curspeed = vlen(curvel);

    if (wishspeed > curspeed * 1.01)
        wishspeed = min(wishspeed, curspeed + PHYS_WARSOWBUNNY_AIRFORWARDACCEL(this) * PHYS_MAXSPEED(this) * dt);
    else
    {
        float f = max(0, (PHYS_WARSOWBUNNY_TOPSPEED(this) - curspeed) / (PHYS_WARSOWBUNNY_TOPSPEED(this) - PHYS_MAXSPEED(this)));
        wishspeed = max(curspeed, PHYS_MAXSPEED(this)) + PHYS_WARSOWBUNNY_ACCEL(this) * f * PHYS_MAXSPEED(this) * dt;
    }
    vector wishvel = wishdir * wishspeed;
    vector acceldir = wishvel - curvel;
    float addspeed = vlen(acceldir);
    acceldir = normalize(acceldir);

    float accelspeed = min(addspeed, PHYS_WARSOWBUNNY_TURNACCEL(this) * PHYS_MAXSPEED(this) * dt);

    if (PHYS_WARSOWBUNNY_BACKTOSIDERATIO(this) < 1)
    {
        vector curdir = normalize(curvel);
        float dot = acceldir * curdir;
        if (dot < 0)
            acceldir -= (1 - PHYS_WARSOWBUNNY_BACKTOSIDERATIO(this)) * dot * curdir;
    }

    this.velocity += accelspeed * acceldir;
}

Here is the call graph for this function:

Here is the caller graph for this function:

PM_check_blocked()

void PM_check_blocked

(

entity

this

)

Definition at line 683 of file player.qc.

References disableclientprediction, PHYS_INPUT_BUTTON_CHAT, PHYS_INPUT_BUTTON_MINIGAME, and player_blocked.

Referenced by sys_phys_update().

{
    if(PHYS_INPUT_BUTTON_CHAT(this) || PHYS_INPUT_BUTTON_MINIGAME(this))
        PHYS_CS(this).movement = '0 0 0';
#ifdef SVQC
    if (!this.player_blocked)
        return;
    PHYS_CS(this).movement = '0 0 0';
    this.disableclientprediction = 1;
#endif
}

Here is the caller graph for this function:

PM_check_frozen()

void PM_check_frozen

(

entity

this

)

Definition at line 609 of file player.qc.

References bound(), IS_CLIENT, movement, PHYS_DODGING_FROZEN, and PHYS_FROZEN.

Referenced by sys_phys_update().

{
    if (!PHYS_FROZEN(this))
        return;
    if (PHYS_DODGING_FROZEN(this) && IS_CLIENT(this))
    {
        // bind movement to a very slow speed so dodging can use .movement for directional calculations
        PHYS_CS(this).movement_x = bound(-2, PHYS_CS(this).movement.x, 2);
        PHYS_CS(this).movement_y = bound(-2, PHYS_CS(this).movement.y, 2);
        PHYS_CS(this).movement_z = bound(-2, PHYS_CS(this).movement.z, 2);
    }
    else
        PHYS_CS(this).movement = '0 0 0';
}

Here is the call graph for this function:

Here is the caller graph for this function:

PM_check_hitground()

void PM_check_hitground

(

entity

this

)

Definition at line 624 of file player.qc.

References CH_PLAYER, entity(), hook, IS_DUCKED, ladder_entity, MAX_WEAPONSLOTS, maxs, mins, MOVE_NOMONSTERS, origin, Q3SURFACEFLAG_METALSTEPS, Q3SURFACEFLAG_NOSTEPS, random(), time, trace_dphitq3surfaceflags, VOICETYPE_PLAYERSOUND, VOL_BASE, VOL_MUFFLED, wasFlying, waterlevel, WATERLEVEL_SWIMMING, and weaponentities.

Referenced by sys_phys_update().

{
#ifdef SVQC
    if (!this.wasFlying) return;
    this.wasFlying = false;
    if (this.waterlevel >= WATERLEVEL_SWIMMING) return;
    if (this.ladder_entity) return;
    for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
    {
        .entity weaponentity = weaponentities[slot];
        if(this.(weaponentity).hook)
            return;
    }
    this.nextstep = time + 0.3 + random() * 0.1;
    trace_dphitq3surfaceflags = 0;
    tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
    if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS) return;
    entity gs = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
        ? GS_FALL_METAL
        : GS_FALL;
    float vol = ((IS_DUCKED(this)) ? VOL_MUFFLED : VOL_BASE);
    GlobalSound(this, gs, CH_PLAYER, vol, VOICETYPE_PLAYERSOUND);
#endif
}

Here is the call graph for this function:

Here is the caller graph for this function:

PM_check_nickspam()

void PM_check_nickspam

(

entity

this

)

Definition at line 563 of file player.qc.

References fixangle, nickspamcount, nickspamtime, PHYS_INPUT_BUTTON_ATCK, PHYS_INPUT_BUTTON_ATCK2, PHYS_INPUT_BUTTON_CROUCH, PHYS_INPUT_BUTTON_HOOK, PHYS_INPUT_BUTTON_JUMP, PHYS_INPUT_BUTTON_USE, PHYS_INPUT_BUTTON_ZOOM, random(), and time.

Referenced by sys_phys_monitor().

{
#ifdef SVQC
    if (time >= this.nickspamtime)
        return;
    if (this.nickspamcount >= autocvar_g_nick_flood_penalty_yellow)
    {
        // slight annoyance for nick change scripts
        PHYS_CS(this).movement = -1 * PHYS_CS(this).movement;
        PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_ZOOM(this) = PHYS_INPUT_BUTTON_CROUCH(this) = PHYS_INPUT_BUTTON_HOOK(this) = PHYS_INPUT_BUTTON_USE(this) = false;

        if (this.nickspamcount >= autocvar_g_nick_flood_penalty_red) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
        {
            this.v_angle_x = random() * 360;
            this.v_angle_y = random() * 360;
            // at least I'm not forcing retardedview by also assigning to angles_z
            this.fixangle = true;
        }
    }
#endif
}

Here is the call graph for this function:

Here is the caller graph for this function:

PM_check_punch()

void PM_check_punch	(	entity	this,
		float	dt
	)

Definition at line 585 of file player.qc.

References normalize(), punchangle, punchvector, and vlen().

Referenced by sys_phys_monitor().

{
#ifdef SVQC
    if (this.punchangle != '0 0 0')
    {
        float f = vlen(this.punchangle) - 10 * dt;
        if (f > 0)
            this.punchangle = normalize(this.punchangle) * f;
        else
            this.punchangle = '0 0 0';
    }

    if (this.punchvector != '0 0 0')
    {
        float f = vlen(this.punchvector) - 30 * dt;
        if (f > 0)
            this.punchvector = normalize(this.punchvector) * f;
        else
            this.punchvector = '0 0 0';
    }
#endif
}

Here is the call graph for this function:

Here is the caller graph for this function:

PM_check_slick()

void PM_check_slick

(

entity

this

)

Definition at line 670 of file player.qc.

References IS_ONGROUND, maxs, mins, MOVE_NOMONSTERS, origin, Q3SURFACEFLAG_SLICK, SET_ONSLICK, trace_dphitq3surfaceflags, and UNSET_ONSLICK.

Referenced by sys_phys_update().

{
    if(!IS_ONGROUND(this))
        return;

    trace_dphitq3surfaceflags = 0;
    tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
    if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK)
        SET_ONSLICK(this);
    else
        UNSET_ONSLICK(this);
}

Here is the caller graph for this function:

PM_check_specialcommand()

bool PM_check_specialcommand	(	entity	this,
		int	buttons
	)

Definition at line 530 of file player.qc.

References BIT, CS(), strlen(), and substring().

Referenced by sys_phys_override().

{
#ifdef SVQC
    string c;
    switch (buttons)
    {
        // buttons mapped in PHYS_INPUT_BUTTON_MASK
        case 0: c = "x"; break;
        case BIT(0): c = "1"; break;
        case BIT(2): c = " "; break;
        case BIT(7): c = "s"; break;
        case BIT(8): c = "w"; break;
        case BIT(9): c = "a"; break;
        case BIT(10): c = "d"; break;
        default: c = "?";
    }

    if (c == substring(specialcommand, CS(this).specialcommand_pos, 1))
    {
        CS(this).specialcommand_pos += 1;
        if (CS(this).specialcommand_pos >= strlen(specialcommand))
        {
            CS(this).specialcommand_pos = 0;
            SpecialCommand(this);
            return true;
        }
    }
    else if (CS(this).specialcommand_pos && (c != substring(specialcommand, CS(this).specialcommand_pos - 1, 1)))
        CS(this).specialcommand_pos = 0;
#endif
    return false;
}

Here is the call graph for this function:

Here is the caller graph for this function:

PM_ClientMovement_UpdateStatus()

void PM_ClientMovement_UpdateStatus

(

entity

this

)

Definition at line 122 of file player.qc.

References _Movetype_CheckWater(), entity(), IS_DEAD, IS_DUCKED, IS_PLAYER, M_ARGV, MAX_WEAPONSLOTS, movement, MUTATOR_CALLHOOK, origin, PHYS_INPUT_BUTTON_CROUCH, SET_DUCKED, trace_startsolid, UNSET_DUCKED, view_ofs, viewloc, VIEWLOC_FREEMOVE, viewmodels, and weaponentities.

Referenced by sys_phys_fix().

{
    if(!IS_PLAYER(this))
        return;

    bool have_hook = false;
    for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
    {
    #if defined(CSQC)
        entity wepent = viewmodels[slot];
    #elif defined(SVQC)
        .entity weaponentity = weaponentities[slot];
        entity wepent = this.(weaponentity);
    #endif
        if(wepent.hook && !wasfreed(wepent.hook))
        {
            have_hook = true;
            break;
        }
    }
    bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
    if(this.viewloc && !(this.viewloc.spawnflags & VIEWLOC_FREEMOVE) && PHYS_CS(this).movement.x < 0)
        do_crouch = true;
    if (have_hook) {
        do_crouch = false;
    //} else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
        //do_crouch = false;
    } else if (PHYS_INVEHICLE(this)) {
        do_crouch = false;
    } else if (STAT(FROZEN, this) || IS_DEAD(this)) {
        do_crouch = false;
    }

    MUTATOR_CALLHOOK(PlayerCanCrouch, this, do_crouch);
    do_crouch = M_ARGV(1, bool);

    if (do_crouch) {
        if (!IS_DUCKED(this)) {
            SET_DUCKED(this);
            this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
            setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
            // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
        }
    } else if (IS_DUCKED(this)) {
        tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
        if (!trace_startsolid) {
            UNSET_DUCKED(this);
            this.view_ofs = STAT(PL_VIEW_OFS, this);
            setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
        }
    }

    _Movetype_CheckWater(this); // needs to be run on the client, might as well use the latest on the server too!
}

Here is the call graph for this function:

Here is the caller graph for this function:

PM_Footsteps()

void PM_Footsteps

(

entity

this

)

Definition at line 649 of file player.qc.

References CH_PLAYER, entity(), IS_DUCKED, lastground, maxs, mins, MOVE_NOMONSTERS, origin, Q3SURFACEFLAG_METALSTEPS, Q3SURFACEFLAG_NOSTEPS, random(), time, trace_dphitq3surfaceflags, vdist, velocity, VOICETYPE_PLAYERSOUND, and VOL_BASE.

Referenced by sys_phys_update().

{
#ifdef SVQC
    if (!autocvar_g_footsteps) return;
    if (IS_DUCKED(this)) return;
    if (time >= this.lastground + 0.2) return;
    if (vdist(this.velocity, <=, autocvar_sv_maxspeed * 0.6)) return;
    if ((time > this.nextstep) || (time < (this.nextstep - 10.0)))
    {
        this.nextstep = time + 0.3 + random() * 0.1;
        trace_dphitq3surfaceflags = 0;
        tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
        if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS) return;
        entity gs = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
            ? GS_STEP_METAL
            : GS_STEP;
        GlobalSound(this, gs, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
    }
#endif
}

Here is the call graph for this function:

Here is the caller graph for this function:

PM_jetpack()

void PM_jetpack	(	entity	this,
		float	maxspd_mod,
		float	dt
	)

Definition at line 695 of file player.qc.

References autocvar_g_balance_pause_fuel_regen, best, bound(), ITEMS_STAT, makevectors, max(), min(), normalize(), pauseregen_finished, PHYS_AMMO_FUEL, PHYS_INPUT_BUTTON_CROUCH, PHYS_JETPACK_ACCEL_SIDE, PHYS_JETPACK_ACCEL_UP, PHYS_JETPACK_ANTIGRAVITY, PHYS_JETPACK_FUEL, PHYS_JETPACK_MAXSPEED_SIDE, PHYS_JETPACK_MAXSPEED_UP, PHYS_JETPACK_REVERSE_THRUST, PHYS_MAXAIRSPEED, sqrt(), TakeResource(), time, UNSET_ONGROUND, v_angle, v_forward, v_right, vector(), velocity, and vlen().

Referenced by sys_phys_update().

{
    //makevectors(this.v_angle.y * '0 1 0');
    makevectors(this.v_angle);
    vector wishvel = v_forward * PHYS_CS(this).movement_x
                    + v_right * PHYS_CS(this).movement_y;
    // add remaining speed as Z component
    float maxairspd = PHYS_MAXAIRSPEED(this) * max(1, maxspd_mod);
    // fix speedhacks :P
    wishvel = normalize(wishvel) * min(1, vlen(wishvel) / maxairspd);
    // add the unused velocity as up component
    wishvel_z = 0;

    // if (PHYS_INPUT_BUTTON_JUMP(this))
        wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));

    // it is now normalized, so...
    float a_side = PHYS_JETPACK_ACCEL_SIDE(this);
    float a_up = PHYS_JETPACK_ACCEL_UP(this);
    float a_add = PHYS_JETPACK_ANTIGRAVITY(this) * PHYS_GRAVITY(this);

    if(PHYS_JETPACK_REVERSE_THRUST(this) && PHYS_INPUT_BUTTON_CROUCH(this)) { a_up = PHYS_JETPACK_REVERSE_THRUST(this); }

    wishvel_x *= a_side;
    wishvel_y *= a_side;
    wishvel_z *= a_up;
    wishvel_z += a_add;

    if(PHYS_JETPACK_REVERSE_THRUST(this) && PHYS_INPUT_BUTTON_CROUCH(this)) { wishvel_z *= -1; }

    float best = 0;
    // finding the maximum over all vectors of above form
    // with wishvel having an absolute value of 1
    // we're finding the maximum over
    //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
    // for z in the range from -1 to 1
    // maximum is EITHER attained at the single extreme point:
    float a_diff = a_side * a_side - a_up * a_up;
    float f;
    if (a_diff != 0)
    {
        f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
        if (f > -1 && f < 1) // can it be attained?
        {
            best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
            //print("middle\n");
        }
    }
    // OR attained at z = 1:
    f = (a_up + a_add) * (a_up + a_add);
    if (f > best)
    {
        best = f;
        //print("top\n");
    }
    // OR attained at z = -1:
    f = (a_up - a_add) * (a_up - a_add);
    if (f > best)
    {
        best = f;
        //print("bottom\n");
    }
    best = sqrt(best);

    //print("best possible acceleration: ", ftos(best), "\n");

    float fxy, fz;
    fxy = bound(0, 1 - (this.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / PHYS_JETPACK_MAXSPEED_SIDE(this), 1);
    if (wishvel_z - PHYS_GRAVITY(this) > 0)
        fz = bound(0, 1 - this.velocity_z / PHYS_JETPACK_MAXSPEED_UP(this), 1);
    else
        fz = bound(0, 1 + this.velocity_z / PHYS_JETPACK_MAXSPEED_UP(this), 1);

    float fvel;
    fvel = vlen(wishvel);
    wishvel_x *= fxy;
    wishvel_y *= fxy;
    wishvel_z = (wishvel_z - PHYS_GRAVITY(this)) * fz + PHYS_GRAVITY(this);

    fvel = min(1, vlen(wishvel) / best);
    if (PHYS_JETPACK_FUEL(this) && !(ITEMS_STAT(this) & IT_UNLIMITED_AMMO))
        f = min(1, PHYS_AMMO_FUEL(this) / (PHYS_JETPACK_FUEL(this) * dt * fvel));
    else
        f = 1;

    //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");

    if (f > 0 && wishvel != '0 0 0')
    {
        this.velocity = this.velocity + wishvel * f * dt;
        UNSET_ONGROUND(this);

#ifdef SVQC
        if (!(ITEMS_STAT(this) & IT_UNLIMITED_AMMO))
            TakeResource(this, RES_FUEL, PHYS_JETPACK_FUEL(this) * dt * fvel * f);

        ITEMS_STAT(this) |= IT_USING_JETPACK;

        // jetpack also inhibits health regeneration, but only for 1 second
        this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
#endif
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

sys_phys_update()

void sys_phys_update	(	entity	this,
		float	dt
	)

Definition at line 11 of file physics.qc.

Referenced by IsFlying().

{
    if (!IS_CLIENT(this)) {
        sys_phys_simulate_simple(this, dt);
        return;
    }
    sys_in_update(this, dt);

    sys_phys_fix(this, dt);
    if (sys_phys_override(this, dt))
        return;

    sys_phys_monitor(this, dt);

    PHYS_CS(this).movement_old = PHYS_CS(this).movement;
    PHYS_CS(this).v_angle_old = this.v_angle;
    PHYS_CS(this).buttons_old = PHYS_INPUT_BUTTON_MASK(this);

    sys_phys_ai(this);

    sys_phys_pregame_hold(this);

    if (IS_SVQC) {
        if (this.move_movetype == MOVETYPE_NONE) { return; }
        // when we get here, disableclientprediction cannot be 2
        if(this.move_movetype == MOVETYPE_FOLLOW) // not compatible with prediction
            this.disableclientprediction = 1;
        else if(this.move_qcphysics)
            this.disableclientprediction = -1;
        else
            this.disableclientprediction = 0;
    }

    viewloc_PlayerPhysics(this);

    PM_check_frozen(this);

    PM_check_blocked(this);

    float maxspeed_mod = 1;

// conveyors: first fix velocity
    if (this.conveyor.active) { this.velocity -= this.conveyor.movedir; }
    MUTATOR_CALLHOOK(PlayerPhysics, this, dt);

    if (!IS_PLAYER(this)) {
        sys_phys_spectator_control(this);
        maxspeed_mod = STAT(SPECTATORSPEED, this);
    }
    sys_phys_fixspeed(this, maxspeed_mod);

    if (IS_DEAD(this)) {
        // handle water here
        vector midpoint = ((this.absmin + this.absmax) * 0.5);
        int cont = pointcontents(midpoint);
        if (cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME) {
            this.velocity = this.velocity * 0.5;

            // do we want this?
            // if(pointcontents(midpoint + '0 0 2') == CONTENT_WATER)
            // { this.velocity_z = 70; }
        }
        sys_phys_postupdate(this);
        return;
    }

    PM_check_slick(this);

    if (IS_SVQC && !PHYS_FIXANGLE(this)) { this.angles = '0 1 0' * this.v_angle.y; }
    if (IS_PLAYER(this)) {
        if (IS_ONGROUND(this)) {
            PM_check_hitground(this);
            PM_Footsteps(this);
        } else if (IsFlying(this)) {
            this.wasFlying = true;
        }
        CheckPlayerJump(this);
    }

    if (this.flags & FL_WATERJUMP) {
        this.velocity_x = this.movedir.x;
        this.velocity_y = this.movedir.y;
        if (time > this.teleport_time || this.waterlevel == WATERLEVEL_NONE) {
            this.flags &= ~FL_WATERJUMP;
            this.teleport_time = 0;
        }
    } else if (MUTATOR_CALLHOOK(PM_Physics, this, maxspeed_mod, dt)) {
        // handled
    } else if (this.move_movetype == MOVETYPE_NOCLIP
        || this.move_movetype == MOVETYPE_FLY
        || this.move_movetype == MOVETYPE_FLY_WORLDONLY
        || MUTATOR_CALLHOOK(IsFlying, this)) {
        this.com_phys_friction = PHYS_FRICTION(this);
        this.com_phys_vel_max = PHYS_MAXSPEED(this) * maxspeed_mod;
        this.com_phys_acc_rate = PHYS_ACCELERATE(this) * maxspeed_mod;
        this.com_phys_friction_air = true;
        sys_phys_simulate(this, dt);
        this.com_phys_friction_air = false;
    } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
        this.com_phys_vel_max = PHYS_MAXSPEED(this) * maxspeed_mod;
        this.com_phys_acc_rate = PHYS_ACCELERATE(this) * maxspeed_mod;
        this.com_phys_water = true;
        sys_phys_simulate(this, dt);
        this.com_phys_water = false;
        this.jumppadcount = 0;
    } else if (this.ladder_entity) {
        this.com_phys_friction = PHYS_FRICTION(this);
        this.com_phys_vel_max = PHYS_MAXSPEED(this) * maxspeed_mod;
        this.com_phys_acc_rate = PHYS_ACCELERATE(this) * maxspeed_mod;
        this.com_phys_gravity = -PHYS_GRAVITY(this) * dt;
        if (PHYS_ENTGRAVITY(this)) { this.com_phys_gravity *= PHYS_ENTGRAVITY(this); }
        this.com_phys_ladder = true;
        this.com_phys_friction_air = true;
        sys_phys_simulate(this, dt);
        this.com_phys_friction_air = false;
        this.com_phys_ladder = false;
        this.com_phys_gravity = 0;
    } else if (ITEMS_STAT(this) & IT_USING_JETPACK) {
        PM_jetpack(this, maxspeed_mod, dt);
    } else if (IS_ONGROUND(this) && (!IS_ONSLICK(this) || !PHYS_SLICK_APPLYGRAVITY(this))) {
        if (!WAS_ONGROUND(this)) {
            emit(phys_land, this);
            if (this.lastground < time - 0.3) {
                this.velocity *= (1 - PHYS_FRICTION_ONLAND(this));
            }
        }
        this.com_phys_vel_max = PHYS_MAXSPEED(this) * maxspeed_mod;
        this.com_phys_gravity = -PHYS_GRAVITY(this) * dt;
        if (PHYS_ENTGRAVITY(this)) { this.com_phys_gravity *= PHYS_ENTGRAVITY(this); }
        this.com_phys_ground = true;
        this.com_phys_vel_2d = true;
        sys_phys_simulate(this, dt);
        this.com_phys_vel_2d = false;
        this.com_phys_ground = false;
        this.com_phys_gravity = 0;
    } else {
        this.com_phys_acc_rate_air = PHYS_AIRACCELERATE(this) * min(maxspeed_mod, 1);
        this.com_phys_acc_rate_air_stop = PHYS_AIRSTOPACCELERATE(this) * maxspeed_mod;
        this.com_phys_acc_rate_air_strafe = PHYS_AIRSTRAFEACCELERATE(this) * maxspeed_mod;
        this.com_phys_vel_max_air_strafe = PHYS_MAXAIRSTRAFESPEED(this) * maxspeed_mod;
        this.com_phys_vel_max_air = PHYS_MAXAIRSPEED(this) * maxspeed_mod;
        this.com_phys_vel_max = PHYS_MAXAIRSPEED(this) * min(maxspeed_mod, 1);
        this.com_phys_air = true;
        this.com_phys_vel_2d = true;
        sys_phys_simulate(this, dt);
        this.com_phys_vel_2d = false;
        this.com_phys_air = false;
    }

    sys_phys_postupdate(this);
}

Here is the caller graph for this function:

Variable Documentation

jetpack_stopped

float jetpack_stopped

Definition at line 472 of file player.qc.

Referenced by CheckPlayerJump().