sv_freezetag.qc File Reference

#include "sv_freezetag.qh"
#include <common/resources/sv_resources.qh>
#include <server/elimination.qh>

Include dependency graph for sv_freezetag.qc:

Go to the source code of this file.

Macros
#define	IN_REVIVING_RANGE(player, it, revive_extra_size)

Functions
void	freezetag_Add_Score (entity targ, entity attacker)
bool	freezetag_CheckTeams ()
bool	freezetag_CheckWinner ()
void	freezetag_count_alive_players ()
void	freezetag_Freeze (entity targ, entity attacker)
void	freezetag_Initialize ()
bool	freezetag_isEliminated (entity e)
entity	freezetag_LastPlayerForTeam (entity this)
void	freezetag_LastPlayerForTeam_Notify (entity this)
void	ft_RemovePlayer (entity this)
void	havocbot_goalrating_ft_freeplayers (entity this, float ratingscale, vector org, float sradius)
void	havocbot_role_ft_freeing (entity this)
void	havocbot_role_ft_offense (entity this)
	MUTATOR_HOOKFUNCTION (ft, ClientDisconnect)
	MUTATOR_HOOKFUNCTION (ft, MakePlayerObserver)
	MUTATOR_HOOKFUNCTION (ft, PlayerDies)
	MUTATOR_HOOKFUNCTION (ft, PlayerSpawn)
	MUTATOR_HOOKFUNCTION (ft, reset_map_players)
	MUTATOR_HOOKFUNCTION (ft, GiveFragsForKill, CBC_ORDER_FIRST)
	MUTATOR_HOOKFUNCTION (ft, Unfreeze)
	MUTATOR_HOOKFUNCTION (ft, Damage_Calculate)
	MUTATOR_HOOKFUNCTION (ft, PlayerPreThink, CBC_ORDER_FIRST)
	MUTATOR_HOOKFUNCTION (ft, SetStartItems)
	MUTATOR_HOOKFUNCTION (ft, HavocBot_ChooseRole)
	MUTATOR_HOOKFUNCTION (ft, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
	MUTATOR_HOOKFUNCTION (ft, SetWeaponArena)
	MUTATOR_HOOKFUNCTION (ft, FragCenterMessage)
	MUTATOR_HOOKFUNCTION (ft, SV_ParseServerCommand)
	MUTATOR_HOOKFUNCTION (ft, Scores_CountFragsRemaining)
void	nades_Clear (entity)
void	nades_GiveBonus (entity player, float score)
	void (entity this) havocbot_role_ft_freeing

Variables
float	autocvar_g_freezetag_frozen_maxtime
float	autocvar_g_freezetag_revive_clearspeed
float	autocvar_g_freezetag_round_timelimit
int	autocvar_g_freezetag_teams_override
float	autocvar_g_freezetag_warmup
float	autocvar_g_ft_start_ammo_cells = 180
float	autocvar_g_ft_start_ammo_fuel = 0
float	autocvar_g_ft_start_ammo_nails = 320
float	autocvar_g_ft_start_ammo_plasma = 180
float	autocvar_g_ft_start_ammo_rockets = 160
float	autocvar_g_ft_start_ammo_shells = 60
float	autocvar_g_ft_start_armor = 100
float	autocvar_g_ft_start_health = 100

Macro Definition Documentation

IN_REVIVING_RANGE

#define IN_REVIVING_RANGE	(		player,
			it,
			revive_extra_size
	)

Value:

(it != player && !IS_DEAD(it) && SAME_TEAM(it, player) \
    && boxesoverlap(player.absmin - revive_extra_size, player.absmax + revive_extra_size, it.absmin, it.absmax))

Definition at line 499 of file sv_freezetag.qc.

Referenced by MUTATOR_HOOKFUNCTION().

Function Documentation

freezetag_Add_Score()

void freezetag_Add_Score	(	entity	targ,
		entity	attacker
	)

Definition at line 158 of file sv_freezetag.qc.

References GameRules_scoring_add, and IS_PLAYER.

Referenced by freezetag_Freeze(), and MUTATOR_HOOKFUNCTION().

{
    if(attacker == targ)
    {
        // you froze your own dumb self
        // counted as "suicide" already
        GameRules_scoring_add(targ, SCORE, -1);
    }
    else if(IS_PLAYER(attacker))
    {
        // got frozen by an enemy
        // counted as "kill" and "death" already
        GameRules_scoring_add(targ, SCORE, -1);
        GameRules_scoring_add(attacker, SCORE, +1);
    }
    // else nothing - got frozen by the game type rules themselves
}

Here is the caller graph for this function:

freezetag_CheckTeams()

bool freezetag_CheckTeams

(

)

Definition at line 52 of file sv_freezetag.qc.

References entity(), freezetag_teams, nades_Clear(), nades_GiveBonus(), NULL, NUM_TEAMS, NumTeams(), Team_GetNumberOfAlivePlayers(), Team_GetNumberOfAliveTeams(), Team_GetTeamFromIndex(), Team_IndexToBit(), and total_players.

Referenced by freezetag_Initialize().

{
    static float prev_missing_teams_mask;
    if (Team_GetNumberOfAliveTeams() == NumTeams(freezetag_teams))
    {
        if(prev_missing_teams_mask > 0)
            Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
        prev_missing_teams_mask = -1;
        return true;
    }
    if(total_players == 0)
    {
        if(prev_missing_teams_mask > 0)
            Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
        prev_missing_teams_mask = -1;
        return false;
    }
    int missing_teams_mask = 0;
    for (int i = 1; i <= NUM_TEAMS; ++i)
    {
        if ((freezetag_teams & Team_IndexToBit(i)) &&
            (Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(i)) == 0))
        {
            missing_teams_mask |= Team_IndexToBit(i);
        }
    }
    if(prev_missing_teams_mask != missing_teams_mask)
    {
        Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
        prev_missing_teams_mask = missing_teams_mask;
    }
    return false;
}

Here is the call graph for this function:

Here is the caller graph for this function:

freezetag_CheckWinner()

bool freezetag_CheckWinner

(

)

Definition at line 89 of file sv_freezetag.qc.

References APP_TEAM_NUM, autocvar_g_freezetag_round_timelimit, autocvar_g_freezetag_warmup, FOREACH_CLIENT, IS_PLAYER, nades_Clear(), NULL, round_handler_GetEndTime, round_handler_Init(), ST_FT_ROUNDS, Team_GetWinnerAliveTeam(), TeamScore_AddToTeam(), and time.

Referenced by freezetag_Initialize().

{
    if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
    {
        Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
        Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
        FOREACH_CLIENT(IS_PLAYER(it), {
            it.freezetag_frozen_timeout = 0;
            it.freezetag_revive_time = 0;
            nades_Clear(it);
        });
        game_stopped = true;
        round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
        return true;
    }

    int winner_team = Team_GetWinnerAliveTeam();
    if (!winner_team)
        return false;

    if(winner_team > 0)
    {
        Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
        Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
        TeamScore_AddToTeam(winner_team, ST_FT_ROUNDS, +1);
    }
    else if(winner_team == -1)
    {
        Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
        Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
    }

    FOREACH_CLIENT(IS_PLAYER(it), {
        it.freezetag_frozen_timeout = 0;
        it.freezetag_revive_time = 0;
        nades_Clear(it);
    });

    game_stopped = true;
    round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
    return true;
}

Here is the call graph for this function:

Here is the caller graph for this function:

freezetag_count_alive_players()

void freezetag_count_alive_players

(

)

Definition at line 22 of file sv_freezetag.qc.

References eliminatedPlayers, entity(), Entity_GetTeam(), Entity_HasValidTeam(), FOREACH_CLIENT, FROZEN_NORMAL, GetResource(), IS_PLAYER, IS_REAL_CLIENT, NUM_TEAMS, RES_HEALTH, Team_GetNumberOfAlivePlayers(), Team_GetTeamFromIndex(), Team_SetNumberOfAlivePlayers(), and total_players.

Referenced by freezetag_Freeze(), ft_RemovePlayer(), and MUTATOR_HOOKFUNCTION().

{
    total_players = 0;
    for (int i = 1; i <= NUM_TEAMS; ++i)
    {
        Team_SetNumberOfAlivePlayers(Team_GetTeamFromIndex(i), 0);
    }
    FOREACH_CLIENT(IS_PLAYER(it) && Entity_HasValidTeam(it),
    {
        ++total_players;
        if (GetResource(it, RES_HEALTH) < 1 || STAT(FROZEN, it) == FROZEN_NORMAL)
        {
            continue;
        }
        entity team_ = Entity_GetTeam(it);
        int num_alive = Team_GetNumberOfAlivePlayers(team_);
        ++num_alive;
        Team_SetNumberOfAlivePlayers(team_, num_alive);
    });
    FOREACH_CLIENT(IS_REAL_CLIENT(it),
    {
        STAT(REDALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(1));
        STAT(BLUEALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(2));
        STAT(YELLOWALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(3));
        STAT(PINKALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(4));
    });

    eliminatedPlayers.SendFlags |= 1;
}

Here is the call graph for this function:

Here is the caller graph for this function:

freezetag_Freeze()

void freezetag_Freeze	(	entity	targ,
		entity	attacker
	)

Definition at line 177 of file sv_freezetag.qc.

References autocvar_g_freezetag_frozen_maxtime, autocvar_g_freezetag_revive_auto, Freeze(), freezetag_Add_Score(), freezetag_count_alive_players(), FROZEN_NORMAL, and time.

Referenced by MUTATOR_HOOKFUNCTION().

{
    if(STAT(FROZEN, targ))
        return;

    targ.freezetag_frozen_time = time;
    if (autocvar_g_freezetag_revive_auto && autocvar_g_freezetag_frozen_maxtime > 0)
        targ.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime;

    Freeze(targ, 0, FROZEN_NORMAL, true);

    freezetag_count_alive_players();

    freezetag_Add_Score(targ, attacker);
}

Here is the call graph for this function:

Here is the caller graph for this function:

freezetag_Initialize()

void freezetag_Initialize

(

)

Definition at line 752 of file sv_freezetag.qc.

References autocvar_g_freezetag_round_timelimit, autocvar_g_freezetag_teams_override, autocvar_g_freezetag_warmup, BITS, bound(), cvar(), EliminatedPlayers_Init(), freezetag_CheckTeams(), freezetag_CheckWinner(), freezetag_isEliminated(), freezetag_teams, func_null(), GameRules_scoring, round_handler_Init(), round_handler_Spawn(), SFL_SORT_PRIO_PRIMARY, and ST_FT_ROUNDS.

Referenced by REGISTER_MUTATOR().

{
    freezetag_teams = autocvar_g_freezetag_teams_override;
    if(freezetag_teams < 2)
        freezetag_teams = cvar("g_freezetag_teams"); // read the cvar directly as it gets written earlier in the same frame

    freezetag_teams = BITS(bound(2, freezetag_teams, 4));
    GameRules_scoring(freezetag_teams, SFL_SORT_PRIO_PRIMARY, 0, {
        field_team(ST_FT_ROUNDS, "rounds", SFL_SORT_PRIO_PRIMARY);
        field(SP_FREEZETAG_REVIVALS, "revivals", 0);
    });

    round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, func_null);
    round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);

    EliminatedPlayers_Init(freezetag_isEliminated);
}

Here is the call graph for this function:

Here is the caller graph for this function:

freezetag_isEliminated()

bool freezetag_isEliminated

(

entity

e

)

Definition at line 193 of file sv_freezetag.qc.

References entity(), FROZEN_NORMAL, havocbot_role_ft_freeing(), havocbot_role_ft_offense(), IS_DEAD, IS_PLAYER, and void().

Referenced by freezetag_Initialize().

{
    if(IS_PLAYER(e) && (STAT(FROZEN, e) == FROZEN_NORMAL || IS_DEAD(e)))
        return true;
    return false;
}

Here is the call graph for this function:

Here is the caller graph for this function:

freezetag_LastPlayerForTeam()

entity freezetag_LastPlayerForTeam

(

entity

this

)

Definition at line 132 of file sv_freezetag.qc.

References entity(), FOREACH_CLIENT, FROZEN_NORMAL, GetResource(), IS_PLAYER, NULL, RES_HEALTH, and SAME_TEAM.

Referenced by freezetag_LastPlayerForTeam_Notify().

{
    entity last_pl = NULL;
    FOREACH_CLIENT(IS_PLAYER(it) && it != this && SAME_TEAM(it, this), {
        if (STAT(FROZEN, it) != FROZEN_NORMAL && GetResource(it, RES_HEALTH) >= 1)
        {
            if (!last_pl)
                last_pl = it;
            else
                return NULL;
        }
    });
    return last_pl;
}

Here is the call graph for this function:

Here is the caller graph for this function:

freezetag_LastPlayerForTeam_Notify()

void freezetag_LastPlayerForTeam_Notify

(

entity

this

)

Definition at line 147 of file sv_freezetag.qc.

References entity(), freezetag_LastPlayerForTeam(), round_handler_IsActive, and round_handler_IsRoundStarted.

Referenced by ft_RemovePlayer(), and MUTATOR_HOOKFUNCTION().

{
    if(round_handler_IsActive())
    if(round_handler_IsRoundStarted())
    {
        entity pl = freezetag_LastPlayerForTeam(this);
        if(pl)
            Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

ft_RemovePlayer()

void ft_RemovePlayer

(

entity

this

)

Definition at line 309 of file sv_freezetag.qc.

References freezetag_count_alive_players(), freezetag_LastPlayerForTeam_Notify(), FROZEN_NORMAL, RES_HEALTH, SetResourceExplicit(), and Unfreeze().

Referenced by MUTATOR_HOOKFUNCTION().

{
    if (STAT(FROZEN, this) != FROZEN_NORMAL)
        freezetag_LastPlayerForTeam_Notify(this);
    Unfreeze(this, false);

    SetResourceExplicit(this, RES_HEALTH, 0); // neccessary to correctly count alive players
    freezetag_count_alive_players();
}

Here is the call graph for this function:

Here is the caller graph for this function:

havocbot_goalrating_ft_freeplayers()

void havocbot_goalrating_ft_freeplayers	(	entity	this,
		float	ratingscale,
		vector	org,
		float	sradius
	)

Definition at line 208 of file sv_freezetag.qc.

References entity(), FLOAT_MAX, FOREACH_CLIENT, FROZEN_NORMAL, GetResource(), IS_PLAYER, navigation_routerating(), NULL, RES_HEALTH, SAME_TEAM, vdist, and vlen2.

Referenced by havocbot_role_ft_freeing(), and havocbot_role_ft_offense().

{
    entity best_pl = NULL;
    float best_dist2 = FLOAT_MAX;
    FOREACH_CLIENT(IS_PLAYER(it) && it != this && SAME_TEAM(it, this), {
        if (STAT(FROZEN, it) == FROZEN_NORMAL)
        {
            if(vdist(it.origin - org, >, sradius))
                continue;
            navigation_routerating(this, it, ratingscale, 2000);
        }
        else if (best_dist2
            && GetResource(it, RES_HEALTH) < GetResource(this, RES_HEALTH) + 30
            && vlen2(it.origin - org) < best_dist2)
        {
            // If teamate is not frozen still seek them out as fight better
            // in a group.
            best_dist2 = vlen2(it.origin - org);
            if (best_dist2 < 700 ** 2)
            {
                best_pl = NULL;
                best_dist2 = 0; // already close to a teammate
            }
            else
                best_pl = it;
        }
    });
    if (best_pl)
        navigation_routerating(this, best_pl, ratingscale / 2, 2000);
}

Here is the call graph for this function:

Here is the caller graph for this function:

havocbot_role_ft_freeing()

void havocbot_role_ft_freeing

(

entity

this

)

Definition at line 275 of file sv_freezetag.qc.

References havocbot_goalrating_enemyplayers(), havocbot_goalrating_ft_freeplayers(), havocbot_goalrating_items(), havocbot_goalrating_waypoints(), havocbot_role_ft_offense(), havocbot_role_timeout, IS_DEAD, LOG_TRACE, navigation_goalrating_end(), navigation_goalrating_start(), navigation_goalrating_timeout(), navigation_goalrating_timeout_set(), origin, random(), and time.

Referenced by freezetag_isEliminated(), havocbot_role_ft_offense(), and MUTATOR_HOOKFUNCTION().

{
    if(IS_DEAD(this))
        return;

    if (!this.havocbot_role_timeout)
        this.havocbot_role_timeout = time + random() * 10 + 20;

    if (time > this.havocbot_role_timeout)
    {
        LOG_TRACE("changing role to offense");
        this.havocbot_role = havocbot_role_ft_offense;
        this.havocbot_role_timeout = 0;
        return;
    }

    if (navigation_goalrating_timeout(this))
    {
        navigation_goalrating_start(this);
        havocbot_goalrating_items(this, 10000, this.origin, 10000);
        havocbot_goalrating_enemyplayers(this, 5000, this.origin, 10000);
        havocbot_goalrating_ft_freeplayers(this, 20000, this.origin, 10000);
        havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
        navigation_goalrating_end(this);

        navigation_goalrating_timeout_set(this);
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

havocbot_role_ft_offense()

void havocbot_role_ft_offense

(

entity

this

)

Definition at line 239 of file sv_freezetag.qc.

References FOREACH_CLIENT, FROZEN_NORMAL, havocbot_goalrating_enemyplayers(), havocbot_goalrating_ft_freeplayers(), havocbot_goalrating_items(), havocbot_goalrating_waypoints(), havocbot_role_ft_freeing(), havocbot_role_timeout, IS_DEAD, IS_PLAYER, LOG_TRACE, navigation_goalrating_end(), navigation_goalrating_start(), navigation_goalrating_timeout(), navigation_goalrating_timeout_set(), origin, random(), SAME_TEAM, and time.

Referenced by freezetag_isEliminated(), havocbot_role_ft_freeing(), and MUTATOR_HOOKFUNCTION().

{
    if(IS_DEAD(this))
        return;

    if (!this.havocbot_role_timeout)
        this.havocbot_role_timeout = time + random() * 10 + 20;

    // Count how many players on team are unfrozen.
    int unfrozen = 0;
    FOREACH_CLIENT(IS_PLAYER(it) && SAME_TEAM(it, this) && STAT(FROZEN, it) != FROZEN_NORMAL, {
        unfrozen++;
    });

    // If only one left on team or if role has timed out then start trying to free players.
    if ((!unfrozen && STAT(FROZEN, this) != FROZEN_NORMAL) || time > this.havocbot_role_timeout)
    {
        LOG_TRACE("changing role to freeing");
        this.havocbot_role = havocbot_role_ft_freeing;
        this.havocbot_role_timeout = 0;
        return;
    }

    if (navigation_goalrating_timeout(this))
    {
        navigation_goalrating_start(this);
        havocbot_goalrating_items(this, 12000, this.origin, 10000);
        havocbot_goalrating_enemyplayers(this, 10000, this.origin, 10000);
        havocbot_goalrating_ft_freeplayers(this, 9000, this.origin, 10000);
        havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
        navigation_goalrating_end(this);

        navigation_goalrating_timeout_set(this);
    }
}

Here is the call graph for this function:

Here is the caller graph for this function:

MUTATOR_HOOKFUNCTION() [1/16]

MUTATOR_HOOKFUNCTION	(	ft	,
		ClientDisconnect
	)

Definition at line 319 of file sv_freezetag.qc.

References entity(), ft_RemovePlayer(), and M_ARGV.

{
    entity player = M_ARGV(0, entity);

    ft_RemovePlayer(player);
    return true;
}

Here is the call graph for this function:

MUTATOR_HOOKFUNCTION() [2/16]

MUTATOR_HOOKFUNCTION	(	ft	,
		MakePlayerObserver
	)

Definition at line 327 of file sv_freezetag.qc.

References entity(), ft_RemovePlayer(), and M_ARGV.

{
    entity player = M_ARGV(0, entity);

    ft_RemovePlayer(player);
}

Here is the call graph for this function:

MUTATOR_HOOKFUNCTION() [3/16]

MUTATOR_HOOKFUNCTION	(	ft	,
		PlayerDies
	)

Definition at line 334 of file sv_freezetag.qc.

References entity(), freezetag_Add_Score(), freezetag_count_alive_players(), freezetag_Freeze(), freezetag_LastPlayerForTeam_Notify(), FROZEN_NORMAL, IS_PLAYER, ITEM_DAMAGE_NEEDKILL, M_ARGV, NULL, RESPAWN_FORCE, round_handler_CountdownRunning, round_handler_IsActive, time, and Unfreeze().

{
    entity frag_attacker = M_ARGV(1, entity);
    entity frag_target = M_ARGV(2, entity);
    float frag_deathtype = M_ARGV(3, float);

    if(round_handler_IsActive())
    if(round_handler_CountdownRunning())
    {
        if (STAT(FROZEN, frag_target) == FROZEN_NORMAL)
            Unfreeze(frag_target, true);
        freezetag_count_alive_players();
        frag_target.respawn_time = time;
        frag_target.respawn_flags |= RESPAWN_FORCE;
        return true;
    }

    frag_target.respawn_time = time + 1;
    frag_target.respawn_flags |= RESPAWN_FORCE;

    // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
    // you succeed changing team through the menu: you both really die (gibbing) and get frozen
    if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
        || frag_deathtype == DEATH_TEAMCHANGE.m_id || frag_deathtype == DEATH_AUTOTEAMCHANGE.m_id)
    {
        // let the player die, he will be automatically frozen when he respawns
        if (STAT(FROZEN, frag_target) != FROZEN_NORMAL)
        {
            freezetag_Add_Score(frag_target, frag_attacker);
            freezetag_count_alive_players();
            freezetag_LastPlayerForTeam_Notify(frag_target);
            frag_target.freezetag_frozen_timeout = -2; // freeze on respawn
        }
        else
        {
            float t = frag_target.freezetag_frozen_timeout;
            float t2 = frag_target.freezetag_frozen_time;
            Unfreeze(frag_target, false); // remove ice
            // keep timeout value so it can be restored when player will be refrozen on respawn
            // NOTE this can't be exactly -2 since game starts from time 2
            frag_target.freezetag_frozen_timeout = -t;
            frag_target.freezetag_frozen_time = t2;
        }
        return true;
    }

    if (STAT(FROZEN, frag_target) == FROZEN_NORMAL)
        return true;

    freezetag_Freeze(frag_target, frag_attacker);
    freezetag_LastPlayerForTeam_Notify(frag_target);

    if(frag_attacker == frag_target || frag_attacker == NULL)
    {
        if(IS_PLAYER(frag_target))
            Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_SELF);
        Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_SELF, frag_target.netname);
    }
    else
    {
        Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_FREEZE, frag_target.netname, frag_attacker.netname);
    }

    return true;
}

Here is the call graph for this function:

MUTATOR_HOOKFUNCTION() [4/16]

MUTATOR_HOOKFUNCTION	(	ft	,
		PlayerSpawn
	)

Definition at line 400 of file sv_freezetag.qc.

References entity(), freezetag_count_alive_players(), freezetag_Freeze(), M_ARGV, NULL, round_handler_IsActive, and round_handler_IsRoundStarted.

{
    entity player = M_ARGV(0, entity);

    if(player.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
        return true; // do nothing, round is starting right now

    if(player.freezetag_frozen_timeout <= -2) // player was dead
    {
        float t = player.freezetag_frozen_timeout;
        float t2 = player.freezetag_frozen_time;
        freezetag_Freeze(player, NULL);
        if (t < -2)
        {
            player.freezetag_frozen_timeout = -t;
            player.freezetag_frozen_time = t2;
        }
        return true;
    }

    freezetag_count_alive_players();

    if(round_handler_IsActive())
    if(round_handler_IsRoundStarted())
    {
        Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_SPAWN_LATE);
        freezetag_Freeze(player, NULL);
    }

    return true;
}

Here is the call graph for this function:

MUTATOR_HOOKFUNCTION() [5/16]

MUTATOR_HOOKFUNCTION	(	ft	,
		reset_map_players
	)

Definition at line 432 of file sv_freezetag.qc.

References CS(), FOREACH_CLIENT, freezetag_count_alive_players(), IS_PLAYER, and PutClientInServer().

{
    FOREACH_CLIENT(IS_PLAYER(it), {
        CS(it).killcount = 0;
        it.freezetag_revive_time = 0;
        it.freezetag_frozen_timeout = -1;
        PutClientInServer(it);
        it.freezetag_frozen_timeout = 0;
    });
    freezetag_count_alive_players();
    return true;
}

Here is the call graph for this function:

MUTATOR_HOOKFUNCTION() [6/16]

MUTATOR_HOOKFUNCTION	(	ft	,
		GiveFragsForKill	,
		CBC_ORDER_FIRST
	)

Definition at line 445 of file sv_freezetag.qc.

References M_ARGV.

{
    M_ARGV(2, float) = 0; // no frags counted in Freeze Tag
    return true;
}

MUTATOR_HOOKFUNCTION() [7/16]

MUTATOR_HOOKFUNCTION	(	ft	,
		Unfreeze
	)

Definition at line 451 of file sv_freezetag.qc.

References entity(), and M_ARGV.

{
    entity targ = M_ARGV(0, entity);
    targ.freezetag_frozen_time = 0;
    targ.freezetag_frozen_timeout = 0;
}

Here is the call graph for this function:

MUTATOR_HOOKFUNCTION() [8/16]

MUTATOR_HOOKFUNCTION	(	ft	,
		Damage_Calculate
	)

Definition at line 458 of file sv_freezetag.qc.

References autocvar_g_freezetag_frozen_maxtime, autocvar_g_freezetag_revive_auto, autocvar_g_freezetag_revive_auto_reducible, autocvar_g_freezetag_revive_auto_reducible_forcefactor, autocvar_g_freezetag_revive_auto_reducible_maxforce, DIFF_TEAM, entity(), fabs(), FROZEN_NORMAL, M_ARGV, max(), time, vector(), and vlen().

{
    entity frag_attacker = M_ARGV(1, entity);
    entity frag_target = M_ARGV(2, entity);
    //float frag_deathtype = M_ARGV(3, float);
    //float frag_damage = M_ARGV(4, float);
    vector frag_force = M_ARGV(6, vector);

    if (STAT(FROZEN, frag_target) == FROZEN_NORMAL && autocvar_g_freezetag_revive_auto_reducible
        && autocvar_g_freezetag_frozen_maxtime > 0 && autocvar_g_freezetag_revive_auto)
    {
        float t = 0;
        if ((autocvar_g_freezetag_revive_auto_reducible < 0 || DIFF_TEAM(frag_attacker, frag_target))
            && frag_target.freezetag_frozen_timeout > time)
        {
            if (fabs(autocvar_g_freezetag_revive_auto_reducible) == 1)
            {
                float maxforce = autocvar_g_freezetag_revive_auto_reducible_maxforce;
                t = vlen(frag_force);
                // limit hit force considered at once, e.g when you have the Strength
                // powerup but also with weapons that fire multiple projectiles at once (crylink)
                if (frag_target.freezetag_frozen_force + t > maxforce)
                {
                    t = max(0, maxforce - frag_target.freezetag_frozen_force);
                    frag_target.freezetag_frozen_force = maxforce;
                }
                else
                    frag_target.freezetag_frozen_force += t;
                t *= autocvar_g_freezetag_revive_auto_reducible_forcefactor;
            }
            frag_target.freezetag_frozen_timeout -= t;
            if (frag_target.freezetag_frozen_timeout < time)
                frag_target.freezetag_frozen_timeout = time;
        }
    }
}

Here is the call graph for this function:

MUTATOR_HOOKFUNCTION() [9/16]

MUTATOR_HOOKFUNCTION	(	ft	,
		PlayerPreThink	,
		CBC_ORDER_FIRST
	)

Definition at line 503 of file sv_freezetag.qc.

References autocvar_g_freezetag_frozen_maxtime, autocvar_g_freezetag_revive_auto, autocvar_g_freezetag_revive_auto_progress, autocvar_g_freezetag_revive_clearspeed, autocvar_g_freezetag_revive_extra_size, autocvar_g_freezetag_revive_spawnshield, autocvar_g_freezetag_revive_speed, autocvar_g_freezetag_revive_speed_t2s, autocvar_g_freezetag_revive_time_to_score, autocvar_sv_eventlog, bound(), entity(), FOREACH_CLIENT, frametime, freezetag_count_alive_players(), FROZEN_NORMAL, ftos(), GameLogEcho(), GameRules_scoring_add, if(), IN_REVIVING_RANGE, IS_PLAYER, M_ARGV, max(), nades_GiveBonus(), NULL, RES_HEALTH, round_handler_IsActive, round_handler_IsRoundStarted, SetResourceExplicit(), start_health, strcat(), strlen(), substring(), time, Unfreeze(), vector(), warmup_stage, warmup_start_health, WP_FROZEN_COLOR, and WP_REVIVING_COLOR.

{
    if(game_stopped)
        return true;

    if(round_handler_IsActive())
    if(!round_handler_IsRoundStarted())
        return true;

    entity player = M_ARGV(0, entity);
    //if (STAT(FROZEN, player) == FROZEN_NORMAL)
    //if(player.freezetag_frozen_timeout > 0 && time < player.freezetag_frozen_timeout)
        //player.iceblock.alpha = ICE_MIN_ALPHA + (ICE_MAX_ALPHA - ICE_MIN_ALPHA) * (player.freezetag_frozen_timeout - time) / (player.freezetag_frozen_timeout - player.freezetag_frozen_time);

    player.freezetag_frozen_force = 0;

    if (!(frametime && IS_PLAYER(player)))
        return true;

    entity revivers_last = NULL;
    entity revivers_first = NULL;

    bool player_is_reviving = false;
    int n = 0;
    vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
    FOREACH_CLIENT(IS_PLAYER(it), {
        // check if player is reviving anyone
        if (STAT(FROZEN, it) == FROZEN_NORMAL)
        {
            if ((STAT(FROZEN, player) == FROZEN_NORMAL))
                continue;
            if (!IN_REVIVING_RANGE(player, it, revive_extra_size))
                continue;
            player_is_reviving = true;
            break;
        }

        if (!(STAT(FROZEN, player) == FROZEN_NORMAL))
            continue; // both player and it are NOT frozen
        if (!IN_REVIVING_RANGE(player, it, revive_extra_size))
            continue;

        // found a teammate that is reviving player
        if (autocvar_g_freezetag_revive_time_to_score > 0 && STAT(FROZEN, player) == FROZEN_NORMAL)
        {
            it.freezetag_revive_time += frametime / autocvar_g_freezetag_revive_time_to_score;
            while (it.freezetag_revive_time > 1)
            {
                GameRules_scoring_add(it, SCORE, +1);
                it.freezetag_revive_time -= 1;
            }
        }
        if (revivers_last)
            revivers_last.chain = it;
        revivers_last = it;
        if (!revivers_first)
            revivers_first = it;
        ++n;
    });
    if (revivers_last)
        revivers_last.chain = NULL;

    // allow normal revival during automatic revival
    // (if we wouldn't allow it then freezetag_frozen_timeout should be checked too in the previous loop)
    //if (STAT(FROZEN, player) == FROZEN_NORMAL) // redundant check
    if (!n && player.freezetag_frozen_timeout > 0 && time >= player.freezetag_frozen_timeout)
        n = -1;

    float base_progress = 0;
    if  (STAT(FROZEN, player) == FROZEN_NORMAL && autocvar_g_freezetag_revive_auto
        && autocvar_g_freezetag_frozen_maxtime > 0 && autocvar_g_freezetag_revive_auto_progress)
    {
        // NOTE if auto-revival is in progress, manual revive speed is reduced so that it always takes the same amount of time
        base_progress = bound(0, (1 - (player.freezetag_frozen_timeout - time) / autocvar_g_freezetag_frozen_maxtime), 1);
    }

    if (!n) // no teammate nearby
    {
        float clearspeed = autocvar_g_freezetag_revive_clearspeed;
        if (STAT(FROZEN, player) == FROZEN_NORMAL)
        {
            if (autocvar_g_freezetag_revive_time_to_score > 0)
            {
                if (STAT(REVIVE_PROGRESS, player) > base_progress)
                {
                    // reduce auto-revival time based on manual revival progress
                    base_progress = STAT(REVIVE_PROGRESS, player);
                    player.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime * (1 - STAT(REVIVE_PROGRESS, player));
                }
                // don't clear revive progress, it would allow stacking points
                // by entering and exiting the revival zone many times
                STAT(REVIVE_PROGRESS, player) = base_progress;
            }
            else
                STAT(REVIVE_PROGRESS, player) = bound(base_progress, STAT(REVIVE_PROGRESS, player) - frametime * clearspeed * (1 - base_progress), 1);
        }
        else if (!STAT(FROZEN, player) && !player_is_reviving)
            STAT(REVIVE_PROGRESS, player) = base_progress; // thawing nobody
    }
    else if (STAT(FROZEN, player) == FROZEN_NORMAL) // OK, there is at least one teammate reviving us
    {
        float spd = autocvar_g_freezetag_revive_speed_t2s;
        if (autocvar_g_freezetag_revive_time_to_score <= 0)
            spd = autocvar_g_freezetag_revive_speed * (1 - base_progress);
        STAT(REVIVE_PROGRESS, player) = bound(base_progress, STAT(REVIVE_PROGRESS, player) + frametime * max(1/60, spd), 1);

        if(STAT(REVIVE_PROGRESS, player) >= 1)
        {
            float frozen_time = time - player.freezetag_frozen_time;
            Unfreeze(player, false);
            SetResourceExplicit(player, RES_HEALTH, ((warmup_stage) ? warmup_start_health : start_health));
            player.spawnshieldtime = time + autocvar_g_freezetag_revive_spawnshield;
            freezetag_count_alive_players();

            if(n == -1)
            {
                if(autocvar_sv_eventlog)
                    GameLogEcho(strcat(":ft:autorevival:", ftos(player.playerid)));
                Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_AUTO_REVIVED, frozen_time);
                Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_AUTO_REVIVED, player.netname, frozen_time);
                return true;
            }

            // EVERY team mate nearby gets a point (even if multiple!)
            for(entity it = revivers_first; it; it = it.chain)
            {
                GameRules_scoring_add(it, FREEZETAG_REVIVALS, +1);
                if (autocvar_g_freezetag_revive_time_to_score <= 0)
                    GameRules_scoring_add(it, SCORE, +1);
                nades_GiveBonus(it, autocvar_g_nades_bonus_score_low);
            }

            Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_REVIVED, revivers_first.netname);
            Send_Notification(NOTIF_ONE, revivers_first, MSG_CENTER, CENTER_FREEZETAG_REVIVE, player.netname);
            Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_REVIVED, player.netname, revivers_first.netname);
            if(autocvar_sv_eventlog)
            {
                string revivers = "";
                for(entity it = revivers_first; it; it = it.chain)
                    revivers = strcat(revivers, ftos(it.playerid), ",");
                revivers = substring(revivers, 0, strlen(revivers) - 1);
                GameLogEcho(strcat(":ft:revival:", ftos(player.playerid), ":", revivers));
            }
        }

        for(entity it = revivers_first; it; it = it.chain)
            STAT(REVIVE_PROGRESS, it) = STAT(REVIVE_PROGRESS, player);
    }

    if (STAT(FROZEN, player) == FROZEN_NORMAL)
    {
        entity player_wp = player.waypointsprite_attached;
        if (n > 0 || (n == 0 && STAT(REVIVE_PROGRESS, player) > 0.95))
        {
            WaypointSprite_UpdateSprites(player_wp, WP_Reviving, WP_Null, WP_Null);
            WaypointSprite_UpdateTeamRadar(player_wp, RADARICON_WAYPOINT, WP_REVIVING_COLOR);
        }
        else
        {
            WaypointSprite_UpdateSprites(player_wp, WP_Frozen, WP_Null, WP_Null);
            WaypointSprite_UpdateTeamRadar(player_wp, RADARICON_WAYPOINT, WP_FROZEN_COLOR);
        }

        WaypointSprite_UpdateMaxHealth(player_wp, 1);
        WaypointSprite_UpdateHealth(player_wp, STAT(REVIVE_PROGRESS, player));
    }

    return true;
}

Here is the call graph for this function:

MUTATOR_HOOKFUNCTION() [10/16]

MUTATOR_HOOKFUNCTION	(	ft	,
		SetStartItems
	)

Definition at line 673 of file sv_freezetag.qc.

References autocvar_g_ft_start_ammo_cells, autocvar_g_ft_start_ammo_fuel, autocvar_g_ft_start_ammo_nails, autocvar_g_ft_start_ammo_plasma, autocvar_g_ft_start_ammo_rockets, autocvar_g_ft_start_ammo_shells, autocvar_g_ft_start_armor, autocvar_g_ft_start_health, cvar(), start_ammo_cells, start_ammo_fuel, start_ammo_nails, start_ammo_plasma, start_ammo_rockets, start_ammo_shells, start_armorvalue, start_health, start_items, warmup_start_ammo_cells, warmup_start_ammo_fuel, warmup_start_ammo_nails, warmup_start_ammo_plasma, warmup_start_ammo_rockets, warmup_start_ammo_shells, warmup_start_armorvalue, and warmup_start_health.

{
    start_items &= ~(IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS);
    if(!cvar("g_use_ammunition"))
        start_items |= IT_UNLIMITED_AMMO;

    start_health       = warmup_start_health       = autocvar_g_ft_start_health;
    start_armorvalue   = warmup_start_armorvalue   = autocvar_g_ft_start_armor;
    start_ammo_shells  = warmup_start_ammo_shells  = autocvar_g_ft_start_ammo_shells;
    start_ammo_nails   = warmup_start_ammo_nails   = autocvar_g_ft_start_ammo_nails;
    start_ammo_rockets = warmup_start_ammo_rockets = autocvar_g_ft_start_ammo_rockets;
    start_ammo_cells   = warmup_start_ammo_cells   = autocvar_g_ft_start_ammo_cells;
    start_ammo_plasma  = warmup_start_ammo_plasma  = autocvar_g_ft_start_ammo_plasma;
    start_ammo_fuel    = warmup_start_ammo_fuel    = autocvar_g_ft_start_ammo_fuel;
}

Here is the call graph for this function:

MUTATOR_HOOKFUNCTION() [11/16]

MUTATOR_HOOKFUNCTION	(	ft	,
		HavocBot_ChooseRole
	)

Definition at line 689 of file sv_freezetag.qc.

References CS(), entity(), havocbot_role_ft_freeing(), havocbot_role_ft_offense(), IS_DEAD, jointime, M_ARGV, random(), and time.

{
    entity bot = M_ARGV(0, entity);

    if (!IS_DEAD(bot))
    {
        if (random() < 0.5)
            bot.havocbot_role = havocbot_role_ft_freeing;
        else
            bot.havocbot_role = havocbot_role_ft_offense;
    }

    // if bots spawn all at once assign them a more appropriated role after a while
    if (time < CS(bot).jointime + 1)
        bot.havocbot_role_timeout = time + 10 + random() * 10;

    return true;
}

Here is the call graph for this function:

MUTATOR_HOOKFUNCTION() [12/16]

MUTATOR_HOOKFUNCTION	(	ft	,
		TeamBalance_CheckAllowedTeams	,
		CBC_ORDER_EXCLUSIVE
	)

Definition at line 708 of file sv_freezetag.qc.

References freezetag_teams, and M_ARGV.

{
    M_ARGV(0, float) = freezetag_teams;
    return true;
}

MUTATOR_HOOKFUNCTION() [13/16]

MUTATOR_HOOKFUNCTION	(	ft	,
		SetWeaponArena
	)

Definition at line 714 of file sv_freezetag.qc.

References autocvar_g_freezetag_weaponarena, and M_ARGV.

{
    if(M_ARGV(0, string) == "0" || M_ARGV(0, string) == "")
        M_ARGV(0, string) = autocvar_g_freezetag_weaponarena;
}

MUTATOR_HOOKFUNCTION() [14/16]

MUTATOR_HOOKFUNCTION	(	ft	,
		FragCenterMessage
	)

Definition at line 720 of file sv_freezetag.qc.

References CS(), entity(), FROZEN_NORMAL, GetResource(), IS_BOT_CLIENT, M_ARGV, ping, and RES_HEALTH.

{
    entity frag_attacker = M_ARGV(0, entity);
    entity frag_target = M_ARGV(1, entity);
    //float frag_deathtype = M_ARGV(2, float);
    int kill_count_to_attacker = M_ARGV(3, int);
    int kill_count_to_target = M_ARGV(4, int);

    if(STAT(FROZEN, frag_target) == FROZEN_NORMAL)
        return; // target was already frozen, so this is just pushing them off the cliff

    Send_Notification(NOTIF_ONE, frag_attacker, MSG_CHOICE, CHOICE_FRAG_FREEZE, frag_target.netname, kill_count_to_attacker, (IS_BOT_CLIENT(frag_target) ? -1 : CS(frag_target).ping));
    Send_Notification(NOTIF_ONE, frag_target, MSG_CHOICE, CHOICE_FRAGGED_FREEZE, frag_attacker.netname, kill_count_to_target,
        GetResource(frag_attacker, RES_HEALTH), GetResource(frag_attacker, RES_ARMOR), (IS_BOT_CLIENT(frag_attacker) ? -1 : CS(frag_attacker).ping));

    return true;
}

Here is the call graph for this function:

MUTATOR_HOOKFUNCTION() [15/16]

MUTATOR_HOOKFUNCTION	(	ft	,
		SV_ParseServerCommand
	)

Definition at line 738 of file sv_freezetag.qc.

References cmd_name, M_ARGV, round_handler_IsActive, round_handler_IsRoundStarted, and shuffleteams_on_reset_map.

{
    string cmd_name = M_ARGV(0, string);
    if (cmd_name == "shuffleteams")
        shuffleteams_on_reset_map = !(round_handler_IsActive() && !round_handler_IsRoundStarted());
    return false;
}

MUTATOR_HOOKFUNCTION() [16/16]

MUTATOR_HOOKFUNCTION	(	ft	,
		Scores_CountFragsRemaining
	)

Definition at line 746 of file sv_freezetag.qc.

{
    // announce remaining frags
    return true;
}

nades_Clear()

void nades_Clear

(

entity

)

Referenced by freezetag_CheckTeams(), and freezetag_CheckWinner().

Here is the caller graph for this function:

nades_GiveBonus()

void nades_GiveBonus	(	entity	player,
		float	score
	)

Referenced by freezetag_CheckTeams(), and MUTATOR_HOOKFUNCTION().

Here is the caller graph for this function:

void()

void

(

entity

this

)

Referenced by freezetag_isEliminated().

Here is the caller graph for this function:

Variable Documentation

autocvar_g_freezetag_frozen_maxtime

float autocvar_g_freezetag_frozen_maxtime

Definition at line 6 of file sv_freezetag.qc.

Referenced by freezetag_Freeze(), and MUTATOR_HOOKFUNCTION().

autocvar_g_freezetag_revive_clearspeed

float autocvar_g_freezetag_revive_clearspeed

Definition at line 7 of file sv_freezetag.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_freezetag_round_timelimit

float autocvar_g_freezetag_round_timelimit

Definition at line 8 of file sv_freezetag.qc.

Referenced by freezetag_CheckWinner(), and freezetag_Initialize().

autocvar_g_freezetag_teams_override

int autocvar_g_freezetag_teams_override

Definition at line 10 of file sv_freezetag.qc.

Referenced by freezetag_Initialize().

autocvar_g_freezetag_warmup

float autocvar_g_freezetag_warmup

Definition at line 11 of file sv_freezetag.qc.

Referenced by freezetag_CheckWinner(), and freezetag_Initialize().

autocvar_g_ft_start_ammo_cells

float autocvar_g_ft_start_ammo_cells = 180

Definition at line 18 of file sv_freezetag.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_ft_start_ammo_fuel

float autocvar_g_ft_start_ammo_fuel = 0

Definition at line 20 of file sv_freezetag.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_ft_start_ammo_nails

float autocvar_g_ft_start_ammo_nails = 320

Definition at line 16 of file sv_freezetag.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_ft_start_ammo_plasma

float autocvar_g_ft_start_ammo_plasma = 180

Definition at line 19 of file sv_freezetag.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_ft_start_ammo_rockets

float autocvar_g_ft_start_ammo_rockets = 160

Definition at line 17 of file sv_freezetag.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_ft_start_ammo_shells

float autocvar_g_ft_start_ammo_shells = 60

Definition at line 15 of file sv_freezetag.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_ft_start_armor

float autocvar_g_ft_start_armor = 100

Definition at line 14 of file sv_freezetag.qc.

Referenced by MUTATOR_HOOKFUNCTION().

autocvar_g_ft_start_health

float autocvar_g_ft_start_health = 100

Definition at line 13 of file sv_freezetag.qc.

Referenced by MUTATOR_HOOKFUNCTION().