main.qc File Reference

#include "main.qh"
#include <common/command/generic.qh>
#include <common/constants.qh>
#include <common/deathtypes/all.qh>
#include <common/debug.qh>
#include <common/mapinfo.qh>
#include <common/monsters/sv_monsters.qh>
#include <common/util.qh>
#include <common/vehicles/all.qh>
#include <common/weapons/_all.qh>
#include <lib/csqcmodel/sv_model.qh>
#include <lib/warpzone/common.qh>
#include <lib/warpzone/server.qh>
#include <server/anticheat.qh>
#include <server/bot/api.qh>
#include <server/command/common.qh>
#include <server/compat/quake3.qh>
#include <server/damage.qh>
#include <server/gamelog.qh>
#include <server/hook.qh>
#include <server/ipban.qh>
#include <server/mutators/_mod.qh>
#include <server/spawnpoints.qh>
#include <server/weapons/common.qh>
#include <server/weapons/csqcprojectile.qh>
#include <server/world.qh>

Include dependency graph for main.qc:

This graph shows which files directly or indirectly include this file:

Go to the source code of this file.

Macros
#define	X(out, in)

Functions
void	CreatureFrame_All ()
void	CreatureFrame_FallDamage (entity this)
void	CreatureFrame_hotliquids (entity this)
void	CreatureFrame_Liquids (entity this)
void	dedicated_print (string input)
	print(), but only print if the server is not local More...
void	dropclient_do (entity this)
bool	dropclient_schedule (entity this)
	Schedules dropclient for a player and returns true; if dropclient is already scheduled (for that player) it does nothing and returns false. More...
string	GetField_fullspawndata (entity e, string f,...)
void	main ()
void	make_safe_for_remove (entity e)
void	Pause_TryPause (bool ispaused)
void	remove_except_protected (entity e)
void	remove_safely (entity e)
void	remove_unsafely (entity e)
void	StartFrame ()
void	SV_OnEntityPreSpawnFunction (entity this)
void	SV_PausedTic (float elapsedtime)
void	sys_phys_update (entity this, float dt)
void	systems_update ()
void	URI_Get_Callback (float id, float status, string data)
	engine callback More...
void	WarpZone_PostInitialize_Callback ()

Variables
float	anglejitter
vector	anglesjitter
bool	autocvar_sv_autopause = false
string	cvarfilter
bool	game_delay_last
string	gametypefilter
vector	originjitter

Macro Definition Documentation

X

#define X	(		out,
			in
	)

Value:

MACRO_BEGIN \
        if (in != 0) { out = out + (random() * 2 - 1) * in; } \
    MACRO_END

Referenced by SV_OnEntityPreSpawnFunction().

Function Documentation

CreatureFrame_All()

void CreatureFrame_All

(

)

Definition at line 175 of file main.qc.

References g_damagedbycontents, IL_EACH, and time.

Referenced by StartFrame().

{
    if(game_stopped || time < game_starttime)
        return;

    IL_EACH(g_damagedbycontents, it.damagedbycontents,
    {
        if (it.move_movetype == MOVETYPE_NOCLIP) continue;
        CreatureFrame_Liquids(it);
        CreatureFrame_FallDamage(it);
        it.oldvelocity = it.velocity;
    });
}

Here is the caller graph for this function:

CreatureFrame_FallDamage()

void CreatureFrame_FallDamage

(

entity

this

)

Definition at line 134 of file main.qc.

References autocvar_g_balance_falldamage_deadminspeed, autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage, autocvar_g_balance_falldamage_minspeed, autocvar_g_balance_falldamage_onlyvertical, Damage(), DMG_NOWEP, fabs(), flags, hook, IS_DEAD, IS_VEHICLE, MAX_WEAPONSLOTS, maxs, min(), mins, MOVE_NOMONSTERS, NULL, oldvelocity, origin, Q3SURFACEFLAG_NODAMAGE, trace_dphitq3surfaceflags, vdist, velocity, vlen(), and weaponentities.

{
    if(IS_VEHICLE(this) || (this.flags & FL_PROJECTILE))
        return; // vehicles and projectiles don't receive fall damage
    if(!(this.velocity || this.oldvelocity))
        return; // if the entity hasn't moved and isn't moving, then don't do anything

    // check for falling damage
    bool have_hook = false;
    for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
    {
        .entity weaponentity = weaponentities[slot];
        if(this.(weaponentity).hook && this.(weaponentity).hook.state)
        {
            have_hook = true;
            break;
        }
    }
    if(!have_hook)
    {
        float dm; // dm is the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
        if(autocvar_g_balance_falldamage_onlyvertical)
            dm = fabs(this.oldvelocity.z) - vlen(this.velocity);
        else
            dm = vlen(this.oldvelocity) - vlen(this.velocity);
        if (IS_DEAD(this))
            dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
        else
            dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
        if (dm > 0)
        {
            tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
            if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODAMAGE))
                Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, DMG_NOWEP, this.origin, '0 0 0');
        }
    }

    if(autocvar_g_maxspeed > 0 && vdist(this.velocity, >, autocvar_g_maxspeed))
        Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, DMG_NOWEP, this.origin, '0 0 0');
}

Here is the call graph for this function:

CreatureFrame_hotliquids()

void CreatureFrame_hotliquids

(

entity

this

)

Definition at line 63 of file main.qc.

References ATTEN_NORM, autocvar_g_balance_contents_damagerate, autocvar_g_balance_contents_playerdamage_lava, autocvar_g_balance_contents_playerdamage_lava_burn, autocvar_g_balance_contents_playerdamage_lava_burn_time, autocvar_g_balance_contents_playerdamage_slime, autocvar_g_balance_contents_projectiledamage, CH_PLAYER_SINGLE, CONTENT_LAVA, CONTENT_SLIME, contents_damagetime, Damage(), DMG_NOWEP, Fire_AddDamage(), flags, NULL, sound, time, VOL_BASE, waterlevel, watersound_finished, and watertype.

Referenced by CreatureFrame_Liquids().

{
    if (this.contents_damagetime >= time)
    {
        return;
    }

    this.contents_damagetime = time + autocvar_g_balance_contents_damagerate;

    if (this.flags & FL_PROJECTILE)
    {
        if (this.watertype == CONTENT_LAVA)
            Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
        else if (this.watertype == CONTENT_SLIME)
            Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
    }
    else
    {
        if (STAT(FROZEN, this))
        {
            if (this.watertype == CONTENT_LAVA)
                Damage(this, NULL, NULL, 10000, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
            else if (this.watertype == CONTENT_SLIME)
                Damage(this, NULL, NULL, 10000, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
        }
        else if (this.watertype == CONTENT_LAVA)
        {
            if (this.watersound_finished < time)
            {
                this.watersound_finished = time + 0.5;
                sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
            }
            Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
            if(autocvar_g_balance_contents_playerdamage_lava_burn)
                Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
        }
        else if (this.watertype == CONTENT_SLIME)
        {
            if (this.watersound_finished < time)
            {
                this.watersound_finished = time + 0.5;
                sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
            }
            Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
        }
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

CreatureFrame_Liquids()

void CreatureFrame_Liquids

(

entity

this

)

Definition at line 111 of file main.qc.

References contents_damagetime, CreatureFrame_hotliquids(), FL_INWATER, and flags.

{
    if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
    {
        if (!(this.flags & FL_INWATER))
        {
            this.flags |= FL_INWATER;
            this.contents_damagetime = 0;
        }

        CreatureFrame_hotliquids(this);
    }
    else
    {
        if (this.flags & FL_INWATER)
        {
            // play leave water sound
            this.flags &= ~FL_INWATER;
            this.contents_damagetime = 0;
        }
    }
}

Here is the call graph for this function:

dedicated_print()

void dedicated_print

(

string

input

)

print(), but only print if the server is not local

Definition at line 205 of file main.qc.

References print(), and server_is_dedicated.

Referenced by GameLogEcho(), and Say().

{
    if (server_is_dedicated) print(input);
}

Here is the call graph for this function:

Here is the caller graph for this function:

dropclient_do()

void dropclient_do

(

entity

this

)

Definition at line 29 of file main.qc.

References owner.

Referenced by dropclient_schedule().

{
    if (this.owner)
        dropclient(this.owner);
    delete(this);
}

Here is the caller graph for this function:

dropclient_schedule()

bool dropclient_schedule

(

entity

this

)

Schedules dropclient for a player and returns true; if dropclient is already scheduled (for that player) it does nothing and returns false.

NOTE: this function exists only to allow sending a message to the kicked player with Send_Notification, which doesn't work if called together with dropclient

Definition at line 42 of file main.qc.

References dropclient_do(), entity(), FOREACH_ENTITY_CLASS, new_pure, setthink, and time.

Referenced by MUTATOR_HOOKFUNCTION(), PlayerPostThink(), and PlayerPreThink().

{
    bool scheduled = false;
    FOREACH_ENTITY_CLASS("dropclient_handler", true,
    {
        if(it.owner == this)
        {
            scheduled = true;
            break; // can't use return here, compiler shows a warning
        }
    });
    if (scheduled)
        return false;

    entity e = new_pure(dropclient_handler);
    setthink(e, dropclient_do);
    e.owner = this;
    e.nextthink = time + 0.1;
    return true;
}

Here is the call graph for this function:

Here is the caller graph for this function:

GetField_fullspawndata()

string GetField_fullspawndata	(	entity	e,
		string	f,
			...
	)

Definition at line 400 of file main.qc.

References argv(), ftos(), LOG_WARNF, string_null, strstrofs, tokenize_console, and v.

Referenced by door_reset().

{
    string v = string_null;

    if (!e.fullspawndata)
    {
        //LOG_WARNF("^1EDICT %s (classname %s) has no fullspawndata, engine lacks support?", ftos(num_for_edict(e)), e.classname);
        return v;
    }

    if (strstrofs(e.fullspawndata, "//", 0) >= 0)
    {
        // tokenize and tokenize_console return early if "//" is reached,
        // which can leave an odd number of tokens and break key:value pairing.
        LOG_WARNF("^1EDICT %s fullspawndata contains unsupported //comment^7%s", ftos(num_for_edict(e)), e.fullspawndata);
        return v;
    }

    //print(sprintf("%s(EDICT %s, FIELD %s)\n", __FUNC__, ftos(num_for_edict(e)), f));
    //print(strcat("FULLSPAWNDATA:", e.fullspawndata, "\n"));

    // tokenize treats \ as an escape, but tokenize_console returns the required literal
    for (int t = tokenize_console(e.fullspawndata) - 3; t > 0; t -= 2)
    {
        //print(sprintf("\tTOKEN %s:%s\t%s:%s\n", ftos(t), ftos(t + 1), argv(t), argv(t + 1)));
        if (argv(t) == f)
        {
            v = argv(t + 1);
            break;
        }
    }

    //print(strcat("RESULT: ", v, "\n\n"));

    if (v && ...(0, bool) == true)
    {
        v = strreplace("\\", "/", v);
        if (whichpack(v) == "")
            return string_null;
    }

    return v;
}

Here is the call graph for this function:

Here is the caller graph for this function:

main()

void main

(

)

Definition at line 506 of file main.qc.

{

}

make_safe_for_remove()

void make_safe_for_remove

(

entity

e

)

Definition at line 210 of file main.qc.

References entity(), initialize_entity_first, NULL, and prev.

Referenced by remove_safely().

{
    if (e.initialize_entity)
    {
        entity ent, prev = NULL;
        for (ent = initialize_entity_first; ent; )
        {
            if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
            {
                //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
                // skip it in linked list
                if (prev)
                {
                    prev.initialize_entity_next = ent.initialize_entity_next;
                    ent = prev.initialize_entity_next;
                }
                else
                {
                    initialize_entity_first = ent.initialize_entity_next;
                    ent = initialize_entity_first;
                }
            }
            else
            {
                prev = ent;
                ent = ent.initialize_entity_next;
            }
        }
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

Pause_TryPause()

void Pause_TryPause

(

bool

ispaused

)

Definition at line 189 of file main.qc.

References FOREACH_CLIENT, IS_PLAYER, IS_REAL_CLIENT, and PHYS_INPUT_BUTTON_CHAT.

Referenced by StartFrame(), and SV_PausedTic().

{
    int n = 0;
    FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
        if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
        ++n;
    });
    if (!n) return;
    setpause(ispaused);
}

Here is the caller graph for this function:

remove_except_protected()

void remove_except_protected

(

entity

e

)

Definition at line 241 of file main.qc.

References error().

Referenced by InitializeEntitiesRun().

{
    if(e.remove_except_protected_forbidden)
        error("not allowed to remove this at this point");
    builtin_remove(e);
}

Here is the call graph for this function:

Here is the caller graph for this function:

remove_safely()

void remove_safely

(

entity

e

)

Definition at line 255 of file main.qc.

References make_safe_for_remove().

Referenced by spawnfunc().

{
    make_safe_for_remove(e);
    builtin_remove(e);
}

Here is the call graph for this function:

Here is the caller graph for this function:

remove_unsafely()

void remove_unsafely

(

entity

e

)

Definition at line 248 of file main.qc.

References error().

Referenced by InitializeEntitiesRun(), spawnfunc(), and StartFrame().

{
    if(e.classname == "spike")
        error("Removing spikes is forbidden (crylink bug), please report");
    builtin_remove(e);
}

Here is the call graph for this function:

Here is the caller graph for this function:

StartFrame()

void StartFrame

(

)

Definition at line 274 of file main.qc.

References anticheat_startframe(), autocvar_slowmo, autocvar_sv_autopause, autocvar_sv_eventlog, autocvar_sys_ticrate, bot_serverframe(), CheckRules_World(), CreatureFrame_All(), CSQCProjectile_Check(), delete_fn(), execute_next_frame(), FOREACH_CLIENT, frametime, ftos(), g_players, g_projectiles, game_delay_last, GameLogEcho(), IL_EACH, InitializeEntitiesRun(), IS_FAKE_CLIENT, IS_PLAYER, IS_REAL_CLIENT, LOG_INFO, MUTATOR_CALLHOOK, orig_slowmo, Pause_TryPause(), PlayerPostThink(), PlayerPreThink(), ReadyRestart(), RedirectionThink(), remove_unsafely(), server_is_dedicated, serverframetime, serverprevtime, servertime, solve_quadratic(), sys_frametime, sys_phys_update(), time, TIMEOUT_LEADTIME, and warmup_stage.

{
    // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
    IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
    IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));

    execute_next_frame();
    if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);

    delete_fn = remove_unsafely; // not during spawning!
    serverprevtime = servertime;
    servertime = time;
    serverframetime = frametime;

#ifdef PROFILING
    if(time > client_cefc_accumulatortime + 1)
    {
        float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
        int c_seeing = 0;
        int c_seen = 0;
        FOREACH_CLIENT(true, {
            if(IS_REAL_CLIENT(it))
                ++c_seeing;
            if(IS_PLAYER(it))
                ++c_seen;
        });
        LOG_INFO(
            "CEFC time: ", ftos(t * 1000), "ms; ",
            "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
            "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
        );
        client_cefc_accumulatortime = time;
        client_cefc_accumulator = 0;
    }
#endif

    IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));

    if (RedirectionThink()) return;

    UncustomizeEntitiesRun();
    InitializeEntitiesRun();

    WarpZone_StartFrame();

    sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
    if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback

    if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
        orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout

    // detect when the pre-game countdown (if any) has ended and the game has started
    bool game_delay = (time < game_starttime);
    if (autocvar_sv_eventlog && game_delay_last && !game_delay)
        GameLogEcho(":startdelay_ended");
    game_delay_last = game_delay;

    CreatureFrame_All();
    CheckRules_World();

    if (warmup_stage && !game_stopped && warmup_limit > 0 && time - game_starttime >= warmup_limit) {
        ReadyRestart(true);
        return;
    }

    bot_serverframe();
    anticheat_startframe();
    MUTATOR_CALLHOOK(SV_StartFrame);

    GlobalStats_updateglobal();
    FOREACH_CLIENT(true, GlobalStats_update(it));
    IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
}

Here is the call graph for this function:

SV_OnEntityPreSpawnFunction()

void SV_OnEntityPreSpawnFunction

(

entity

this

)

Definition at line 354 of file main.qc.

References angles, cvarfilter, DoesQ3ARemoveThisEntity(), expr_evaluate(), g_monster_targets, gametypefilter, have_team_spawns, IL_PUSH(), isGametypeInFilter(), MapInfo_LoadedGametype, monster_attack, movetype, MUTATOR_CALLHOOK, origin, q3compat, set_movetype(), teamplay, and X.

{
    if (this)
    if (this.gametypefilter != "")
    if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
    {
        delete(this);
        return;
    }
    if (this.cvarfilter != "" && !expr_evaluate(this.cvarfilter)) {
        delete(this);
        return;
    }

    if (q3compat && DoesQ3ARemoveThisEntity(this)) {
        delete(this);
        return;
    }

    set_movetype(this, this.movetype);

    if (this.monster_attack) {
        IL_PUSH(g_monster_targets, this);
    }

    // support special -1 and -2 angle from radiant
    if (this.angles == '0 -1 0') {
        this.angles = '-90 0 0';
    } else if (this.angles == '0 -2 0') {
        this.angles = '+90 0 0';
    }

    #define X(out, in) MACRO_BEGIN \
        if (in != 0) { out = out + (random() * 2 - 1) * in; } \
    MACRO_END
    X(this.origin.x, this.originjitter.x); X(this.origin.y, this.originjitter.y); X(this.origin.z, this.originjitter.z);
    X(this.angles.x, this.anglesjitter.x); X(this.angles.y, this.anglesjitter.y); X(this.angles.z, this.anglesjitter.z);
    X(this.angles.y, this.anglejitter);
    #undef X

    if (MUTATOR_CALLHOOK(OnEntityPreSpawn, this)) {
        delete(this);
        return;
    }
}

Here is the call graph for this function:

SV_PausedTic()

void SV_PausedTic

(

float

elapsedtime

)

Definition at line 200 of file main.qc.

References Pause_TryPause(), and server_is_dedicated.

{
    if (!server_is_dedicated) Pause_TryPause(false);
}

Here is the call graph for this function:

sys_phys_update()

void sys_phys_update	(	entity	this,
		float	dt
	)

Definition at line 11 of file physics.qc.

References absmax, absmin, angles, CheckPlayerJump(), com_phys_acc_rate, com_phys_acc_rate_air, com_phys_acc_rate_air_stop, com_phys_acc_rate_air_strafe, com_phys_air, com_phys_friction, com_phys_friction_air, com_phys_gravity, com_phys_ground, com_phys_ladder, com_phys_vel_2d, com_phys_vel_max, com_phys_vel_max_air, com_phys_vel_max_air_strafe, com_phys_water, CONTENT_LAVA, CONTENT_SLIME, CONTENT_WATER, conveyor, disableclientprediction, emit, FL_WATERJUMP, flags, IS_CLIENT, IS_DEAD, IS_ONGROUND, IS_ONSLICK, IS_PLAYER, IS_SVQC, IsFlying(), ITEMS_STAT, jumppadcount, ladder_entity, lastground, min(), move_movetype, move_qcphysics, movedir, MOVETYPE_FLY, MOVETYPE_FLY_WORLDONLY, MOVETYPE_FOLLOW, MOVETYPE_NOCLIP, MOVETYPE_NONE, MUTATOR_CALLHOOK, PHYS_ACCELERATE, PHYS_AIRACCELERATE, PHYS_AIRSTOPACCELERATE, PHYS_AIRSTRAFEACCELERATE, PHYS_FRICTION, PHYS_FRICTION_ONLAND, PHYS_INPUT_BUTTON_MASK, PHYS_MAXAIRSPEED, PHYS_MAXAIRSTRAFESPEED, PHYS_MAXSPEED, PHYS_SLICK_APPLYGRAVITY, PM_check_blocked(), PM_check_frozen(), PM_check_hitground(), PM_check_slick(), PM_Footsteps(), PM_jetpack(), sys_in_update(), sys_phys_ai(), sys_phys_fix(), sys_phys_fixspeed(), sys_phys_monitor(), sys_phys_override(), sys_phys_postupdate(), sys_phys_pregame_hold(), sys_phys_simulate(), sys_phys_simulate_simple(), sys_phys_spectator_control(), teleport_time, time, v_angle, vector(), velocity, viewloc_PlayerPhysics(), WAS_ONGROUND, wasFlying, waterlevel, WATERLEVEL_NONE, and WATERLEVEL_SWIMMING.

Referenced by StartFrame().

{
    if (!IS_CLIENT(this)) {
        sys_phys_simulate_simple(this, dt);
        return;
    }
    sys_in_update(this, dt);

    sys_phys_fix(this, dt);
    if (sys_phys_override(this, dt))
        return;

    sys_phys_monitor(this, dt);

    PHYS_CS(this).movement_old = PHYS_CS(this).movement;
    PHYS_CS(this).v_angle_old = this.v_angle;
    PHYS_CS(this).buttons_old = PHYS_INPUT_BUTTON_MASK(this);

    sys_phys_ai(this);

    sys_phys_pregame_hold(this);

    if (IS_SVQC) {
        if (this.move_movetype == MOVETYPE_NONE) { return; }
        // when we get here, disableclientprediction cannot be 2
        if(this.move_movetype == MOVETYPE_FOLLOW) // not compatible with prediction
            this.disableclientprediction = 1;
        else if(this.move_qcphysics)
            this.disableclientprediction = -1;
        else
            this.disableclientprediction = 0;
    }

    viewloc_PlayerPhysics(this);

    PM_check_frozen(this);

    PM_check_blocked(this);

    float maxspeed_mod = 1;

// conveyors: first fix velocity
    if (this.conveyor.active) { this.velocity -= this.conveyor.movedir; }
    MUTATOR_CALLHOOK(PlayerPhysics, this, dt);

    if (!IS_PLAYER(this)) {
        sys_phys_spectator_control(this);
        maxspeed_mod = STAT(SPECTATORSPEED, this);
    }
    sys_phys_fixspeed(this, maxspeed_mod);

    if (IS_DEAD(this)) {
        // handle water here
        vector midpoint = ((this.absmin + this.absmax) * 0.5);
        int cont = pointcontents(midpoint);
        if (cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME) {
            this.velocity = this.velocity * 0.5;

            // do we want this?
            // if(pointcontents(midpoint + '0 0 2') == CONTENT_WATER)
            // { this.velocity_z = 70; }
        }
        sys_phys_postupdate(this);
        return;
    }

    PM_check_slick(this);

    if (IS_SVQC && !PHYS_FIXANGLE(this)) { this.angles = '0 1 0' * this.v_angle.y; }
    if (IS_PLAYER(this)) {
        if (IS_ONGROUND(this)) {
            PM_check_hitground(this);
            PM_Footsteps(this);
        } else if (IsFlying(this)) {
            this.wasFlying = true;
        }
        CheckPlayerJump(this);
    }

    if (this.flags & FL_WATERJUMP) {
        this.velocity_x = this.movedir.x;
        this.velocity_y = this.movedir.y;
        if (time > this.teleport_time || this.waterlevel == WATERLEVEL_NONE) {
            this.flags &= ~FL_WATERJUMP;
            this.teleport_time = 0;
        }
    } else if (MUTATOR_CALLHOOK(PM_Physics, this, maxspeed_mod, dt)) {
        // handled
    } else if (this.move_movetype == MOVETYPE_NOCLIP
        || this.move_movetype == MOVETYPE_FLY
        || this.move_movetype == MOVETYPE_FLY_WORLDONLY
        || MUTATOR_CALLHOOK(IsFlying, this)) {
        this.com_phys_friction = PHYS_FRICTION(this);
        this.com_phys_vel_max = PHYS_MAXSPEED(this) * maxspeed_mod;
        this.com_phys_acc_rate = PHYS_ACCELERATE(this) * maxspeed_mod;
        this.com_phys_friction_air = true;
        sys_phys_simulate(this, dt);
        this.com_phys_friction_air = false;
    } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
        this.com_phys_vel_max = PHYS_MAXSPEED(this) * maxspeed_mod;
        this.com_phys_acc_rate = PHYS_ACCELERATE(this) * maxspeed_mod;
        this.com_phys_water = true;
        sys_phys_simulate(this, dt);
        this.com_phys_water = false;
        this.jumppadcount = 0;
    } else if (this.ladder_entity) {
        this.com_phys_friction = PHYS_FRICTION(this);
        this.com_phys_vel_max = PHYS_MAXSPEED(this) * maxspeed_mod;
        this.com_phys_acc_rate = PHYS_ACCELERATE(this) * maxspeed_mod;
        this.com_phys_gravity = -PHYS_GRAVITY(this) * dt;
        if (PHYS_ENTGRAVITY(this)) { this.com_phys_gravity *= PHYS_ENTGRAVITY(this); }
        this.com_phys_ladder = true;
        this.com_phys_friction_air = true;
        sys_phys_simulate(this, dt);
        this.com_phys_friction_air = false;
        this.com_phys_ladder = false;
        this.com_phys_gravity = 0;
    } else if (ITEMS_STAT(this) & IT_USING_JETPACK) {
        PM_jetpack(this, maxspeed_mod, dt);
    } else if (IS_ONGROUND(this) && (!IS_ONSLICK(this) || !PHYS_SLICK_APPLYGRAVITY(this))) {
        if (!WAS_ONGROUND(this)) {
            emit(phys_land, this);
            if (this.lastground < time - 0.3) {
                this.velocity *= (1 - PHYS_FRICTION_ONLAND(this));
            }
        }
        this.com_phys_vel_max = PHYS_MAXSPEED(this) * maxspeed_mod;
        this.com_phys_gravity = -PHYS_GRAVITY(this) * dt;
        if (PHYS_ENTGRAVITY(this)) { this.com_phys_gravity *= PHYS_ENTGRAVITY(this); }
        this.com_phys_ground = true;
        this.com_phys_vel_2d = true;
        sys_phys_simulate(this, dt);
        this.com_phys_vel_2d = false;
        this.com_phys_ground = false;
        this.com_phys_gravity = 0;
    } else {
        this.com_phys_acc_rate_air = PHYS_AIRACCELERATE(this) * min(maxspeed_mod, 1);
        this.com_phys_acc_rate_air_stop = PHYS_AIRSTOPACCELERATE(this) * maxspeed_mod;
        this.com_phys_acc_rate_air_strafe = PHYS_AIRSTRAFEACCELERATE(this) * maxspeed_mod;
        this.com_phys_vel_max_air_strafe = PHYS_MAXAIRSTRAFESPEED(this) * maxspeed_mod;
        this.com_phys_vel_max_air = PHYS_MAXAIRSPEED(this) * maxspeed_mod;
        this.com_phys_vel_max = PHYS_MAXAIRSPEED(this) * min(maxspeed_mod, 1);
        this.com_phys_air = true;
        this.com_phys_vel_2d = true;
        sys_phys_simulate(this, dt);
        this.com_phys_vel_2d = false;
        this.com_phys_air = false;
    }

    sys_phys_postupdate(this);
}

Here is the call graph for this function:

Here is the caller graph for this function:

systems_update()

void systems_update

(

)

Definition at line 7 of file main.qc.

{
    float realtime = time;
    SYSTEM_UPDATE(phys);
    time = realtime;
}

URI_Get_Callback()

void URI_Get_Callback	(	float	id,
		float	status,
		string	data
	)

engine callback

Definition at line 469 of file main.qc.

References Curl_URI_Get_Callback(), ftos(), LOG_INFO, MUTATOR_CALLHOOK, OnlineBanList_URI_Get_Callback(), URI_GET_CURL, URI_GET_CURL_END, URI_GET_DISCARD, URI_GET_IPBAN, URI_GET_IPBAN_END, and url_URI_Get_Callback().

{
    if(url_URI_Get_Callback(id, status, data))
    {
        // handled
    }
    else if (id == URI_GET_DISCARD)
    {
        // discard
    }
    else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
    {
        // sv_cmd curl
        Curl_URI_Get_Callback(id, status, data);
    }
    else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
    {
        // online ban list
        OnlineBanList_URI_Get_Callback(id, status, data);
    }
    else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
    {
        // handled by a mutator
    }
    else
    {
        LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
    }
}

Here is the call graph for this function:

WarpZone_PostInitialize_Callback()

void WarpZone_PostInitialize_Callback

(

)

Definition at line 456 of file main.qc.

References classname, DPCONTENTS_BODY, DPCONTENTS_BOTCLIP, DPCONTENTS_PLAYERCLIP, DPCONTENTS_SOLID, entity(), find(), NULL, spawn(), and waypoint_spawnforteleporter_wz().

Referenced by WarpZone_Projectile_Touch().

{
    // create waypoint links for warpzones
    entity tracetest_ent = spawn();
    setsize(tracetest_ent, PL_MIN_CONST, PL_MAX_CONST);
    tracetest_ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
    //for(entity e = warpzone_first; e; e = e.warpzone_next)
    for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
        waypoint_spawnforteleporter_wz(e, tracetest_ent);
    delete(tracetest_ent);
}

Here is the call graph for this function:

Here is the caller graph for this function:

Variable Documentation

anglejitter

float anglejitter

Definition at line 350 of file main.qc.

anglesjitter

vector anglesjitter

Definition at line 349 of file main.qc.

autocvar_sv_autopause

bool autocvar_sv_autopause = false

Definition at line 271 of file main.qc.

Referenced by StartFrame().

cvarfilter

string cvarfilter

Definition at line 352 of file main.qc.

Referenced by SV_OnEntityPreSpawnFunction().

game_delay_last

bool game_delay_last

Definition at line 269 of file main.qc.

Referenced by StartFrame().

gametypefilter

string gametypefilter

Definition at line 351 of file main.qc.

Referenced by SV_OnEntityPreSpawnFunction().

originjitter

vector originjitter

Definition at line 348 of file main.qc.

Referenced by SUB().